DCTOE ;AFDRUKKEN TOELEVERINGEN [ 01/17/2002  4:18 PM ]
 #Include BL.Derde.Kennis
 #include BL.Derde.LevSpecifiek
 ;
 ; Het afdrukken van een toelevering kan met volgende oproep
 ; --> Do PRINT^DCTOE(TOENr,,,,SelPrint)
 ;     SelPrint = 0 of '$D (geen printerkeuze, printer reeds gedefinieerd)
 ;              = 1 (met printerkeuze)
 ;              = 2 (met automatische printerselectie "Bon")
 ;
VERWERK(FromNr,Sessie) 
 New TOENr
 Do INIT
 Set TOENr=$S(FromNr:FromNr-1,1:FromNr)
 For  Set TOENr=$O(^HULP($J,"P",Sessie,TOENr)) Quit:TOENr=""  Do PRINT(TOENr,$S(Sessie="X":"K",1:Sessie),1)
 Quit
 ;
FN(Number,Fraction,Format) 
 Quit $$FN^DCALG(Number,Fraction,$G(Format))
 ;
PASTEB(R,AddBlank) 
 New NewPage
 If $G(DetailHalux) Set NewPage="Do DFOOTER^"_$ZN_","_"HTITEL"_"^"_$ZN_",DHEADER^"_$ZN
 Else  Set NewPage="Do FOOTER^"_$ZN_","_$S(LEVNr=$$$LevHalux:"HTITEL",1:"TITEL")_"^"_$ZN_",HEADER^"_$ZN
 Do PASTEB^DCALG(R,NewPage,$G(AddBlank))
 Quit
 ;
BLOCK(R) 
 Do BLOCK^DCALG(R)
 Quit
 ;
CACHE(R) 
 Do CACHE^DCALG(R)
 Quit
 ;
PASTE(Page,Line,Text,BPos,EPos,Attr) 
 Do PASTE^DCALG(Page,Line,Text,BPos,EPos,Attr)
 Quit
 ;
 ; Afdruk body
BODY 
 New B,R,BCount,TLNr,Paste,LEVKLNr,LevKlNm
 Set R=^KTO(LEVNr,TOENr,1),LEVKLNr=$P(R,D,9)
 If "\\0\212250\999250\"'[(D_LEVKLNr_D) Do
 .Set LevKlNm=$P($G(^BLBeri("K",LEVKLNr)),D)
 .Do CACHE(L("B","B"))
 .Set T=$$TXT("Klant")_": "_LEVKLNr_" "_LevKlNm,T=$E(T,1,45)
 .Do PASTE(PCount,LCount,T,5,"","U")
 .Do CACHE(L("B","B"))
 Set BCount=0
 Set TLNr=100
 For  Set TLNr=$O(^KTO(LEVNr,TOENr,TLNr)) Quit:TLNr=""  Do
 .Set Paste=$$TOELEV^DCDETAIL(TOENr,TLNr)
 .If Paste Do PASTEB(L("B","B"),1)
 If $D(B) Do PASTEB(L("B","B"),1)
 Quit
 ;
 ; Afdruk hoofding
HEADER 
 New T
 If $D(VPerfoT) New VPerfo Set VPerfo=VPerfoT
 Do CACHE(L("B","F"))
 Do CACHE(L("B","B"))
 Set T=$$TXT("Art")
 Do PASTE(PCount,LCount,T,3,"","")
 Set T=$$TXT("Aant")
 Do PASTE(PCount,LCount,T,"",56,"")
 If LEVNr=$$$LevHalux Do
 . Set T=$$TXT("BarCode")
 . Do PASTE(PCount,LCount,T,60,"","")
 Else  Do
 . Set T=$$TXT("Prijs")_" "_ToeMunt
 . Do PASTE(PCount,LCount,T,"",69,"")
 Set T=$$TXT("LevWk")
 Do PASTE(PCount,LCount,T,"",77,"")
 If $D(L("B","S")) Do CACHE(L("B","S"))
 Quit
 ;
 ; Afdruk hoofding detail
DHEADER 
 New T
 If $D(VPerfoT) New VPerfo Set VPerfo=VPerfoT
 Do CACHE(L("D","F"))
 Do CACHE(L("D","B"))
 Set T=$$TXT("Art")
 Do PASTE(PCount,LCount,T,3,"","")
 Set T=$$TXT("Aant")
 Do PASTE(PCount,LCount,T,"",77,"")
 If $D(L("D","S")) Do CACHE(L("D","S"))
 Quit
 ;
 ; Afdruk titel (volgende blazijden)
TITEL 
 New OrdDat,LevInd,R,T,Blank,Titel,Allign,VPerfo
 New Aanspr,Naam,Woonpl,KLNr,LevAdr,ORDNr,OrdRef
 Do PPRINT
 Set PCount=PCount+1,LCount=0
 Set R=^KTO(LEVNr,TOENr,1),OrdDat=$TR($P(R,D,2),".","-"),ORDNr=$P(R,D,7),KLNr=$P(R,D,8)
 Set (LevAdr,OrdRef)=""
 Set LevInd=^KL1(LEVNr),R=^KLE(LevInd,0)
 Set Naam=$P(R,D,2),Aanspr=$P(R,D,4),Woonpl=$P(R,D,7)
 Do VHPB^DCALG(PCount,.Blank,6)
 Set T=$$FIRMANM^DCALG("L",LEVNr)
 Do PASTE(PCount,Blank-1,T,40,"","")
 Do PASTE(PCount,Blank,Woonpl,40,"","")
 Set Titel=$$TXT("Toelev")
 Set Allign=$L(Titel)
 Set T=$$TXT("Date") Set:$L(T)>Allign Allign=$L(T)
 Do PASTE(PCount,Blank,T,2,"","")
 Do PASTE(PCount,Blank,OrdDat,Allign+4,"","")
 Set T=Titel_$J("",Allign-$L(Titel)+2)_$TR($FN(TOENr,","),",",".")
 Set T=$E(T,1,35)
 Do PASTE(PCount,Blank-1,T,2,"","B")
 If PCount>1 Do
 .Set T=$$TXT("Vervg")_" ("_(PCount-1)_")"
 .Do PASTE(PCount,Blank,T,"",79,"")
 Quit
 ;
 ; Afdruk titel (eerste blad)
FTITEL 
 New OrdDat,LevInd,R,T,Blank,Titel,Allign,VPerfo
 New Aanspr,Naam,Toenaam,Straat,PostNr,Woonpl,Land,BtwNr,KLNr,LevAdr,ORDNr,OrdRef,ToeRef
 Set PCount=PCount+1,LCount=0
 Set R=^KTO(LEVNr,TOENr,1),OrdDat=$TR($P(R,D,2),".","-"),ToeRef=$P(R,D,3),ORDNr=$P(R,D,7),KLNr=$P(R,D,8)
 Set (LevAdr,OrdRef)=""
 Set LevInd=^KL1(LEVNr),R=^KLE(LevInd,0),BtwNr=$$BTWNR^DCALG($P(R,D,16))
 Set Naam=$P(R,D,2),Toenaam=$P(R,D,3),Aanspr=$P(R,D,4)
 Set Straat=$P(R,D,5),PostNr=$P(R,D,6),Woonpl=$P(R,D,7)
 Set Land=$$LAND^vhRtn1($P(R,D,8))
 Do VHPB^DCALG(PCount,.Blank)
 If $L(BtwNr) Do
 .Do PASTE(PCount,AdresPos-5,BtwNr,48,"","")
 .Set T=$$TXT("Btw")
 .Do PASTE(PCount,AdresPos-5,T,40,"","")
 Set T=$$FIRMANM^DCALG("L",LEVNr)
 Do PASTE(PCount,AdresPos,T,40,"","")
 If '$L(Toenaam) Do
 .Do PASTE(PCount,AdresPos+1,Straat,40,"","")
 .Do PASTE(PCount,AdresPos+3,PostNr_"   "_Woonpl,40,"","")
 .If Land'="BE" Do PASTE(PCount,AdresPos+4,$$LAND^vhRtn1(Land,2,Taal),40,"","")
 If $L(Toenaam) Do
 .Do PASTE(PCount,AdresPos+1,Toenaam,40,"","")
 .Do PASTE(PCount,AdresPos+2,Straat,40,"","")
 .Do PASTE(PCount,AdresPos+4,PostNr_"   "_Woonpl,40,"","")
 .If Land'="BE" Do PASTE(PCount,AdresPos+5,$$LAND^vhRtn1(Land,2,Taal),40,"","")
 Set Titel=$$TXT("Toelev")
 Set Allign=$L(Titel)
 Set T=$$TXT("Date") Set:$L(T)>Allign Allign=$L(T)
 Do PASTE(PCount,Blank-1,T,2,"","")
 Do PASTE(PCount,Blank-1,OrdDat,Allign+4,"","")
 Set T=Titel_$J("",Allign-$L(Titel)+2)_$TR($FN(TOENr,","),",",".")
 Set T=$E(T,1,35)
 Do PASTE(PCount,Blank-3,T,2,"","B")
 Do VHPD^DCALG(PCount,.Blank,.VH)
 Quit
 ;
 ; Afdruk titel Halux
HTITEL(PrintVerzendwijze=1)
 New OrdDat,I,R,T,Blank,Titel,Allign,VPerfo,ToeRef,LevInd,Aanspr,Naam,Woonpl,ORDNr,KLNr,KlTaal,DueOut,VerzW,bl,arCnt,TipOn,SifSpb,Baliko,Hangmap,Specials,Stapelhoogte
 New ToeleveringAPI, Toelevering, ToeleveringProductInfo
 Set ToeleveringAPI = ##class(DOM.DomeinContext).Instance().GeefToeleveringAPI()
 Set Toelevering = ToeleveringAPI.GeefToelevering(TOENr)
 Set bl=##class(BL.PPS.TBX.LeanBatch).%New()
 Set ToeleveringProductInfo = bl.GeefToeleveringProductInfo(Toelevering)
 Set TipOn=ToeleveringProductInfo.AantalTipon
 Set SifSpb=ToeleveringProductInfo.AantalLadenMetUitsparing
 Set Baliko=ToeleveringProductInfo.AantalBaliko
 Set Hangmap=ToeleveringProductInfo.AantalHangmappen
 Set StapelingService = ##class(APPS.Halux.common.StapelService).%New(Toelevering)
 Set Stapelhoogte = (StapelingService.GeefStapelHoogte()/1000)
 Set Specials=""
 For I="TipOn","SifSpb","Baliko","Hangmap" Do:@I
 . Set $P(Specials,D)=$P(Specials,D)+1
 . Set T=$$TXT(I)
 . Set:$P(Specials,D,2)<$L(T) $P(Specials,D,2)=$L(T)
 . Set:$P(Specials,D,3)<$L(@I) $P(Specials,D,3)=$L(@I)
 Set $P(Specials,D,3)=$P(Specials,D,3)+1
 For I="TipOn","SifSpb","Baliko","Hangmap" Do:@I
 . Set T=$$TXT(I),R=T_$J("",$P(Specials,D,2)-$L(T))_":"_$J(@I,$P(Specials,D,3))
 . Set Specials($O(Specials(""),-1)+1)=R
 Do:PCount PPRINT
 Set PCount=PCount+1,LCount=0
 Set R=^KTO(LEVNr,TOENr,1),OrdDat=$TR($P(R,D,2),".","-"),ToeRef=$P(R,D,3)
 Set ORDNr=$P(R,D,7),KLNr=$P(R,D,8),DueOut=$P(R,D,19)
 Set LevInd=^KL1(LEVNr),R=^KLE(LevInd,0)
 Set Naam=$P(R,D,2),Aanspr=$P(R,D,4),Woonpl=$P(R,D,7)
 Do VHPB^DCALG(PCount,.Blank,5)
 If Specials For I=1:1:Specials Do PASTE(PCount,Blank-5+I,Specials(I),"",78,"B")
 Set T=$$FIRMANM^DCALG("L",LEVNr)
 Do PASTE(PCount,Blank-2,T,40,"","")
 Do PASTE(PCount,Blank-1,Woonpl,40,"","")
 Set Titel=$$TXT("Toelev")
 Set Allign=$L(Titel)
 Set T=$$TXT("Date") Set:$L(T)>Allign Allign=$L(T)
 Do PASTE(PCount,Blank-1,T,2,"","")
 Do PASTE(PCount,Blank-1,OrdDat,Allign+4,"","")
 Set T=Titel_$J("",Allign-$L(Titel)+2)_$TR($FN(TOENr,","),",",".")
 If PCount'>1,$E(ToeRef,1,6)="KOMM. " Do
 . Set R=^KKL(^KK1(KLNr),0),KlTaal=$P(R,D,9)
 . Set:KlTaal="" KlTaal="N"
 . Set T=T_"/"_$E(ToeRef,7,99),T=$E(T,1,33)_"/"_KlTaal
 Set T=$E(T,1,35)
 Do PASTE(PCount,Blank-2,T,2,"","B")
 Do:PCount>1
 .Set T=$$TXT("Vervg")_" ("_(PCount-1)_")"
 .Do PASTE(PCount,Blank,T,"",79,"")
 Do:DueOut
 .If KLNr,ORDNr,$D(^KOD(KLNr,"F",ORDNr)) Set VerzW=$$SHOW^KLVERZW(,KLNr,ORDNr)
 .Set T=$$TXT("DueOut")
 .Do PASTE(PCount,Blank,T,2,"","")
 .Set T=$$FMTDT^vhLib.DataTypes(DueOut)
 .Set:($L($G(VerzW))&&PrintVerzendwijze) T=T_"  "_VerzW
 .Do PASTE(PCount,Blank,T,Allign+4,"","")
 If PCount=1,Stapelhoogte Do
 .Set T=$$TXT("StapelH")_":"_$$EXTNUM^vhLib.DataTypes(Stapelhoogte,5,".",2)_"m"
 .Do PASTE(PCount,Blank,T,"",78,"B")
 Quit
 ;
 ; Afdruk afsluiting (eerste bladzijden)
FOOTER 
 Set C(PCount,LCount)=C(PCount,LCount)_P("D",0)
 For I=LCount+1:1:MaxLines-1 Do CACHE(L("B","B"))
 Do CACHE(L("B","L"))
 Set T=" "_$$TXT("Vervt")_" "
 Do PASTE(PCount,LCount,T,"",79,"")
 Set C(PCount,LCount)=P("D",1)_C(PCount,LCount)
 Quit
 ;
 ; Afdruk afsluiting detail (eerste bladzijden)
DFOOTER 
 Set C(PCount,LCount)=C(PCount,LCount)_P("D",0)
 For I=LCount+1:1:MaxLines-1 Do CACHE(L("D","B"))
 Do CACHE(L("D","L"))
 Set T=" "_$$TXT("Vervt")_" "
 Do PASTE(PCount,LCount,T,"",79,"")
 Set C(PCount,LCount)=P("D",1)_C(PCount,LCount)
 Quit
 ;
 ; Afdruk afsluiting (laatste blad)
LFOOTER 
 Do CACHE($S($LL(lbKenAnk):L("A","L"),LEVNr=$$$LevHalux:L("A","H"),1:L("A","L")))
 Quit
 ;
 ; Afdruk afsluiting detail (laatste blad)
LDFOOTER 
 Do CACHE(L("D","L"))
 Quit
 ;
 ; Afdruk van de voorwaarden
VOORW 
 New B,I,R,R1,T,BCount,%KontKrt,TKontKrt,BetVw,LeverVw,LTemp,VPerfoT
 Set VPerfoT=VPerfo
 New VPerfo
 Set BCount=0
 Set LevInd=^KL1(LEVNr),R=^KLE(LevInd,0),%KontKrt=$P(R,D,17),BetVw=$P(R,D,18)
 Set R=^KLE(LevInd,2),TKontKrt=$P(R,D,2)
 Set R=^KLE(LevInd,3),LeverVw=$P(R,D,3)
 Set R=$$LEVVW^LEVER(LeverVw,Taal) ; Leveringsvoorwaarde
 If $L(R) Do
 .Set T=$$TXT("LevVw")
 .Set R=T_"`3``U\:`"_($L(T)+3)_D_R
 .For I=1:1:$L(R,"#") Set $P(R,"#",I)=$P(R,"#",I)_"`"_($L(T)+5)
 .For I=1:1:$L(R,"#") Do BLOCK($P(R,"#",I))
 .Do BLOCK("")
 Set T=$$TXT("BetVw") ; Betalingsvoorwaarde
 Set R=$$BETVW^LEVER(BetVw,%KontKrt,TKontKrt,"",Taal)
 Set R=T_"`3``U\:`"_($L(T)+3)_D_R
 For I=1:1:$L(R,"#") Set $P(R,"#",I)=$P(R,"#",I)_"`"_($L(T)+5)
 For I=1:1:$L(R,"#") Do BLOCK($P(R,"#",I))
 Do BLOCK("")
 Do MEMO^DCALG("T")
 If B(BCount)="" Kill B(BCount) Set BCount=BCount-1
 Set LTemp=L("B","S") If P("Type")="CA"!(P("Type")="BL")!(P("Type")="TK") Kill L("B","S")
 If LCount+BCount+2>MaxLines Do FOOTER,TITEL,HEADER
 Set L("B","S")=LTemp
 Set C(PCount,LCount)=C(PCount,LCount)_P("D",0)
 If P("Type")'="CA",P("Type")'="BL",P("Type")'="TK" For I=LCount+1:1:MaxLines-2-BCount Do CACHE(L("B","B"))
 Do CACHE(L("V","F"))
 Set C(PCount,LCount)=P("D",1)_C(PCount,LCount)
 Do PASTEB(L("V","B"))
 Quit
 ;
 ; Afdruk van de voorwaarden - via proxy objects - Added by WimV on 12/05/2005
VOORWPROXY(LEVNr,TOENr,Cache,Taal)   ; Cache als .local doorgeven --> wordt opgevuld met teksten
#define LEVRec(%i)   ^KLE(LEVID,%i)
 New LEVID,Rec,R,i
 New LeverVw,BetVw,PctKontKrt,TKontKrt,Rembours,VoorBet
 Set LEVID=^KL1(LEVNr)
 Set:($G(Taal)="") Taal=$P($$$LEVRec(0),"\",9) Set:(Taal="") Taal="N"
 
 ; Leveringsvoorwaarde
 Set LeverVw=$P($$$LEVRec(3),"\",3)
 Set R=$$LEVVW^LEVER(LeverVw,Taal)
 For i=1:1:$L(R,"#") Set Cache("LEVERINGSVOORWAARDE",i)=$P(R,"#",i)
 ; Betalingsvoorwaarde
 Set PctKontKrt=$P($$$LEVRec(0),"\",17), BetVw=$P($$$LEVRec(0),"\",18)
 Set TKontKrt=$P($$$LEVRec(2),"\",2)
 Set R=$$BETVW^LEVER(BetVw,PctKontKrt,TKontKrt,"",Taal)
 For i=1:1:$L(R,"#") Set Cache("BETALINGSVOORWAARDE",i)=$P(R,"#",i)
 ; Memo
 Do MEMOPROXY^DCALG("T",Taal,.Cache)
 Quit
 ;
 ; Afdruk van de kennisankers - via proxy objects
KENANKPROXY(LEVNr,TOENr,Cache)   ; Cache als .local doorgeven --> wordt opgevuld met teksten
 New i,R,KLNr,lbKenAnk,KenAnk,KennisObject,Msg,Wrap,Lijn,varErrStr
 Do:LEVNr=$$$LevHalux  ; Enkel Halux
 . Set R=^KTO(LEVNr,TOENr,1),KLNr=$P(R,"\",8)
 . Set lbKenAnk=##class(BL.Derde.Kennis.Kennis).GetIDsToPopup(KLNr,.varErrStr,$LB($$$adWerkbon,$$$adpGetAll($$$adProductie)),,"PRINT",,,1)
 . Quit:'$LL(lbKenAnk)  ; Geen kennisankers
 . For i=$LL(lbKenAnk):-1:1 Do
 . . Set KenAnk=($LI(lbKenAnk,i))
 . . Set KennisObject=##class(Derde.Kennis.Kennis).%OpenId(KenAnk)
 . . Quit:'$IsObject(KennisObject)
 . . Set Msg=KennisObject.Msg
 . . Set Cache("KENNISANKER",$O(Cache("KENNISANKER",""),-1)+1)=Msg
 . . ;Quit
 . . ;Set Msg(1)=$TR(Msg,$C(13,10),"~")
 . . ;Do GETWRAP^vhBIGEDIT("Msg",73,.Wrap,"G","~","")
 . . ;For Lijn=1:1:Wrap Do
 . . ;. Set R=$S(Lijn=1:"- ",1:"  ")_$P(Wrap(Lijn),"`",5)
 . . ;. Set Cache("KENNISANKER",$O(Cache("KENNISANKER",""),-1)+1)=R
 Quit
 ;
 ; Afdruk van de kennisankers
KENANK(lbKenAnk) 
 New I,R,KenAnk,Msg,Wrap,Lijn
 Do CACHE($S(LEVNr=$$$LevHalux:L("V","F"),1:L("V","B")))
 Set BCount=0
 For I=$LL(lbKenAnk):-1:1 Do 
 . Set KenAnk=($LI(lbKenAnk,I))
 . Set KennisObject=##class(Derde.Kennis.Kennis).%OpenId(KenAnk)
 . Quit:'$IsObject(KennisObject)
 . Set Msg=KennisObject.Msg
 . Set Msg(1)=$TR(Msg,$C(13,10),"~")
 . Do GETWRAP^vhBIGEDIT("Msg",73,.Wrap,"G","~","")
 . For Lijn=1:1:Wrap Do
 . . Set R=$S(Lijn=1:"- ",1:"  ")_$P(Wrap(Lijn),"`",5)_"`3"
 . . Do BLOCK(R)
 . Do PASTEB(L("V","B"),Lijn=Wrap)
 Quit
 ;
 
KENNISANKERS(lbKenAnk)
	Do:$listlength(lbKenAnk) KENANK^DCTOE(lbKenAnk)
 Quit
 ; 
 
ORDREF(KLNr,ORDNr) 
 New R,OrdRef
 Set R=$G(^KOD(KLNr,"F",ORDNr,1)),OrdRef=$P(R,D,3)
 Set:OrdRef?2N1"."2N1"."2N1" ".E OrdRef=$P(OrdRef," ",2,99)
 Quit OrdRef
 ;
 ; Afdrukken van een bladzijde
PPRINT 
 Do PPRINT^DCPRINT(PCount)
 Kill C(PCount)
 Quit
 ;
 ; Opbouwen local C en afdrukken van de toelevering
PRINT(TOENr,Sessie,Init,MetFax,SelPrint) 
 New LEVNr,LevInd,Taal,ToelTyp
 New Toelevering set Toelevering = ##class(DOM.DomeinContext).Instance().GeefToeleveringAPI().GeefToelevering(TOENr)
 New C,PCount,LCount,KLNr,varErrStr,lbKenAnk
 
 Set SelPrint=$G(SelPrint)
 If 0'[SelPrint Do SELPRINT^DCPRINT(SelPrint) Quit:'$D(Print)
 If '$G(Init) Do INIT
 Set PCount=0,ToelTyp=1,lbKenAnk=""
 Set R=^KTO1(TOENr),LEVNr=$P(R,D)
 
 If LEVNr=5005,$D(^BLBeri("Z",TOENr)) Set BLBeri=1
 Set R=^KTO(LEVNr,TOENr,1),ToeMunt=$$MUNT^vhRtn1($P(R,D,18),1)
 If LEVNr=$$$LevHalux {
	Set KLNr=$P(R,D,8)
	Set lbKenAnk=##class(BL.Derde.Kennis.Kennis).GetIDsToPopup(KLNr,.varErrStr,$LB($$$adpGetAll($$$adProductie)),,"PRINT",,,0,2,1,0)
 }

 Set LevInd=^KL1(LEVNr),R=^KLE(LevInd,0),Taal=$P(R,D,9) If Taal="" Set Taal="N"
 Do PRINT^LOG("TO",TOENr,$S($G(MetFax):"F",1:"P"))
 Do @$S(LEVNr=$$$LevHalux:"HTITEL",1:"FTITEL"),HEADER,BODY,KENNISANKERS(lbKenAnk),VOORW:LEVNr'=$$$LevHalux,LFOOTER,PPRINT
 If LEVNr=$$$LevHalux,$$ToeleveringBevatDetailHalux(TOENr,LEVNr),$$PrintProductieVoorbereiding(Toelevering) Do
 . Set PCount=PCount+1,LCount=0
 . Do DetailHalux(TOENr),LDFOOTER,PPRINT
 Do:($$PrintProductieVoorbereiding(Toelevering)) PrintToelevering^HADTBXPrep(TOENr,Print("DEV"))
 Set:$G(MetFax) Data("Pages")=$G(Data("Pages"))+PCount
 If 0'[SelPrint Do CLOSE^vhPRINTER Kill ^KTOB(TOENr)
 Quit

PrintProductieVoorbereiding(Toelevering)
	new PrintProductieVoorbereidingDoorOrderverwerkingBepaler
	set PrintProductieVoorbereidingDoorOrderverwerkingBepaler = ##class(APPS.Halux.PPS.impl.PrintProductieVoorbereidingDoorOrderverwerkingBepaler).%New()
	quit PrintProductieVoorbereidingDoorOrderverwerkingBepaler.PrintenNodig(Toelevering)


 ;
 ; Moet er een detailblad afgedrukt worden voor Halux
ToeleveringBevatDetailHalux(TOENr,LEVNr)
 New BevatDetail,TLNr
 Set BevatDetail=0
 Set TLNr=100
 For  Set TLNr=$O(^KTO(LEVNr,TOENr,TLNr)) Quit:TLNr=""  Set BevatDetail=$$LijnBevatDetailHalux(LEVNr,TOENr,TLNr) Quit:BevatDetail
 Quit BevatDetail
 ;
 ; TBX, KAD en GRP moeten niet afgedrukt worden op het detailoverzicht
LijnBevatDetailHalux(LEVNr,TOENr,TLNr)
 New LijnBevatDetail,PRNr,GenTyp,ProductTypeAPI
 Set PRNr=$P(^KTO(LEVNr,TOENr,TLNr),D,2)
 Do:PRNr
 . Set GenTyp=$$GENTYP^HAD(PRNr)
 . Set ProductTypeAPI = ##class(DOM.DomeinContext).Instance().GeefProductTypeAPI()
 . If ((($P(GenTyp,D,1,2) = "TBX\BBX") && ('ProductTypeAPI.IsHangmapLade(PRNr))) || ($P(GenTyp,D)'="TBX")),'ProductTypeAPI.IsInkortingProduct(PRNr),$P(GenTyp,D)'="KAD",$P(GenTyp,D,2)'="GRP" Set LijnBevatDetail=1
 . Else  Set LijnBevatDetail=0
 Quit $G(LijnBevatDetail)
 ;
 ; Afdrukken detailblad Halux
DetailHalux(TOENr, PrintVerzendwijze=1)
 New TLNr,Paste,DetailHalux,EerstePagina
 Set DetailHalux=1
 Set EerstePagina=1
 Do HTITEL(PrintVerzendwijze),DHEADER
 Set BCount=0
 Set TLNr=100
 For  Set TLNr=$O(^KTO(LEVNr,TOENr,TLNr)) Quit:TLNr=""  Do
 . Quit:'$$LijnBevatDetailHalux(LEVNr,TOENr,TLNr)
 . Do:(('EerstePagina) && $$IsNieuwePaginaGevraagd(LEVNr,TOENr,TLNr)) DFOOTER,HTITEL,DHEADER
 . Set EerstePagina = 0
 . Set Paste=$$TOELEVBS^DCDETAIL(TOENr,TLNr)
 . If Paste Do PASTEB(L("D","K"))
 Quit
 
IsNieuwePaginaGevraagd(LEVNr,TOENr,TLNr)
 New PRNr,ProductTypeAPI,Resultaat
 Set Resultaat = 0
 Set PRNr=$P(^KTO(LEVNr,TOENr,TLNr),D,2)
 If (PRNr) {
	#dim ProductTypeAPI As DOM.PM.ProductTypeAPI = ##class(DOM.DomeinContext).Instance().GeefProductTypeAPI()
 	If (ProductTypeAPI.IsLegraboxProduct(PRNr) || ProductTypeAPI.IsTAORboxProduct(PRNr)) {
	 	Set Resultaat = 1
 	}
 }
 Quit Resultaat
 
 ;
 ; Initialisatie
INIT 
 If '$D(VH) Do VH^DCINIT
 If '$D(P) Do PINIT^DCINIT
 If '$D(L) Do LINIT^DCINIT("T")
 If '$D(PageLen)!'$D(V) Do FINIT^DCINIT("T")
 Write P("D",1)
 Quit
 ;
 ; Ophalen taalafhankelijke tekst
TXT(Ref,Piece) 
 If '$D(Piece) Set Piece=2
 Quit $P($P($T(@("T"_Ref)),U,Piece),D,$F("NFDE",Taal)-1)
 ;
TToelev ;BESTELBON\BON DE COMMANDE\AUFTRAG\ORDER
TDate ;Datum\Date\Datum\Date
TDueOut ;Dueout\Dueout\Dueout\Dueout
TBtw ;BTW nr.\No. TVA\BTW nr.\VAT nbr
TVervg ;vervolg\suite\fortsetzung\continue
TVervt ;vervolgt\à suivre\fortgesetzt\t.b.continued
TKlant ;Klant\Client\Kunde\Customer
TArt ;Artikel\Article\Artikel\Article
TAant ;Aantal\Quant.\Menge\Quant.
TPrijs ;Prijs\Prix\Preis\Price
TBarCode ;Barcode\Barcode\Barcode\Barcode
TLevWk ;Week\Sem.\Woche\Week
TLevVw ;Leveringsvoorwaarde\Conditions de livraison\Lieferbedingung\Betalingsvoorwaarde
TBetVw ;Betalingsvoorwaarde\Conditions de paiement\Zahlungsbedingung\Betalingsvoorwaarde
TTipOn ;Tip-on\Tip-on\Tip-on\Tip-on
TSifSpb ;Sif/spb\Sif/spb\Sif/spb\Sif/spb
TBaliko ;Baliko\Baliko\Baliko\Baliko
THangmap ;Hangmap\Hangmap\Hangmap\Hangmap
TStapelH ;Stapelhoogte\Stapelhoogte\Stapelhoogte\Stapelhoogte