#include PRGACNTs
#include APPS.TBXWeb
 
	// Munt pariteit tov. de EURO. 
	// Om een bedrag in EUR om te zetten naar de de resp. munt :  bedrag / MuntPar 
GetMuntPar(Munt) 
	Quit:(Munt="CHF") $$$MuntParCHF
	Quit 1
PrijsConvert(Munt,Prijs)
	Quit:(Munt="")||(Munt="EUR") Prijs
	Quit Prijs/$$GetMuntPar(Munt)
 
	// GetUserMunt is DEPRECATED.  
	// Use method TBXContext.GeefUserMuntEenheid(VERW) 
	// 
	// Deze implementatie blijft enkel staan voor Backward compatibility 
GetUserMunt(sDomVERW,VERW)
	Quit $S($G(VERW)="VHEPN":"EUR", sDomVERW="SFS":"CHF", 1:"EUR")
 
 
AppIsEnabled(App,SubApp,IPAddress)
#define IP4   $P(IPAddress,".",4)
	Quit:('$D(^UI.Settings(App,SubApp))) 1   ; Enabled if global/nodes not defined
	New arEnable
	Merge arEnable=^UI.Settings(App,SubApp,"Enable")
	Quit:($G(arEnable("ALL"),1)) 1           ; Enabled for all users
	Quit:($G(arEnable("IP",$$$IP4),0)) 1     ; internal IP address
	Quit:($G(arEnable("IP",IPAddress),0)) 1   ; any IP address
	Quit 0
	
RedirectPage(RedirURL)
	Set RedirURL=$G(RedirURL,"/Under Construction.htm")
	Set %response.Redirect=RedirURL
	;Set %response.ServerSideRedirect=RedirURL
	Quit
	
SesDataFromRq(SesKey,RqKey,DflVal)
	Set RqKey=$G(RqKey,SesKey)
	Quit $$SetSesData^cspBasis.Library($Name(%session.Data(SesKey)),$Name(%request.Data(RqKey,1)),.DflVal)
 
SesDataFromLocal(SesKey,Local,DflVal)
	Quit $$SetSesData^cspBasis.Library($Name(%session.Data(SesKey)),$Name(Local),.DflVal)
 
SetSesData(SesRef,NewValRef,DflVal)
	If $D(@NewValRef) Do
	. Set @SesRef=@NewValRef
	Else  Do
	. Set:('$$$aHasData(@SesRef)) @SesRef=$G(DflVal)
	Quit @SesRef
 
DataFromRqOrSes(RqKey,SesKey,DflVal)
	Set SesKey=$G(SesKey,RqKey)
	Quit $$drsGetData^cspBasis.Library($Name(%request.Data(RqKey,1)),$Name(%session.Data(SesKey)),.DflVal)
drsGetData(RqRef,SesRef,DflVal)   ; GetRqOrSesData
	Quit:($$$aHasData(@RqRef)) @RqRef
	Quit $G(@SesRef,$G(DflVal))
 
	
GetURLDomain()
    New ServName,ServPort
    Set ServName=$$$LCase($G(%request.CgiEnvs("SERVER_NAME")))
    Set ServPort=$G(%request.CgiEnvs("SERVER_PORT"),80)
    Set:(ServName="") ServName="www.tandem-box.com"
    Set:(ServPort'=80) ServName=ServName_":"_ServPort
	Quit ServName
 
TBXDomainCVT(Domain)
  #define DefaultDomain   $G(^Settings("TBX","DefaultDomain"),"www.tandem-box.com")
  #define OtherDomain     $G(^Settings("TBX","OtherDomain"),"www.optima-tbx.fr")
 ;#define OtherDomain     $G(^Settings("TBX","OtherDomain"),"www.tandem-box.com")
 
	Set Domain=$$$LCase(Domain)
	Set TestDomeinenOmzetten=##class(TECH.Config.ConfigMgr).Instance().GetBoolean("cspBasis.Library_TestDomeinenOmzetten")
	If TestDomeinenOmzetten {
 
		Quit:($$$Server="CACHE01"                               ) $S(Domain="cache01":$$$OtherDomain, 1:$$$DefaultDomain)   // Alleen voor Cache01 (Uitzondering) 
	
		Quit:(Domain="test.tandem-box.com"                      ) "www.tandem-box.com"
		Quit:(Domain="test.optima-tbx.fr"                       ) "www.optima-tbx.fr"
		Quit:(Domain="test.tandem-box.de"                       ) "tbx.tandem-box.de"
		Quit:(Domain="test.du-pont.be"                          ) "tbx.du-pont.be"
		Quit:(Domain="test.destil.nl"                           ) "tbx.destil.nl"
		Quit:(Domain="testhafele.tandem-box.com"                ) "hafele.tandem-box.com"
		Quit:(Domain="test.sfsunimarket.biz"                    ) "tbx.sfsunimarket.biz"
		Quit:(Domain="testtandembox.meubelbeslagholland.nl"     ) $$$TBoxWebDomeinMBHO
		;Quit:(Domain="testtandembox.hafele.be"                 ) $$$TBoxWebDomeinHFLB
 
		Quit:(Domain="localdev.tandem-box.com"                  ) "www.tandem-box.com"
		Quit:(Domain="localdev.optima-tbx.fr"                   ) "www.optima-tbx.fr"
		Quit:(Domain="localdev.tandem-box.de"                   ) "tbx.tandem-box.de"
		Quit:(Domain="localdev.du-pont.be"                      ) "tbx.du-pont.be"
		Quit:(Domain="localdev.destil.nl"                       ) "tbx.destil.nl"
		Quit:(Domain="localdev-hafele.tandem-box.com"           ) "hafele.tandem-box.com"
		Quit:(Domain="localdev.sfsunimarket.biz"                ) "tbx.sfsunimarket.biz"
		Quit:(Domain="localdev-tandembox.meubelbeslagholland.nl") $$$TBoxWebDomeinMBHO
		Quit:(Domain="localdev-tandembox.hafele.be"             ) $$$TBoxWebDomeinHFLB
	
		Quit:(Domain="demo.tandem-box.com"                      ) "demo.tandem-box.com"
		Quit:(Domain="demo.sfsunimarket.biz"                    ) "demo.sfsunimarket.biz"
		Quit:(Domain="192.168.1.67"                             ) $$$DefaultDomain
		Quit:(Domain="cache02"                                  ) $$$OtherDomain
	 
		Quit:(Domain="test.tandem-box.eu"                       ) "www.tandem-box.com"
		Quit:(Domain="195.130.157.3"                            ) "www.tandem-box.com"
	 
		Quit Domain
		;Quit $$$DefaultDomain
	}
	Else {
		Quit $P(Domain,":",1)   ; 2e piece is de HTTP-poort (indien aanwezig) 
	}
 
	Quit ""
 
 
	// SendMiniMail eXtended :
	// Replace the domain "vanhoecke.be" in <From> if <lbTo> also contains "vanhoecke.be" domain(s)
SendMiniMailXtd(From,lbTo,Subject,Body,BodyIsStream,Args6,Args7,Args8,lbAttachments,Args10)   ; ,Args11,Args12)
	#define MailsViaNotes01   1
	Do:('$$$MailsViaNotes01) smxSenderFakeDomain^vhLib.Mail(.From,lbTo,,)
	Quit $$SendMiniMail^vhLib.Mail(.From,.lbTo,.Subject,.Body,.BodyIsStream,.Args6,.Args7,.Args8,.lbAttachments,.Args10)   ; ,.Args11,.Args12)
	Quit ""
 
 
	/// Ophalen van de vertaalde waarde van de interne code en omzetten naar HTML-code.
	/// lbFlags om extra conversies te doen (zoals Uppercase, Lowercase, ...)
WebTextValue(VtlGroep,Intern,Taal,TextType,VervangWaarde,lbFlags)
	; Ter info:
	; lbFlags is optioneel (later toegevoegd). 
	; Is dus by default leeg ==> Immediate conversion to HTML (zoals voorheen)
	; Als lbFlags waarde(n) bevat ==> GetVertaling moet plainText teruggeven -> eerst conversie voor lbFlags -> dan convert to HTML
	Quit:($G(Intern)="") ""
	New Val,blnPlainText,ReturnsHTML,FlgItem
	Set Taal=$G(Taal,"N")
	Set TextType=$G(TextType,"L")
	Set lbFlags=$G(lbFlags,"")
	Set blnPlainText=(lbFlags'="")
	Set Val=##class(Res.Vertaling).GetVertalingPlus(VtlGroep,Intern,TextType,Taal,.VervangWaarde,blnPlainText,.ReturnsHTML)
	Quit:(Val="") Intern_" ("_TextType_"-"_Taal_")"
	; Else
	If $L(lbFlags) Do
	. Do wtvBeforeHTML   ; First item of lbFlags
	Quit $S($G(ReturnsHTML):Val, 1:$$ConvertToHTML^vhRtn1(Val))
wtvBeforeHTML
	Quit:($LG(lbFlags,1)="")
	Set FlgItem=$LG(lbFlags,1)
	If FlgItem="L"  Set Val=$$$LCase(Val)
	Else  If FlgItem="U"  Set Val=$$$UCase(Val)
	Else  If FlgItem="F"  Set Val=$$$FCase(Val)
	Else  If '$$$IsList(FlgItem)  Quit
	Else  If ($LG(FlgItem,1)="X")&&($L($LG(FlgItem,2))) Do
	. X "Set Val="_$$$Replace($LI(FlgItem,2),"%v","Val")
	Quit