cwXML
 Quit
 
TEST
 New Data
 Write @F11,@F1
 
 ; Firmagegevens
 Set Data("FAdres")="EUROPARK - NOORD   9"
 Set Data("FTel")=" (32-3) 760.19.00"
 Set Data("FFax")=" (32-3) 760.19.19"
 Set Data("FWoonpl")="B-9100  SINT-NIKLAAS"

 ; Klantgegevens
 Set Data("Aan")="N.V. VAN HOECKE"
 Set Data("Tav")="Wim Vermeulen"
 Set Data("Fax")="03-760 19 19"
 Set Data("Betreft")="Test remboursleveringen"
 Set Data("Datum")="Woensdag, 02-Feb-05"
 Set Data("Van")="Christiaan Willems"
 Set Data("Pages")=0
 Set Data("Taal")="N"
 Set Data("Body","Paragraaf",1)="Tekst(DevObj,.Data,1)"
 Set Data("Body","Paragraaf",2)="Transport(DevObj,.Data)"
 Set Data("Body","Paragraaf",3)="MVRGR(DevObj,.Data)"
 ;Set Data("Body","Paragraaf",4)="HOOGACHTEND(DevObj,.Data)"
 Set Data("Body","Tekst",1,1)="Geachte klant,"
 Set Data("Body","Tekst",1,2)=""
 Set Data("Body","Tekst",1,3)="Vriendelijk verzoek volgende bedrag(en) bij levering te betalen."
 Set Data("Body","Transport",1)="Door onze diensten"
 Set Data("Body","Transport",1,1)="339401\3525.09\EUR"
 Set Data("Body","Transport",1,2)="339175\239.52\EUR"
 Set Data("Body","Transport",2)="Per expediteur"
 Set Data("Body","Transport",2,1)="371591\222.34\EUR"
 
 Set DevObj=$$OPEN^vhDEV(,"WinV.Txt","W")
 Use DevObj
 Do FAX(DevObj,.Data)
 Close DevObj
 Quit
 
FAX(DevObj,Data)
 Set DevObj=$G(DevObj,0)
 Do DOCUMENT(DevObj,.Data)
 Quit
 
DOCUMENT(DevObj,Data)
 Do BEGINTAG^XMLWRITE(DevObj,"DOCUMENT")
 Do TYPE(DevObj)
 Do LOGO(DevObj)
 Do HEADER(DevObj,.Data)
 Do BODY(DevObj,.Data)
 Do FOOTER(DevObj)
 Do ENDTAG^XMLWRITE(DevObj,"DOCUMENT")
 Quit
 
TYPE(DevObj)
 Do TAGWRITE^XMLWRITE(DevObj,"TYPE","TELEFAX")
 Do WRITELN^XMLWRITE(DevObj)
 Quit
 
LOGO(DevObj)
 Do TAGWRITE^XMLWRITE(DevObj,"LOGO","Groot logo")
 Quit
 
HEADER(DevObj,Data)
 Do BEGINTAG^XMLWRITE(DevObj,"HEADER")
 
 Do TAGWRITE^XMLWRITE(DevObj,"NAME_TO",Data("Aan"))
 Do TAGWRITE^XMLWRITE(DevObj,"PERSON_TO",Data("Tav"))
 Do TAGWRITE^XMLWRITE(DevObj,"FAX",Data("Fax"))
 Do TAGWRITE^XMLWRITE(DevObj,"ABOUT",Data("Betreft"))
 Do TAGWRITE^XMLWRITE(DevObj,"DATE",Data("Datum"))
 Do TAGWRITE^XMLWRITE(DevObj,"FROM",QN_" - "_Data("Van"))
 Do TAGWRITE^XMLWRITE(DevObj,"PAGECNT",$G(Data("Pages"))+1_" ("_$$TXT("Incl",,Data("Taal"))_")")
 
 Do ENDTAG^XMLWRITE(DevObj,"HEADER")
 Do WRITELN^XMLWRITE(DevObj)
 Quit
 
BODY(DevObj,Data)
 New Paragraaf
 Do BEGINTAG^XMLWRITE(DevObj,"BODY")
 Set Paragraaf=""
 For  Set Paragraaf=$O(Data("Body","Paragraaf",Paragraaf)) Quit:Paragraaf=""  Do @Data("Body","Paragraaf",Paragraaf)
 Do ENDTAG^XMLWRITE(DevObj,"BODY")
 Do WRITELN^XMLWRITE(DevObj)
 Quit
 
 ; Bodyparagraaf "Afsluiting (met vriendelijke groeten)"
MVRGR(DevObj,Data)
 ;Do TAGWRITE^XMLWRITE(DevObj,"TEXT",$$TXT("MVrGr",,Data("Taal"))_",")
 Do BEGINTAG^XMLWRITE(DevObj,"SIGNATURE")
 Do TAGWRITE^XMLWRITE(DevObj,"SIGNER",QN)
 Do TAGWRITE^XMLWRITE(DevObj,"DIGISIGN","Handtekening")
 Do TAGWRITE^XMLWRITE(DevObj,"NAME",Data("Van"))
 Do ENDTAG^XMLWRITE(DevObj,"SIGNATURE")
 Do WRITELN^XMLWRITE(DevObj)
 Quit
 
 ; Bodyparagraaf "Afsluiting (hoogachten)"
HOOGACHTEND(DevObj,Data)
 ;Do TAGWRITE^XMLWRITE(DevObj,"TEXT",$$TXT("HgAcht",,Data("Taal"))_",")
 Do BEGINTAG^XMLWRITE(DevObj,"SIGNATURE")
 Do TAGWRITE^XMLWRITE(DevObj,"SIGNER",QN)
 Do TAGWRITE^XMLWRITE(DevObj,"DIGISIGN","Handtekening")
 Do TAGWRITE^XMLWRITE(DevObj,"NAME",Data("Van"))
 Do ENDTAG^XMLWRITE(DevObj,"SIGNATURE")
 Do WRITELN^XMLWRITE(DevObj)
 Quit
 
 ; 
FOOTER(DevObj)
 Do BEGINTAG^XMLWRITE(DevObj,"FOOTER")
 Do ENDTAG^XMLWRITE(DevObj,"FOOTER")
 Do WRITELN^XMLWRITE(DevObj)
 Quit

 ; Bodyparagraaf "Tekst"
Tekst(DevObj,Data,Item)
 New I
 For I=1:1 Quit:'$D(Data("Body","Tekst",Item,I))  Do
 . Do TAGWRITE^XMLWRITE(DevObj,"TEXT",Data("Body","Tekst",Item,I))
 Quit
 
 ; Bodyparagraaf "Transport"
Transport(DevObj,Data)
 New Item
 Do BEGINTAG^XMLWRITE(DevObj,"TRANSPORT")
 Set Item=""
 For  Set Item=$O(Data("Body","Transport",Item)) Quit:Item=""  Do TransportItem(DevObj,.Data,Item)
 Do ENDTAG^XMLWRITE(DevObj,"TRANSPORT")
 Do WRITELN^XMLWRITE(DevObj)
 Quit
 
 ; Transportparagraaf "Item"
TransportItem(DevObj,Data,Item)
 New ItemNr,BONNr,Rembours,Totaal,Munt
 Do BEGINTAG^XMLWRITE(DevObj,"ITEM")
 Do TAGWRITE^XMLWRITE(DevObj,"VERZENDWIJZE",Data("Body","Transport",Item))
 Do BEGINTAG^XMLWRITE(DevObj,"LEVERINGEN")
 Set ItemNr="",Totaal=0
 For  Set ItemNr=$O(Data("Body","Transport",Item,ItemNr)) Quit:ItemNr=""  Do
 . Set BONNr=$P(Data("Body","Transport",Item,ItemNr),D)
 . Set Rembours=$P(Data("Body","Transport",Item,ItemNr),D,2)
 . Set Munt=$P(Data("Body","Transport",Item,ItemNr),D,3)
 . Set Totaal=Totaal+Rembours
 . Do BEGINTAG^XMLWRITE(DevObj,"LEVERING")
 . Do TAGWRITE^XMLWRITE(DevObj,"BONNR",$$EXTNUM^vhDTyp(BONNr,0,".",0))
 . Do TAGWRITE^XMLWRITE(DevObj,"REMBOURS",$$EXTNUM^vhDTyp(Rembours,0,".T",2))
 . Do ENDTAG^XMLWRITE(DevObj,"LEVERING")
 Do TAGWRITE^XMLWRITE(DevObj,"TOTAAL",$$EXTNUM^vhDTyp(Totaal,0,".T",2))
 Do TAGWRITE^XMLWRITE(DevObj,"MUNT",Munt)
 Do ENDTAG^XMLWRITE(DevObj,"LEVERINGEN")
 Do ENDTAG^XMLWRITE(DevObj,"ITEM")
 Do WRITELN^XMLWRITE(DevObj)
 Quit
 
 ; Ophalen taalafhankelijke tekst
TXT(Ref,Piece,Taal) 
 If '$D(Piece) Set Piece=2
 Quit $P($P($T(@("T"_Ref)),U,Piece),D,$F("NFDE",Taal)-1)
 ;
TFAX	;TELEFAX\TELEFAX\TELEFAX\TELEFAX
TVerv	;vervolg\suite\fortsetzung\continue
TAan	;Aan\A\An\To
TTav	;T.a.v.\A l'att.\z. Hd.\Attn.
TAank	;Aankoopdienst\Service achats\Ankauf\Purchase department
TVerk	;Verkoopdienst\Service de vente\Verkauf\Sales department
TBetr	;Betreft\Concernant\Betrifft\Concerning
TDate	;Datum\Date\Datum\Date
TVan	;Van\De\Von\From
TPages	;#Pag(s)\#Pag(s)\#Pag(n)\#Pag(s)
TIncl	;incl. dit blad\incl. cette page\incl. diese Seite\incl. this page
TOnze	;onze\notre\unser\our;ons\notre\unser\our
TTekst	;Tekst\Tekst\Tekst\Tekst
TKlant	;klant\client\Kunde\customer
TLever	;
TMVrGr	;Met vriendelijke groeten\Meilleures salutations\Mit freundlichen Grüßen\Kind regards
THgAcht	;Hoogachtend\Avec nos salutations distinguées\Hochachtungsvoll\Yours faithfully