KLBTW ;Klant BTW-Nummers [ 04/03/2002  3:54 PM ]
 Do INIT Quit:Datum'?4.N
 Do FETCH Quit:'$D(^HULP(%J))
 Do PRINT
 Kill ^HULP(%J)
 Quit
 
INIT Do:'$D(Q)
 .Set Q="K"
 .Do ^cA604
 Set %J=$$%J^vhRtn1()
 Kill ^HULP(%J)
 Write @F11,@F1,@FMTI,"Lijsten van nieuwe BTW-nummers - ",QN," ",@FMTi
 Set Datum=$$EXTDATE^vhDTyp($H,"MN")-1
 Set Datum=$$EXTDATE^vhDTyp($H,"J")_"."_$TR($J(Datum\3*3+1,2)," ","0")
 Set Datum=$$ASK^vhINP("Vanaf wijzigings datum : ",5,Datum,"","-[] = Exit")
 Quit:Datum="-"!(Datum=".")
 Set Datum=$$INTDATE^vhDTyp(Datum,"DM") Quit:Datum=""
 Set Datum=$$CALCDATE^vhDTyp(Datum,"M","FD")
 Quit
 
FETCH Set KLId=0
 Set FP=2401 Write @F,@FCH,"Klanten verwerkt : "
 Set (Cnt,SelCnt)=0,FP=2421
 For  Set KLId=$O(^KKL(KLId)) Quit:KLId=""  Do
 .Set Cnt=Cnt+1 If Cnt#10=0 Write @F,Cnt_"/"_SelCnt
 .Quit:$P(^KKL(KLId,2),D,23)<Datum
 .Set KLNr=$P(^KKL(KLId,0),D)
 .Quit:'$D(^KK1(KLNr))
 .Quit:($P(^KKL(KLId,1),D,11)="Consument")
 .Quit:($P(^KKL(KLId,1),D,11)="Relatie")
 .Do FETCHKL^UTILI(KLNr)
 .Set Land=$$LAND^vhRtn1($P(B(1),D,8))
 .Quit:Land="BE"
 .Set ^HULP(%J,Land_" "_KLId)=$P(B(1),D,1,7)_D_Land_D_$P(B(1),D,16)
 .Set SelCnt=SelCnt+1
 Set FP=2301 Write @F,@F1,@FCS
 Quit
 
PRINT Do INIT^PROC("KLBTW")
 Set Land=$P($O(^HULP(%J,""))," ")
 Set KLBTW(11)="Controle van nieuwe BTW nummers"_D_$$LAND^vhRtn1(Land,2,"N")
 Set KLBTW(10)="CB^KLBTW"
 Do PRINT^OUTPUT(.KLBTW,"P","S;B")
 Quit
 
CB(Ref) 
 New RefLand
 Quit:Ref?1A ""
 Set RefLand=$$LAND^vhRtn1($P(@Ref,D,8))
 If RefLand'=Land Do  Quit "PB\;"
 .Set Land=RefLand
 .Set $P(sTitel,D,2)=$$LAND^vhRtn1(Land,2,"N")
 Quit ""