Imports DubbeleSifonLadeManager = TA_OR_rework.DubbeleSifonLadeManager

Public Class SifonLadeController
    Private Shared _instance As SifonLadeController

    Private ReadOnly _sifonladeManager As MustInheritSifonLadeManager(Of ISifonLade)
    Private ReadOnly _sifonladeDubbelManager As MustInheritSifonLadeManager(Of ISifonLadeDubbel)
    Private ReadOnly _reworkTrayRepository As ReworkTrayRepository

    ''' <summary>
    ''' Singleton instantie opvragen.
    ''' </summary>
    ''' <returns>Instantie</returns>
    Public Shared Function GetInstance() As SifonLadeController
        If _instance Is Nothing Then
            _instance = New SifonLadeController
        End If
        Return _instance
    End Function

    Public Sub New()
        'Rework tray slot engine.
        Dim reworkTrayEngine As New ReworkTrayEngine(New ReworkTraySlotRepository())

        'Rework tray repository
        _reworkTrayRepository = New ReworkTrayRepository()

        'Special lade engine initialiseren met de juiste mapper.
        Dim sifonLadeEngine = New SpecialLadeEngine(Of ISifonLade)(New SifonLadenMapper)
        'Manager initialiseren met de engine.
        _sifonladeManager = New SifonLadeManager(sifonLadeEngine, reworkTrayEngine, _reworkTrayRepository)

        'Dubbele special lade engine initialiseren met de juiste mapper.
        Dim sifonladeDubbelEngine = New SpecialLadeEngine(Of ISifonLadeDubbel)(New SifonLadenDubbelMapper)
        'Manager initialiseren met de engine.
        _sifonladeDubbelManager = New DubbeleSifonLadeManager(sifonladeDubbelEngine, reworkTrayEngine, _reworkTrayRepository)
    End Sub

#Region "Normale sifon lade"

    ''' <summary>
    ''' Zoek de sifonlade aan de hand van de lade code.
    ''' </summary>
    ''' <returns></returns>
    Public Function ZoekSifonLade(ladeCode As String) As Boolean
        'Manager aanroepen en resultaat retourneren. True als de lade is gevonden.
        Return _sifonladeManager.ZoekEnLaadLaden(ladeCode)
    End Function

#Region "Informatie"
    ''' <summary>
    ''' Informatie opvragen over de sifonLade als DTO.
    ''' </summary>
    ''' <returns>DTO met informatie</returns>
    Public Function GeefInformatieSifonLade() As SifonLadeDto
        'De eerste sifonlade opvragen.
        Dim sifonLade As ISifonLade = _sifonladeManager.EersteOfStandaard()

        'Controleren of de sifonLade niet leeg is.
        If sifonLade Is Nothing Then
            'Zo ja, retourneer Nothing.
            Return Nothing
        End If

        'De DTO converter aanmaken.
        Dim dtoConverter = New SifonLadeDtoConverter
        'Sifonlade converteren en retourneren als DTO.
        Return dtoConverter.ToDto(sifonLade)
    End Function

    ''' <summary>
    ''' Opvragen van aantal sifonladen.
    ''' </summary>
    ''' <returns>Het aantal sifonladen</returns>
    Public Function GeefAantalSifonLaden() As Integer
        Return _sifonladeManager.AantalLaden()
    End Function

    ''' <summary>
    ''' Opvragen van de namen van alle onderdelen van een sifonlade met de bijhorende barcodes
    ''' </summary>
    ''' <returns></returns>
    Public Function GeefSifonLadenOrigineleOnderdelenEnBarcodes() As List(Of String())
        Return _sifonladeManager.GeefOrigineleOnderdelenEnBarcodes()
    End Function
#End Region

    ''' <summary>
    ''' Gewijzigde waarden van de sifon lade updaten.
    ''' </summary>
    ''' <param name="sifonLadeDto">De DTO van de sifon lade</param>
    Public Sub UpdateWaardenSifonLade(sifonLadeDto As SifonLadeDto)
        'De DTO converter aanmaken.
        Dim dtoConverter = New SifonLadeDtoConverter
        'Dto converteren naar sifon lade.
        Dim sifonlade = dtoConverter.FromDto(sifonLadeDto)
        'Manager aanroepen om te updaten.
        _sifonladeManager.UpdateAlleLaden(sifonlade)
    End Sub

    ''' <summary>
    ''' Sifonlade bouwen en zijkanten verdelen over rework trays.
    ''' </summary>
    Public Sub VerdeelSifonLadenOverReworkTrays()
        _sifonladeManager.BouwLaden()
    End Sub

    Public Sub ProduceerSifonladen()
        _sifonladeManager.Produceer()
        _reworkTrayRepository.verwijderReworkTraysSpecialLade()
    End Sub
#End Region

#Region "Dubbele sifon lade"

    ''' <summary>
    ''' Zoek de dubbele sifonlade aan de hand van de lade code.
    ''' </summary>
    ''' <returns></returns>
    Public Function ZoekDubbeleSifonLade(ladeCode As String) As Boolean
        'Manager aanroepen en resultaat retourneren. True als de lade is gevonden.
        Return _sifonladeDubbelManager.ZoekEnLaadLaden(ladeCode)
    End Function

#Region "Informatie"

    ''' <summary>
    ''' Informatie opvragen over de dubbele sifonLade als DTO.
    ''' </summary>
    ''' <returns>DTO met informatie</returns>
    Public Function GeefInformatieDubbeleSifonLade() As SifonLadeDubbelDto
        'De eerste sifonlade opvragen.
        Dim sifonLade As ISifonLade = _sifonladeDubbelManager.EersteOfStandaard()

        'Controleren of de sifonLade niet leeg is.
        If sifonLade Is Nothing Then
            'Zo ja, retourneer Nothing.
            Return Nothing
        End If

        'De DTO converter aanmaken.
        Dim dtoConverter = New SifonLadeDubbelDtoConverter
        'Sifonlade converteren en retourneren als DTO.
        Return dtoConverter.ToDto(sifonLade)
    End Function

    ''' <summary>
    ''' Opvragen van aantal dubbele sifonladen.
    ''' </summary>
    ''' <returns>Het aantal sifonladen</returns>
    Public Function GeefAantalDubbeleSifonLaden() As Integer
        Return _sifonladeDubbelManager.AantalLaden()
    End Function

    ''' <summary>
    ''' Opvragen van de namen van alle onderdelen van een dubbele sifonlade met de bijhorende barcodes
    ''' </summary>
    ''' <returns></returns>
    Public Function GeefDubbeleSifonLadenOrigineleOnderdelenEnBarcodes() As List(Of String())
        Return _sifonladeDubbelManager.GeefOrigineleOnderdelenEnBarcodes()
    End Function
#End Region

    ''' <summary>
    ''' Gewijzigde waarden van de sifonlade updaten.
    ''' </summary>
    ''' <param name="sifonLadeDubbelDto">De DTO van de dubbele sifonlade</param>
    Public Sub UpdateWaardenDubbeleSifonLade(sifonLadeDubbelDto As SifonLadeDubbelDto)
        'De DTO converter aanmaken.
        Dim dtoConverter = New SifonLadeDubbelDtoConverter
        'Dto converteren naar sifon lade.
        Dim sifonlade = dtoConverter.FromDto(sifonLadeDubbelDto)
        'Manager aanroepen om te updaten.
        _sifonladeDubbelManager.UpdateAlleLaden(sifonlade)
    End Sub

    ''' <summary>
    ''' Dubbele sifonlade bouwen en zijkanten verdelen over rework trays.
    ''' </summary>
    Public Sub VerdeelDubbeleSifonLadenOverReworkTrays()
        _sifonladeManager.BouwLaden()
    End Sub

    Public Sub ProduceerDubbeleSifonladen()
        _sifonladeDubbelManager.Produceer()
        _reworkTrayRepository.verwijderReworkTraysSpecialLade()
    End Sub

#End Region

    Public Function GeefAantalTrays() As Integer
        Return _reworkTrayRepository.aantalReworkTraysSpecial
    End Function

    Public Function GeefSpecialLadeReworkTrayNummer(index As Integer) As String
        Return _reworkTrayRepository.geefSpecialLadeReworkTrayNummer(index)
    End Function

    ''' <summary>
    ''' inhoud van alle slots van een reworktray geven
    ''' </summary>
    ''' <param name="index"></param>
    ''' <returns></returns>
    Public Function GeefSlotsSpecialReworkTray(index As Integer) As List(Of List(Of String))
        Dim trays As New List(Of List(Of String))
        Try
            For teller As Integer = 0 To _reworkTrayRepository.reworkTraysSpecialLaden(index).slots.Count - 1
                Dim slot As Slot = _reworkTrayRepository.reworkTraysSpecialLaden(index).slots(teller)
                Dim content As New List(Of String)
                If Not (slot.zijkantenSpeciaal Is Nothing OrElse slot.zijkantenSpeciaal.Count <= 0) Then
                    'voorraad
                    content.Add(slot.nummer)
                    content.Add(slot.zijkantenSpeciaal(0).PartCalc)
                    content.Add(slot.zijkantenSpeciaal(0).GeefBatch)
                    If slot.zijkantenSpeciaal.Count = 4 Then 'voorraad
                        content.Add(slot.zijkantenSpeciaal(0).geefColorDubbelVoorraad(slot.zijkantenSpeciaal(1), slot.zijkantenSpeciaal(2), slot.zijkantenSpeciaal(3)))
                    ElseIf slot.type = SlotType.enkel Then 'voorraad met 1 zijkant
                        content.Add(slot.zijkantenSpeciaal(0).geefColorEnkel(slot.zijkantenSpeciaal(1)))
                    Else
                        content.Add(slot.zijkantenSpeciaal(0).geefColorDubbel(slot.zijkantenSpeciaal(1)))
                    End If

                    content.Add(slot.zijkantenSpeciaal(0).PartL)
                    content.Add(slot.zijkantenSpeciaal(0).PartW)
                Else 'leeg slot
                    'de cijfers wel, maar gewoon geen andere informatie meegeven
                    content.Add(teller + 1)
                    content.Add("")
                    content.Add("")
                    content.Add("")
                    content.Add("")
                    content.Add("")
                End If

                trays.Add(content)
            Next
            Return trays
        Catch ex As Exception
            MessageBox.Show("Er is een fout opgetreden bij het opvragen van een special lade reworktray" & ex.Message, "Er is een fout opgetreden...", MessageBoxButtons.OK, MessageBoxIcon.Error)
            Return Nothing
        End Try
    End Function

End Class