ATKJOB3 ; Afstand-toegang voor klanten [ 05/31/2002   9:21 AM ]
 Quit
 ;
KLREF(JobNr,KLNr) 
 New D,U,Q,I,R,Count,KortText,DataRef,PRNr,IDNr,Pakket,PakNr,PakOms,Aantal,BLKLNr
 Quit:'$G(^ATK(0,0,"A"))
 Do INIT^ATKJOB
 Set Count=0,DataRef="KLREF",Pakket="",BLKLNr=$G(^BLBeri("IK",KLNr))
 For  Set Pakket=$O(^PAKKET("IK",KLNr,Pakket)) Quit:Pakket=""  Do
 .Set PakNr=^PAKKET("IK",KLNr,Pakket),R=^PAKKET("D",PakNr),PakOms=$P(R,D,2),PRNr=""
 .For  Set PRNr=$O(^PAKKET("D",PakNr,PRNr)) Quit:'PRNr  Do
 ..Quit:'$D(^KPR(PRNr))
 ..Set Aantal=$P(^PAKKET("D",PakNr,PRNr),D),KortText=$P(^KPR(PRNr,0),D)
 ..Set R=PRNr_D_PakOms_D_KortText_D_Aantal_D_PakNr_D_PakOms
 ..Do PUTHULP^ATKJOB(DataRef,R)
 ..Set ^HULP(JobNr,"KLREF","PAKNR",PakNr,PRNr)=Count
 ..Set ^HULP(JobNr,"KLREF","PRNR",PRNr,PakNr)=Count
 ..Set PakOms=""
 ..If BLKLNr Do
 ...Set IDNr=$P(^KPR(PRNr,2),D,25)
 ...New PRNr
 ...Quit:$E(IDNr)'=7
 ...Set $E(IDNr)=0,IDNr=$$TRIMN^vhRtn1(IDNr)_" "
 ...Set PRNr=$P($G(^KPR2(IDNr)),D)
 ...Quit:'PRNr
 ...Set KortText=$P(^KPR(PRNr,0),D)
 ...Set R=PRNr_D_PakOms_D_KortText_D_Aantal_D_PakNr_D_PakOms
 ...Do PUTHULP^ATKJOB(DataRef,R)
 ...Set ^HULP(JobNr,"KLREF","PAKNR",PakNr,PRNr)=Count
 ...Set ^HULP(JobNr,"KLREF","PRNR",PRNr,PakNr)=Count
 Merge ^HULP(JobNr,"KLREF","INDEX")=^PAKKET("IK",KLNr)
 Do PUTHULP^ATKJOB(DataRef)
 Quit
 ;
MERGE(JobNr,KLNr,%J) 
 New D,U,Q,I,R
 Do INIT^ATKJOB
 Kill ^HULP(%J,"NEWKLREF")
 Merge ^HULP(%J,"NEWKLREF")=^HULP(JobNr,"NEWKLREF")
 If $D(^HULP(%J,"NEWKLREF")) Set ^HULP(%J,"NEWKLREF")=KLNr
 Quit
 ;
VERWERK(%J) 
 New D,U,Q,I,R,KLNr,PRNr,PakNr,OldKlRef,KlRef,Quit
 Do INIT^ATKJOB
 Set KLNr=^HULP(%J,"NEWKLREF"),PRNr=""
 For  Set PRNr=$O(^HULP(%J,"NEWKLREF",PRNr)) Quit:'PRNr  Do
 .Set R=^HULP(%J,"NEWKLREF",PRNr),OldKlRef=$P(R,D),KlRef=$P(R,D,2),PakNr="",Quit=0
 .For  Set PakNr=$O(^PAKKET("IP",PRNr,KLNr,PakNr)) Quit:'PakNr  Do  Quit:Quit
 ..Set R=$G(^PAKKET("D",PakNr))
 ..Quit:$P(R,D,2)'=OldKlRef  Quit:$P(R,D,3)'="E"
 ..Set Quit=1
 .If PakNr Do
 ..Set R=$$UPTRIMAN^vhRtn1(OldKlRef)
 ..Kill ^PAKKET("IK",KLNr,R)
 .Else  Set PakNr=$$NEXTID^PAKKET()
 .Set R=$G(^PAKKET("D",PakNr)) Set:R="" R=KLNr_"\\E\\" Set $P(R,D,2)=KlRef,^PAKKET("D",PakNr)=R
 .Set R=$G(^PAKKET("D",PakNr,PRNr)) Set:R="" R="1\\" Set ^PAKKET("D",PakNr,PRNr)=R
 .Set R=$$UPTRIMAN^vhRtn1(KlRef),^PAKKET("IK",KLNr,R)=PakNr
 .Set ^PAKKET("IP",PRNr,KLNr,PakNr)=""
 Kill ^HULP(%J,"NEWKLREF")
 Quit
 ;