; Via onderstaande labels worden de properties gelinked (gemapped) met de global ^KPR
	; "prop"_PropName  --> ;Node;Piece  van ^KPR(PRNr)
	
propGAProdID	                ;G;13
propKortTekst	              ;0;1
propCifPPL	                 ;J;23
propLijstPrijs	             ;J;25
propLEVNr	             ;J;1
propVerpakProduct	             ;J;32
propVerpakQty	             ;J;33
propStock	             ;1;20
PropOpslagZone			;2;15
propKlasHoofdGroep	                 ;I;1;$E(Val,1,4)
propKlasGroep	                 ;I;2;$E(Val,5,9)
propKlasSubGroep	                 ;I;3;$E(Val,10,18)
propHFReservatie	         ;@;$P(^PRSTOCK("D",PRNr),"\",6)
propHFVoorraad	             ;@;$P(^PRSTOCK("D",PRNr),"\",5)
propHFHerbestelWijze	       ;15;3
propHFHerbestelPunt	        ;15;4
propHFHerbestelAantal	      ;15;5
propHFHerbestelAfr	         ;15;6
propHFNettoLengte	          ;15;7
propHFBrutoLengte	          ;15;8
propHFEenheid	              ;15;9
propHFMetaTag	              ;15;10
propHFDefMagazijn	          ;15;11
propHFSubMagazijn	          ;15;12
propNettoGewicht	           ;X;$LI($$gpvGewicht(PRNr),1)
propTarraGewicht	           ;X;$LI($$gpvGewicht(PRNr),2)
propBrutoGewicht	           ;X;$LI($$gpvGewicht(PRNr),3)
propGENTYPFG	                       ;X;$$gpvGENTYPShort(PRNr)
propGENTYP	                 ;X;$$gpvGENTYP(PRNr)
propKindMoeder	                 ;@;$S($D(^PRLINK("D",PRNr)):"M",$D(^PRLINK("IK",PRNr)):"K",1:"E")
propProductGroep	                 ;X;$$gpvProdGrp(PRNr)
	
GetPropViaNr()	  ; Parameters: PRNr,PropName
	Quit:(PRNr="") ""
	New Txt,Key,Val
	Set Txt=$T(@("prop"_PropName))
	Quit:(Txt="") "#Onbekend property "_PropName_"#"
	Quit:('$D(^KPR(PRNr))) "#Onbekend product "_PRNr_"#"
	Set Key=$P(Txt,";",2)
	If (Key="@")||(Key="X") Do  Quit Val
	. X "Set Val="_$P(Txt,";",3,99)
	Set:("I;J"[Key) Key=$O(^KPR(PRNr,Key))
	Quit:("I;J"[$P(Txt,";",2))&&($E(Key)'=$P(Txt,";",2)) "#Ontbrekende node "_$P(Txt,";",2)_"#"
	If $P(Txt,";",4)="" Quit $P($G(^KPR(PRNr,Key)),"\",$P(Txt,";",3))
	Else  Do
	. Set Val=$P($G(^KPR(PRNr,Key)),"\",$P(Txt,";",3))
	. X "Set Val="_$P(Txt,";",4,99)
	Quit Val
	
SetPropViaNr()	  ; Parameters: PRNr,PropName,Val
	Quit:(PRNr="") 1
	Quit:('$D(Val)) 1
	New Txt,Key
	Set Txt=$T(@("prop"_PropName))
	Quit:(Txt="") "#Onbekend property "_PropName_"#"
	Quit:('$D(^KPR(PRNr))) "#Onbekend product "_PRNr_"#"
	Set Key=$P(Txt,";",2)
	Quit:(Key="X") 0
	If (Key="@") Do  Quit 1
	. X "Set "_$P(Txt,";",3,99)_"=Val"
	Set:("I;J"[Key) Key=$O(^KPR(PRNr,Key))
	Quit:("I;J"[$P(Txt,";",2))&&($E(Key)'=$P(Txt,";",2)) "#Ontbrekende node "_$P(Txt,";",2)_"#"
	Set $P(^KPR(PRNr,Key),"\",$P(Txt,";",3))=Val    
	Quit 1
	
	
gpvGewicht(PRNr)	
	Quit:(PRNr="") ""
	New ID,BLRec,BG,NG
	If $D(^KPR(PRNr,"J5005")) Do  ; een BLUM product
	. Set ID=$TR($P(^KPR(PRNr,2),"\",25),".","")
	. Set $E(ID)=0
	. Set BLRec=$G(^BLProd("D",ID)) 
	. Set BG=$P(BLRec,"\",9)
	. Set NG=$P(BLRec,"\",26)
	If $G(NG)="" Set (BG,NG)=$P($G(^KPR(PRNr,1)),"\",13) ; Indien niet gedefinierd
	Quit $LB(NG, BG-NG, BG)
	
gpvGENTYPShort(PRNr)
	; Geeft enkel FabGrp terug
	New GenPRNr
	Set GenPRNr=$P(^KPR(PRNr,0),"\",3)
	Quit:(GenPRNr="") ""
	Set:GenPRNr'?4.7N GenPRNr=PRNr ; het is reeds het generisch product
    Quit $P($G(^KPR(GenPRNr,"G")),"\",1,3)
 
gpvGENTYP(PRNr)	
         New Typ,GenPRNr,SubGrp
         Set GenPRNr=$P($G(^KPR(PRNr,0)),"\",3)
         Quit:GenPRNr="" ""
         Set:GenPRNr'?4.7N GenPRNr=PRNr ; het is reeds het generisch product
         Set Typ=$P($G(^KPR(GenPRNr,"G")),"\",1,3)
         Set SubGrp=$P($G(^KPR(PRNr,"G")),"\",3)
         Set:$L(SubGrp)=3 $P(Typ,"\",2)=SubGrp
         Quit Typ  ;FabGrp\FabSubGrp\BarcodeBegin
         	
gpvProdGrp(PRNr)
	    New Groep,GenTyp,Key
	    Set LevNr=$E($O(^KPR(PRNr,"J")),2,5)
	    If LevNr=5005 Quit "BLUM"
	    If LevNr=6502 Quit "GRP"
	    If LevNr=6332 Do  Quit Groep  ; HALUX
	    .Set Groep="HAL"
	    .Set GenTyp=$$gpvGENTYP(PRNr)
	    .If GenTyp["GRP" Set Groep="GRP"
	    .If GenTyp["TBX" Set Groep="TBX"
	    Set Key=$O(^KPR(PRNr,"I"))
	    If $E(Key)="I",$P(^KPR(PRNr,Key),"\")["OL" Quit "OL"
	    Quit "REST"