#include vhLib.Macro
 
 
ExecQuery(Query)
	DO DISABLE^%NOJRN
	do StartTimer^vhLib
	new rs set rs = ##class(%ResultSet).%New("%DynamicQuery:SQL")
	do rs.Prepare(Query)
	do rs.Execute()
	do StopTimer^vhLib
	set rs = ""
    do ##class(zStressTest.StressTest).StoreInterval("W",$piece(Query," ",1),$$GetInterval^vhLib())
	quit
 
MergeData(ClassNr)
	DO DISABLE^%NOJRN
	do StartTimer^vhLib
	set FromGlobal = "^zStressTest.PopClass"_ClassNr_"D"
	set ToGlobal = "^zStressTest.PopClass"_ClassNr_"DBackup"
	Merge @ToGlobal=@FromGlobal
	Kill @ToGlobal
	do StopTimer^vhLib
    do ##class(zStressTest.StressTest).StoreInterval("W","Merging "_ClassNr,$$GetInterval^vhLib())
	quit
 
ExecSelectQuery(Query)
	do StartTimer^vhLib
	new rs ,id,ctr
	set rs = $$ExecDynQuery^vhQUERYLIB(Query)
	while rs.Next() { 
		set id = rs.GetData(1)
		set ctr=$i(ctr)
	 }
	do StopTimer^vhLib
	set rs = ""
    do ##class(zStressTest.StressTest).StoreInterval("R",$piece(Query," ",1)_"(# "_+$get(ctr)_")",$$GetInterval^vhLib())
	quit
		
 
PopulateData(ClassNr,Amount)
	DO DISABLE^%NOJRN
	do StartTimer^vhLib
	set Class = "zStressTest.PopClass"_ClassNr
    do $zobjClassMethod(Class,"Populate",Amount)
    do StopTimer^vhLib
    do ##class(zStressTest.StressTest).StoreInterval("W","Populate Class"_ClassNr_" : "_Amount,$$GetInterval^vhLib())
    
	quit
 
 
ReadGlobals(Namespace,Prefix)
	
	new CurrentNamespace
	set CurrentNamespace = $$$NSpace
	
	;znspace Namespace
	;set Prefix="^K"
	
	new Global,QGlobal,Data
	do StartTimer^vhLib
	
	set Global=Prefix
	for { set Global = $order(^$GLOBAL(Global)) quit:('$$$StartsWithVar(Global,Prefix))
		write Global,!
		set QGlobal=Global
		for  { set QGlobal = $query(@QGlobal) quit:QGlobal=""  
			set Data = $get(@QGlobal)
		}
	}
	do StopTimer^vhLib
	
	znspace CurrentNamespace
	
	do ##class(zStressTest.StressTest).StoreInterval("R","Lezen globals "_Prefix,$$GetInterval^vhLib())
	
	
	
	quit