ATKERROR ; Afstand-toegang voor klanten [ 05/31/2002  8:46 AM ]
 ;
ERROR 
 Set ErrDate=$P($H,","),ErrTime=$P($H,",",2)
 If $ZE["<NOSYS>" Do
 .Do NOJOB^ATK
 Else  If $L($G(UserName)) Do
 .Job REMERROR^ATKJOB($ZE,ErrDate,ErrTime,KLNr,UserName,WachtW)::LTimeOut
 .Do LOGOFF^ATKLOGOF(1)
 .Set FP=201
 .Write @F,@F1
 .If Taal="" Do
 ..Do WRITETXT^ATK("ATK","ERROR1","N",10),WRITETXT^ATK("ATK","ERROR2","N",11)
 ..Do WRITETXT^ATK("ATK","ERROR1","F",13),WRITETXT^ATK("ATK","ERROR2","F",14)
 .If $L(Taal) Do WRITETXT^ATK("ATK","ERROR1",Taal,12),WRITETXT^ATK("ATK","ERROR2",Taal,13)
 Else  Do
 .Set FP=201
 .Write @F,@F1
 .Do WRITETXT^ATK("ATK","ERROR1","N",10),WRITETXT^ATK("ATK","NOLOGON2","N",11)
 .Do WRITETXT^ATK("ATK","ERROR1","F",13),WRITETXT^ATK("ATK","NOLOGON2","F",14)
 Do SAVELOC
 Do CLEAN^ATK
 Do VT520^ATK()
 Halt
 ;
SAVELOC 
 Quit:$ZU(5)'="LVH,ATK"
 Set %("N")=$$NEXTID(),%("C")=0,%("L")="%"
 Set ^ERROR(%("N"))=$H_"\"_$J_"\"_$I_"\"_$ZE
 For  Set %("L")=$O(@%("L")) Quit:%("L")=""  Do
 .If $D(@%("L"))#10 Set %("C")=%("C")+1,^ERROR(%("N"),%("C"))=%("L"),^ERROR(%("N"),%("C")+.1)=@%("L")
 .Set %("Q")=%("L")
 .For  Set %("Q")=$Q(@%("Q")) Quit:%("Q")=""  Do
 ..Set %("C")=%("C")+1,^ERROR(%("N"),%("C"))=%("Q"),^ERROR(%("N"),%("C")+.1)=@%("Q")
 Quit
 ;
NEXTID() 
 New ErrorId
 Set ErrorId=$G(^ERROR(0))+1,^ERROR(0)=ErrorId
 Quit ErrorId
 ;
FETCHLOC(Error) 
 Kill %
 Set %("N")=$G(Error) Set:'%("N") %("N")=$$FETCHID()
 If %("N"),$D(^|"LVH,ATK"|ERROR(%("N"))) Do
 .Kill (%)
 .Set %("C")=1
 .For  Set %("C")=$O(^|"LVH,ATK"|ERROR(%("N"),%("C"))) Quit:%("C")=""  Do
 ..If '(%("C")#1) Set %("L")=^|"LVH,ATK"|ERROR(%("N"),%("C")),@%("L")=^|"LVH,ATK"|ERROR(%("N"),%("C")+.1)
 .Set %=^|"LVH,ATK"|ERROR(%("N"))
 .Set %=$$EXTDATE^vhLib.DataTypes($P(%,"\"))_"\"_$$EXTTIME^vhLib.DataTypes($P(%,"\"))_"\Job "_$P(%,"\",2)_"\Dev "_$P(%,"\",3,4)
 Kill %("C"),%("L"),%("N")
 Quit
 ;
FETCHID() 
 New
 Set D="\",U=";",(Q,QN)=""
 If $ZU(5)'="LVH,ATK" Do MASTER^cQ5
 Do INIT^vhTERMINA
 Set sScr("VT")=1
 Set (I,DevTyp)="ATK"
 For  Set I=$O(^vhDEV(I)) Quit:$E(I,1,$L(DevTyp))'=DevTyp  Set @($E(I,$L(DevTyp)+1,9))=^(I)
 Write @F11,@F1,@FMTI," VHISIE Foutbehandeling ",@FMTi
 Do INIT^PROC("ATKERROR","LD"),WL^PROC
 For  Do  Quit:R="ENTER"!(R="-")
 .Do SL^ATK
 .If R="V" Do
 ..Do DELETE^PROC3
 ..If $O(^|"LVH,ATK"|ERROR(0))="" Kill ^|"LVH,ATK"|ERROR(0)
 ..Else  Set ^|"LVH,ATK"|ERROR(0)=$O(^|"LVH,ATK"|ERROR(""),-1)
 Set:R="ENTER" R=LD(6)
 Quit R
 ;