PVKADLean
#include Prod.Product
 
test
	Set Dev=0
	Set Dev=$$OPEN^vhDEV(,"KAD Kenmerken.txt","W")
	Use Dev
	Do WriteTitel
	Do WriteOne(430360,"",1)
	Do WriteOne(409118,"",1)
	Do WriteOne(267202,"",1)
	Do WriteOne(447419,"",1)
	Do WriteOne(190266,"",1)
	Close:0'[Dev Dev
	q
 
Lijst
	Set Dev=0
	Set Dev=$$OPEN^vhDEV(,"KAD Kenmerken.txt","W")
	Use Dev
	Do WriteTitel
	Set VanWeek=$$CALCDATE^vhDTyp($H,"W",-4,"FD")
	Set TotWeek=$$CALCDATE^vhDTyp($H,"W",-1,"LD")
	Set PRNr=0
	For  Set PRNr=$O(^KPR(PRNr)) Quit:PRNr=""  Do
	. Set lbKenm=""
	. Quit:$P($$GENTYP^HAD(PRNr),"\",1,2)'="KAD\"
	. For Week=VanWeek:7:TotWeek Do
	. . Do HISTO^STAT(PRNr,Week,Week+6,"I","M",.Cumul,.Aantal) 
	. . Quit:'Aantal
	. . Do WriteOne(PRNr,Week,Aantal)
	Close:0'[Dev Dev
	Quit
	
WriteTitel
	Write $TR("PRNr,ProdNm,Week,Aantal",",",$c(9))
	Write $TR(",ProfType,ProfAfw,MaxLen,MaxCode,MinLen,MinCode,IsOmManteld,IsKleef,ControleZijde,IsTranspVul,Verpak",",",$c(9))
	Write $TR(",KalQty,ProfLeg,ProfKantel,ToolWisselQty,BorQtyK,BorQtyG,GlasBorQty",",",$c(9))
	Write !
	Quit
 
WriteOne(PRNr,Week,Aantal)	
	Do GetOne(PRNr,1,.lbKenm,.lbBor) ; 1 of Aantal , belangrijk voor frezen
	Quit:lbKenm=""
	Write PRNr,*9,$$$PRGet($$$KortTekst),*9,$$EXTDATE^vhDTyp(Week,"DK"),*9,Aantal
	Write *9,$$ListToPieces^vhLib(lbKenm,$C(9))
	Write *9,$$ListToPieces^vhLib(lbBor,$C(9))
	Write !
	Quit
GetOne(PRNr,Aantal,lbKenm,lbBor)
	Set lbKenm=""
	Set KadNr=$P($G(^KPR(PRNr,"G")),"\",13)
	Quit:KadNr'?1.7N
	Set oKad=##class(Prod.GADef.KaderDeur).%OpenId(KadNr)
	;w oKad.%Id()
	Quit:'$isObject(oKad)
	Set lbKenm=$$GetKenmerken(oKad)
	Quit:lbKenm=""
	Set lbBor=$$GetBoringen(oKad,Aantal)
	Quit
	
GetKenmerken(oKad)
	; . . . Set Hoogte=$LG(##class(Prod.Kenmerk.DataDefinitie).Get("KAD",PRNr,"PH"))
	
	Set MaxLen=$S(oKad.Breedte>oKad.Hoogte:oKad.Breedte,1:oKad.Hoogte)\1
	Set MaxCode=$S(MaxLen<600:"K",MaxLen<1600:"M",1:"G")
	Set MinLen=$S(oKad.Breedte<oKad.Hoogte:oKad.Breedte,1:oKad.Hoogte)\1
	Set MinCode=$S(MinLen<600:"K",MinLen<1600:"M",1:"G")
	Set ProfType=$P(oKad.ProfTypeGetObjectId(),"||",2)
	Set ProfAfw=$P($P(oKad.ProfAfwGetObjectId(),"||",2),"-",2)
	Set IsOmmanteld=ProfAfw'?1(1"EV",1"IL")
	Set IsKleef=ProfType?1(1"PBK",1"PB9")
	Set ControleZijde=$S(ProfType?1(1"PBK",1"PB9"):1,ProfType?1(1"PBG",1"PSG"):3,1:2)
	Set Vulling=$P(oKad.VullingGetObjectId(),"||",2)
	Set IsTranspVul=+$S(Vulling="":"",1:$P($G(^RES("HAD","PI","VULLING","D",Vulling)),"`",5))
	Set MonType=$S(IsKleef:1,IsTranspVul&&(ProfType?1(1"PBG",1"P05",1"PSG")):2,1:3)
	Set Verpak=oKad.Verpakking
	Set lbKenm=$LB(ProfType,ProfAfw,MaxLen,MaxCode,MinLen,MinCode,IsOmmanteld,IsKleef,ControleZijde,MonType,Verpak)
	Quit lbKenm
	
GetBoringen(oKad,Aantal)
	Kill %FRZ
	Set lbBor=oKad.BoringLoopList(MaxLen,Aantal) ; samenvatting van de boringen
	;zw %FRZ
	Set KalQty=0,Key="" 
	For  Set Key=$O(%FRZ("KaliberNew",Key)) Quit:Key=""  Set KalQty=KalQty+%FRZ("KaliberNew",Key)
	
	Set BorQtyG=0,BorQtyK=0,Key="" 
	For  Set Key=$O(%FRZ("ProfGatenQty",Key)) Quit:Key=""  Set BorQtyK=BorQtyK+$G(%FRZ("ProfGatenQty",Key,"K")) Set BorQtyG=BorQtyG+$G(%FRZ("ProfGatenQty",Key,"G"))
	
	Set ToolWisselQty=0,Key="" 
	For  Set Key=$O(%FRZ("ProfWisselQty",Key)) Quit:Key=""  Set ToolWisselQty=ToolWisselQty+$G(%FRZ("ProfWisselQty",Key))
	
	Set ProfLeg=$G(%FRZ("ProfCnt"))
	Set GlasBorQty=$G(%FRZ("QtyGlasBoor"))
	
	Set ProfKantel=9999,Key="",KalCnt=0
	For  Set Key=$O(%FRZ("ProfQty",Key)) Quit:Key=""  Set KalCnt=KalCnt+1 Set:%FRZ("ProfQty",Key)<ProfKantel ProfKantel=%FRZ("ProfQty",Key) ; minimum
	Set:ProfKantel=9999 ProfKantel=""
	Set:KalCnt<2 ProfKantel=""
	
	Set lbBor=$LB(KalQty,ProfLeg,ProfKantel,ToolWisselQty,BorQtyK,BorQtyG,GlasBorQty)
	
	Quit lbBor