#include %Prod.Product
ORGALUX ;Verwerking Orgalux [ 12/27/2003  12:40 PM ]
 ;
ISORGAL(PRNr) ; Is het een orgalux product
 Quit $$ISORGAL^PRODUKT2(PRNr)
 
IsIntivo(PRNr)
	Quit $P($G(^KPR(PRNr,0)),"\")?1(1"OL.I",1"OL.TI",1"OL.FW").E
 
ConsumentenPrijs(PRNr,Land,NoSa)
	Quit $$ConsumentenPrijs^KPRIJS(PRNr,.Land,.NoSa)
 	
VERPAK 
 Goto VERPAK^ORGVERP
 ;
REFORD(ORDNr) 
 New R,KLNr,OrgRef
 Set OrgRef="" Set:$$ISORGAL^FLOW("O",ORDNr) KLNr=$P(^KO1(ORDNr,"F"),D),R=^KOD(KLNr,"F",ORDNr,1),OrgRef=$P(R,D,19)
 Quit OrgRef
 ;
REFBON(BONNr,ORDNr) 
 New R,KLNr,OLNr,OrgRef
 Set OrgRef=""
 Do:$$ISORGAL^FLOW("L",BONNr)
 .Set KLNr=$P(^KU1(BONNr,"F"),D),OLNr=100
 .For  Set OLNr=$O(^KUL(KLNr,"F",BONNr,OLNr)) Quit:'OLNr  Do  Quit:$L(OrgRef)
 ..Set R=^KUL(KLNr,"F",BONNr,OLNr)
 ..Quit:$P(R,D,17)'="KF5"
 ..Set:$P($P(R,D,5)," - ")=ORDNr OrgRef=$P(R,D,20)
 Quit OrgRef
 ;
BEVATMAT(BONNr,ORDNr) 
 New R,BevatMat,KLNr,OLNr,Quit
 Set ORDNr=$G(ORDNr),KLNr=$P(^KU1(BONNr,"F"),D),OLNr=100
 If ORDNr For  Set OLNr=$O(^KUL(KLNr,"F",BONNr,OLNr)) Quit:'OLNr  Do  Quit:Quit
 .Set R=^KUL(KLNr,"F",BONNr,OLNr)
 .Set Quit=$P(R,D,17)="KF5"&($P($P(R,D,5)," - ")=ORDNr)
 For  Set OLNr=$O(^KUL(KLNr,"F",BONNr,OLNr)) Quit:'OLNr  Do  Quit:Quit
 .Set R=^KUL(KLNr,"F",BONNr,OLNr),PRNr=$P(R,D,2)
 .If ORDNr Set Quit=$P(R,D,17)="KF5"&($P($P(R,D,5)," - ")'=ORDNr)
 .Quit:'PRNr
 .Set BevatMat=$$ISMAT(PRNr)
 Quit BevatMat
 ;
ISMAT(MPRNr) 
 New R,IsMat,KPRNr
 ;Set (IsMat,KPRNr)=""
 ;For  Set KPRNr=$O(^PRLINK("D",MPRNr,KPRNr)) Quit:KPRNr=""  Do  Quit:IsMat
 ;.Set R=^PRLINK("D",MPRNr,KPRNr),IsMat=$P(R,D,2)="I"
 Set IsMat=$E($$SORTKEY^PRODUKT(MPRNr),7,9)="MAT"
 Quit IsMat
 ;
 ; Bevat oververpakking
BEVATOVP(BONNr,ORDNr) 
 New R,BevatOVP,KLNr,OLNr,Quit,PRNr
 Set ORDNr=$G(ORDNr),KLNr=$P(^KU1(BONNr,"F"),D),OLNr=100
 If ORDNr For  Set OLNr=$O(^KUL(KLNr,"F",BONNr,OLNr)) Quit:'OLNr  Do  Quit:Quit
 .Set R=^KUL(KLNr,"F",BONNr,OLNr)
 .Set Quit=$P(R,D,17)="KF5"&($P($P(R,D,5)," - ")=ORDNr)
 Set BevatOVP=""
 For  Set OLNr=$O(^KUL(KLNr,"F",BONNr,OLNr)) Quit:'OLNr  Do  Quit:Quit  Quit:BevatOVP
 .Set R=^KUL(KLNr,"F",BONNr,OLNr),PRNr=$P(R,D,2)
 .If ORDNr Set Quit=$P(R,D,17)="KF5"&($P($P(R,D,5)," - ")'=ORDNr)
 .Quit:'PRNr
 .Set BevatOVP=$$ISOVP(PRNr) Set:BevatOVP BevatOVP=BevatOVP_D_$P(R,D,3)
 Quit BevatOVP
 ;
 ; Is oververpakking
ISOVP(MPRNr) 
 New R,IsOVP,KPRNr
 Set (IsOVP,KPRNr)=""
 For  Set KPRNr=$O(^PRLINK("D",MPRNr,KPRNr)) Quit:KPRNr=""  Do  Quit:IsOVP
 .Set R=^PRLINK("D",MPRNr,KPRNr) Set:$P(R,D,2)="O" IsOVP=MPRNr
 Quit IsOVP
 ;
 ; Stockupdate van de moeders met stock overkinderen
STOCKUPD(Night) 
 Set Night=$G(Night,0)
 If Night Do
 .New Night
 .Set Q="K"
 .Do ^cA604,INIT^vhTERMINA
 .Set Update=1
 Else  Do
 .New %SC,zb
 .Set Update=""
 .Do DISPLAY^vhScherm("ORGSTCKUPD"),FIELD^vhScherm("ORGSTCKUPD","ASKUPDATE")
 .Set Update=Update="H"
 .Do:Update DISPLAY^vhScherm("ORGSTCKUPD")
 Quit:'Update
 Set %J=$$%J^vhRtn1()
 Kill ^HULP(%J)
 
 ; Fysstock toekennen aan de moeders vertrekkend van de min. stock van de kinderen
 Set MPRNr=""
 For  
 {
	Set MPRNr=$O(^PRBS("BS",MPRNr))
 	Quit:'MPRNr
  	If $$$ProductGet(MPRNr,$$$LinkType)="S" ; Geen stock over kinderen
 	{
	 	Do STOCKUPDMoeder(MPRNr,%J,Night)
 	}
 }
 ; Reservatie vanuit moeder wissen
 Set PRNr=""
 For  Set PRNr=$O(^PRSTOCK("D",PRNr)) Quit:PRNr=""  Do
 . Set Qty=$P(^PRSTOCK("D",PRNr),D,9) ; oud aantal in reservatie door moeder
 . Quit:'Qty ; Niets gereserveerd
 . Lock +^KPR(PRNr)
 . ;Set Reserv=$P(^KPR(PRNr,2),D,9)
 . Set $P(^PRSTOCK("D",PRNr),D,6)=$P($G(^PRSTOCK("D",PRNr)),D,6)-Qty ; aantal in reservatie door moeder weghalen bij de werkvloer reservatie (truuk)
 . ;Set $P(^KPR(PRNr,2),D,9)=Reserv
 . Set $P(^PRSTOCK("D",PRNr),D,9)=""
 . Lock -^KPR(PRNr)
 ; Nieuwe reservatie toekennen
 Set PRNr=""
 For  Set PRNr=$O(^HULP(%J,PRNr)) Quit:PRNr=""  Do
 . Lock +^KPR(PRNr)
 . Set Qty=^HULP(%J,PRNr)
 . Set $P(^PRSTOCK("D",PRNr),D,6)=$P($G(^PRSTOCK("D",PRNr)),D,6)+Qty ; aantal in reservatie door moeder bijtellen bij de werkvloer reservatie (truuk)
 . Set $P(^PRSTOCK("D",PRNr),D,9)=Qty ; aantal in reservatie door moeder
 . Lock -^KPR(PRNr)
 Quit
 ;
 ; Stockupdate van een moeder met stock overkinderen
STOCKUPDMoeder(MPRNr,%J,Night)
 ; OPTIONEEL :%J, alleen te gebruiken als opgeroepen door STOCKUPD van alle producten
 ; OPTIONEEL :Night, alleen te gebruiken als opgeroepen door STOCKUPD van alle producten
 
	New R,ScanTyp,MFysSt,KFysSt,Reserv,Faktor,KPRNr,QtyOld,QtyNew,Sleutel
	; Fysstock toekennen aan de moeders vertrekkend van de min. stock van de kinderen
	#define StockOverKinderen "S"
	Quit:$$$ProductGet(MPRNr,$$$LinkType)'=$$$StockOverKinderen 
 
	Set R=^KPR(MPRNr,0)
	Set KPRNr=""
 
 	;Fysische stock bepalen dmv fysische stock van de kindproducten.
	Set MoederProduct = ##class(DOM.PM.Bouwstenen.Product).%OpenId(MPRNr)
	Set KindIterator = ##class(TECH.ListIterator).%New(MoederProduct.Bouwstenen)
	 	While(KindIterator.HasNext())
		{
			Set KindBouwsteen = KindIterator.Next()
			#define BouwsteenTypeKind "K"
		 	If ($$$BouwsteenTypeKind=KindBouwsteen.Type)
			{
				Set KPRNr = KindBouwsteen.KindProduct.ProductNr
				#define OpslagzoneManueel 9
			 	Set Faktor=KindBouwsteen.Aantal
		 		If KPRNr && ($$OPSLZONE^PRODUKT2(KPRNr)'=$$$OpslagzoneManueel) && (Faktor)
		 		{
		 	 		Set KFysSt=$$GETSTOCK^PRODUKT4(KPRNr,"F")/Faktor\1
		 			Set MFysSt=$G(MFysSt,KFysSt)
		 	 		Set:KFysSt<MFysSt MFysSt=KFysSt
			 	 	If $L($G(%J)) ; backwards compatible voor STOCKUPD (alle producten)
			 	 	{
				 	 	Set Reserv=+$P(^KPR(MPRNr,2),D,9) ; Reservatie van de moeder
 						Set ^HULP(%J,KPRNr)=$G(^HULP(%J,KPRNr))+(Reserv*Faktor)
			 	 	}
				}
			}
		}
 	
	Quit:'$D(MFysSt)
 
	;Fysische stock persisteren.
	Do:'$G(Night,1) DISPLAY^vhScherm("ORGSTCKUPD","","","","MOEDER;STOCK")
	Lock +^KPR(MPRNr)
	Set R=^KPR(MPRNr,0),$P(R,D,14)=MFysSt,^KPR(MPRNr,0)=R
	Set R=$G(^PRSTOCK("D",MPRNr)),$P(R,D)=MFysSt,^PRSTOCK("D",MPRNr)=R
	Lock -^KPR(MPRNr)
 
 Quit
 
 ;
 ; Stockupdate van de moeders van een kind
STOCKUPDKind(KPRNr)
 New MPRNr
 Set MPRNr=""
 For  Set MPRNr=$O(^PRBS("IP",KPRNr,MPRNr)) Quit:'MPRNr  Do STOCKUPDMoeder(MPRNr)
 Quit
 ;
 ; Stock ZERO van de moeders, noodzakelijk bij stockcontrole
STOCKNUL  New Ok,MPRNr,KPRNr,Voorraad
 Write @F11,@F1
 Write @FMTI,"VAN HOECKE NV - Op nul zetten van de ORGALUX moeder-produkten",@FMTi,!
 Set MPRNr=""
 S Ok=$$^vhTXTPOP("ORGALUX","STOCKNUL")
 Quit:'Ok
 Set FP=201 Write @F
 For  Set MPRNr=$O(^PRBS("BS",MPRNr)) Quit:MPRNr=""  Do
 .Quit:$$$ProductGet(MPRNr,$$$LinkType)'=$$$StockOverKinderen 
 .Set Voorraad=0
 .Set BSKey=""
 .For  Set BSKey=$O(^PRBS("BS",MPRNr,BSKey)) Quit:BSKey=""  Do
 .. Quit:$P(^PRBS("BS",MPRNr,BSKey),D,3)'=$$$BouwsteenTypeKind
 .. Set KPRNr=$P(^PRBS("BS",MPRNr,BSKey),D,1)
 .. Quit:'KPRNr
 .. Quit:$$OPSLZONE^PRODUKT2(KPRNr)=9
 .. Set Voorraad=1
 .;Alleen moeders met kinderen die echte voorraad producten zijn
 .Quit:'Voorraad
 .Write $P(^KPR(MPRNr,0),D,1)," ",$P(^KPR(MPRNr,0),D,14),!
 .Lock +^KPR(MPRNr)
 .Set R=^KPR(MPRNr,0),$P(R,D,14)=0,^KPR(MPRNr,0)=R
 .Lock -^KPR(MPRNr) 
 Quit
 
 ; Datumkontrole voor openen klanten 'Orgalux Inside'
VALDATE(Val,Min,Max) 
 New %TC,%INT,%EXT,er,R,Web
 Set Web=$P(Val," ",2),Val=$P(Val," ")
 Set %TC=1
 If $L(Val),'Val Set %TC=0
 If $L(Web),Web'="zw" Set %TC=0
 If $L(Web),Web="zw",'Val Set %TC=0
 If %TC Do
 .Set R="VALDATE^vhDTyp(Val,,"_$S($D(Min):+Min_",",1:",")_$S($D(Max):+Max_")",1:")")
 .Do @R
 Quit %TC
 ;
OPENDEUR 
 New zb
 Set K=$$PI^vhPOPUP("C;C","-DOZ1","Open deur","ORGALUX","OPENDEUR",K)
 If $L(K)
 Else  If zb="CANC" Set K="-"
 Quit
 ;
CHKWEB(K) 
 New Web,Rubr
 Set Web=$P(K," ",2),K=$P(K," ")
 If K="",$P(B(9),D,3)="",$P(B(9),D,12)=""
 Else  If K="" Set ULOG(912)=$S($P(B(9),D,12)=1:"\zw\",1:"\\zw"),$P(B(9),D,12)=""
 Else  If $P(B(9),D,12),Web="zw" Set $P(B(9),D,12)="",ULOG(912)="\\zw"
 Else  If '$P(B(9),D,12),Web="" Set $P(B(9),D,12)=1,ULOG(912)="\zw\"
 If $D(ULOG(912)),$P(ULOG(912),D)="" Do
 .Set Rubr=""
 .For  Set Rubr=$O(^DMA("LVH1","KL",4,Rubr)) Quit:Rubr=""  If $G(^DMA("LVH1","KL",4,Rubr,16))=912 Do  Quit
 ..Set $P(ULOG(912),D)=$G(^DMA("LVH1","KL",4,Rubr,1))
 Quit K
 ;