ATKOVERZ ; Afstand-toegang voor klanten [ 12/15/2003  3:19 PM ]
 ;
 Do INIT
 Write @F11,@F1
 Do EDIT^vhScherm("ATKOVERZ"),VERWERK("SPT")
 Kill ^HULP(%J)
 Quit
 ;
INIT 
 Do INIT^vhTERMINA
 Set %J=$$%J^vhRtn1()
 Kill ^HULP(%J)
 Set FromDate=$$CALCDATE^vhLib.DataTypes($H,"M","FD"),ToDate=+$H,Sort="D",Beperk=""
 Quit
 ;
VERWERK(Output) 
 Do FETCH(FromDate,ToDate,Sort,.Beperk)
 If $D(^HULP(%J)) Do
 .Do INIT^PROC("ATKOVERZ"_Sort,"OVERZ")
 .Set OVERZ(11)=OVERZ(11)_"\van "_$$EXTDATE^vhLib.DataTypes(FromDate)
 .Set:ToDate'=FromDate OVERZ(11)=OVERZ(11)_" tot "_$$EXTDATE^vhLib.DataTypes(ToDate)
 .Set FP=2101
 .Write @F,@F1
 .Do ^OUTPUT(Output)
 Kill ^HULP(%J)
 Quit
 ;
FETCH(FromDate,ToDate,Sort,Beperk) 
 New I1,I2,I3,KLNr,User,OnTime,OffTime,Time,Count,KNoList,UNoList,SuperV
 Set FromDate=FromDate-1
 For  Set FromDate=$O(^ATK("L",FromDate)) Quit:'FromDate  Quit:FromDate>ToDate  Do
 .Set KLNr=""
 .For  Set KLNr=$O(^ATK("L",FromDate,KLNr)) Quit:'KLNr  Do
 ..Set KNoList=$G(^ATK(KLNr,0,"L")),User=""
 ..For  Set User=$O(^ATK("L",FromDate,KLNr,User)) Quit:User=""  Do
 ...Set R=$G(^ATK("W",User)),SuperV=$P(R,D)
 ...Quit:SuperV=""
 ...If $D(Beperk),Beperk="-",$D(Beperk(SuperV)) Quit
 ...If $D(Beperk),Beperk="",'$D(Beperk(SuperV)) Quit
 ...Set UNoList=$G(^ATK(SuperV,$P(User,D),"L"))
 ...Set:'$L(UNoList) UNoList=KNoList
 ...Quit:UNoList
 ...Set (LogTime,LogOn,LogOff,OnTime,OffTime)=""
 ...For  Set LogTime=$O(^ATK("L",FromDate,KLNr,User,LogTime)) Quit:'LogTime  Do
 ....Set R=^ATK("L",FromDate,KLNr,User,LogTime)
 ....If R Do
 .....Set LogOn=R,Screens=""
 .....If LogOff="" Set OnTime=LogTime
 .....Else  Do
 ......Set LogOff=""
 ....Else  Do
 .....Set (LogOff,Screens)=R
 .....If LogOn="" Set OnTime="?"
 .....Set OffTime=LogTime
 ....If OnTime,OffTime Do
 .....Do SORTHULP(Sort,FromDate,KLNr,User,OnTime,OffTime,Screens)
 .....Set (LogOn,LogOff,OnTime,OffTime)=""
 ...If OnTime!OffTime Do
 ....Set:'OnTime OnTime="?" Set:'OffTime OffTime="?"
 ....Do SORTHULP(Sort,FromDate,KLNr,User,OnTime,OffTime,Screens)
 Set Count=0,I1=""
 For  Set I1=$O(^HULP(%J,I1)) Quit:I1=""  Do
 .Set I2=""
 .For  Set I2=$O(^HULP(%J,I1,I2)) Quit:I2=""  Do
 ..Set User=""
 ..For  Set User=$O(^HULP(%J,I1,I2,User)) Quit:User=""  Do
 ...Set I3=""
 ...For  Set I3=$O(^HULP(%J,I1,I2,User,I3)) Quit:I3=""  Do
 ....Set R=^HULP(%J,I1,I2,User,I3),Count=Count+1,^HULP(%J,Count)=R
 ....Kill ^HULP(%J,I1,I2,User,I3)
 Quit
 ;
SORTHULP(Sort,FromDate,KLNr,User,OnTime,OffTime,Screens) 
 New R,I1,I2,I3,KlantInd,KlNaam,Time,DiffTime,ExtInt,Regio
 Set DiffTime="?",ExtInt=$$EXTINT(User)
 If OnTime,OffTime Set DiffTime=OffTime-OnTime
 If $D(^KK1(KLNr)) Set KlantInd=^KK1(KLNr),R=^KKL(KlantInd,0),KlNaam=$P(R,D,2),Regio=$P(R,D,20)
 Else  Set KlantInd="~"_KLNr,KlNaam="Onbekend",Regio=""
 Set Screens=$TR(Screens,D,";"),Time=OnTime Set:'Time Time=OffTime
 Set R=FromDate_D_KLNr_D_KlNaam_D_$P(User,D)_D_OnTime_D_OffTime_D_DiffTime_D_Screens_D_Regio_D_ExtInt
 Set I1=$S(Sort="D":FromDate,Sort="K":KlantInd,1:FromDate)
 Set I2=$S(Sort="D":KlantInd,Sort="K":FromDate,1:Time)
 Set I3=$S(Sort="D":Time,Sort="K":Time,1:KlantInd)
 Set ^HULP(%J,I1,I2,User,I3)=R
 Quit
 ;
DAY(Day,Sort,Output) 
 New (Day,Sort,Output)
 Set Day=$G(Day),Sort=$G(Sort),Output=$G(Output)
 Do
 .New Day,Sort,Output
 .Do INIT
 Write @F11,@F1
 Set Day=$$INTDATE^vhLib.DataTypes(Day) Set:'Day Day=$H
 If Output'="S",Output'="P",Output'="SP" Set Output="S"
 Set (FromDate,ToDate)=Day
 Do VERWERK(Output)
 Kill ^HULP(%J)
 Quit
 ;
WEEK(Week,Sort,Output) 
 New (Week,Sort,Output)
 Set Week=$G(Week),Sort=$G(Sort),Output=$G(Output)
 Do
 .New Week,Sort,Output
 .Do INIT
 Write @F11,@F1
 Set Week=$$INTDATE^vhLib.DataTypes(Week,"DW") Set:'Week Week=$H
 If Output'="S",Output'="P",Output'="SP" Set Output="S"
 Set FromDate=$$CALCDATE^vhLib.DataTypes(Week,"W","FD"),ToDate=$$CALCDATE^vhLib.DataTypes(Week,"W","LD")
 Do VERWERK(Output)
 Kill ^HULP(%J)
 Quit
 ;
MONTH(Month,Sort,Output) 
 New (Month,Sort,Output)
 Set Month=$G(Month),Sort=$G(Sort),Output=$G(Output)
 Do
 .New Month,Sort,Output
 .Do INIT
 Write @F11,@F1
 Set Month=$$INTDATE^vhLib.DataTypes(Month,"DM") Set:'Month Month=$H
 If Output'="S",Output'="P",Output'="SP" Set Output="S"
 Set FromDate=$$CALCDATE^vhLib.DataTypes(Month,"M","FD"),ToDate=$$CALCDATE^vhLib.DataTypes(Month,"M","LD")
 Do VERWERK(Output)
 Kill ^HULP(%J)
 Quit
 ;
YEAR(Year,Sort,Output) 
 New (Year,Sort,Output)
 Set Year=$G(Year),Sort=$G(Sort),Output=$G(Output)
 Do
 .New Year,Sort,Output
 .Do INIT
 Write @F11,@F1
 Set Year=$$INTDATE^vhLib.DataTypes(Year) Set:'Year Year=$H
 If Output'="S",Output'="P",Output'="SP" Set Output="S"
 Set FromDate=$$CALCDATE^vhLib.DataTypes(Year,"J","FD"),ToDate=$$CALCDATE^vhLib.DataTypes(Year,"J","LD")
 Do VERWERK(Output)
 Kill ^HULP(%J)
 Quit
 ;
DOUTPUT 
 New I,R,Detail,Screen,Date,Cust,User,LogOn,LogOff,LogDiff
 Set R=$G(^HULP(%J,sLD(6)-6))
 If $L(R) Do
 .Do STORE^vhTERMINA()
 .Set Date=$$EXTDATE^vhLib.DataTypes($P(R,D)),Cust=$P(R,D,2)_" "_$P(R,D,3),User=$P(R,D,4)
 .Set LogOn=$$EXTTIME^vhLib.DataTypes($P(R,D,5),"TKS"),LogOff=$$EXTTIME^vhLib.DataTypes($P(R,D,6),"TKS")
 .Set LogDiff=$$EXTTIME^vhLib.DataTypes($P(R,D,7),"TKS")
 .Set Screen=$P(R,D,8)
 .For I=1:1:$L(Screen,";") Set Screen(I)=$P(Screen,";",I)_" - "_$$CONVSCRN($P(Screen,";",I))
 .Do INIT^vhLIST("ATKOVERZ","DETAIL",.Detail)
 .Set T=6,L=5,B=20,R=50
 .Do WRITE^vhLIST(.Detail)
 .For  Set R=$$SCROLL^vhLIST(.Detail) Quit:R="O"
 .Do REFRESH^vhTERMINA()
 Quit
 ;
CONVSCRN(Screen) 
 New Omschr
 Set Omschr=Screen
 Set:Screen="A" Omschr="Afroep orders"
 Set:Screen="B" Omschr="Leveringsbons"
 Set:Screen="C" Omschr="Contract orders"
 Set:Screen="D" Omschr="Detail orderingave"
 Set:Screen="E" Omschr="Intrastat"
 Set:Screen="K" Omschr="Selekteer andere klant"
 Set:Screen="M" Omschr="Ingave order"
 Set:Screen="N" Omschr="Nieuw produkt bij order- en offerteingave"
 Set:Screen="O" Omschr="Standaard orders"
 Set:Screen="P" Omschr="Raadplegen produkt"
 Set:Screen="Q" Omschr="Offerte"
 Set:Screen="R" Omschr="Klantreferenties"
 Set:Screen="S" Omschr="Openstaande fakturen"
 Set:Screen="T" Omschr="Direkt orders"
 Set:Screen="U" Omschr="Wijzigen eigen referentie"
 Set:Screen="V" Omschr="Verkoopanalyse"
 Set:Screen="W" Omschr="Wissel tussen Van Hoecke en eigen referenties"
 Set:Screen="X" Omschr="Verwijder order- of offertelijn"
 Set:Screen="Y" Omschr="Leveringsadressen"
 Set:Screen="Z" Omschr="Sluit order"
 Set:Screen="-" Omschr="Exit VHisie"
 Set:Screen="?" Omschr="Menu ""Schermen"""
 Set:Screen="+" Omschr="Menu ""Akties"""
 Set:Screen="*" Omschr="Legende"
 Set:Screen="=" Omschr="Zoek in lijst"
 Set:Screen=">" Omschr="Fax de huidige lijst"
 Set:Screen="!" Omschr="Wissel prijsmaskering"
 Set:Screen="@" Omschr="Telefoneer me terug"
 Set:Screen="0" Omschr="Logoff zonder akties"
 Set:Screen="SO" Omschr="Standaard orders"
 Set:Screen="CO" Omschr="Contract orders"
 Set:Screen="DO" Omschr="Direkt orders"
 Set:Screen="UL" Omschr="Leveringsbons"
 Set:Screen="OF" Omschr="Openstaande fakturen"
 Set:Screen="VA" Omschr="Verkoopanalyse"
 Set:Screen="KR" Omschr="Klantreferenties"
 Set:Screen="IS" Omschr="Intrastat"
 Set:Screen="PI" Omschr="Prijslijst industie"
 Set:Screen="PP" Omschr="Prijslijst KS"
 Set:Screen="ENTER" Omschr="Ingave of wijzigen aantal order of offerte"
 Quit Omschr
 ;
EXTINT(User) 
 New R,ExtInt
 Set R=^ATK("W",User),ExtInt=$S($P(R,D)=4682:"*",1:"")
 Quit ExtInt
 ;