DCABX ;AFDRUKKEN AFHALINGSLIJST GLS [ 12/15/2003  10:38 AM ]
 ;
 ; Het afdrukken van een spoordokument kan met volgende oproep --> Do PRINT^DCSPO(FANr)
 ;
VERWERK 
 New %J,L,FANr,PCount,ContrNr,AfzendNr,Taal,Marge,MaxLines,PageLen,TotCol,TotGew
 Do INIT,TITEL,HEADER,BODY,FOOTER("L"),PRINT,CLEAN
 Quit
 ;
FN(Number,Fraction,Format) 
 Quit $$FN^DCALG(Number,Fraction,$G(Format))
 ;
PASTEB(R,AddBlank) 
 New NewPage
 Set NewPage="Do FOOTER^"_$ZN_"(),TITEL^"_$ZN_",HEADER^"_$ZN
 Do PASTEB^DCALG(R,NewPage,$G(AddBlank),"BLOCK^"_$ZN,"CACHE^"_$ZN,"PASTE^"_$ZN)
 Quit
 ;
BLOCK(R) 
 Do BLOCK^DCALG(R)
 Quit
 ;
CACHE(R) 
 Set LCount=LCount+1
 Set ^HULP(%J,"ABX",PCount,LCount)=$J("",$G(Marge))_R
 Quit
 ;
PASTE(Page,Line,Text,BPos,EPos,Attr) 
 New T,I,X
 Set Marge=$G(Marge),T=Text Quit:T=""
 If Attr'["T" Set Attr=Attr_"T"
 If Attr["N" Set Attr=$TR(Attr,"NT","")
 If $L(Attr) For I=1:1:$L(Attr) Do
 .If $E(Attr,I)="T" Set T=$TR(T,P("T","F"),P("T","T")) Quit
 .Set T=P($E(Attr,I),1)_T
 .If $E(Attr,I)'="Q"!'$G(Prefs("NLQ")) Set T=T_P($E(Attr,I),0)
 If BPos,EPos Set $E(^HULP(%J,"ABX",Page,Line),BPos+Marge,EPos+Marge)=T Quit
 If BPos Set $E(^HULP(%J,"ABX",Page,Line),BPos+Marge,BPos+Marge+$L(Text)-1)=T Quit
 Set $E(^HULP(%J,"ABX",Page,Line),EPos+Marge-$L(Text)+1,EPos+Marge)=T
 Quit
 ;
PASTER(Value,From,To) 
 Do PASTER^DCALG(Value,$G(From),$G(To))
 Quit
 ;
BODY 
 New B,R,T,BCount,FANr,BONNr,KLNr,KlantInd,Naam,ToeNaam,Aanspr,Adres,PostNr,Woonpl,Land,Proforma
 New Colli,Gewicht,FakNrs,Palet
 Set FANr=""
 For  Set FANr=$O(^HULP(%J,"FNR",FANr)) Quit:FANr=""  Do
 .Set BCount=0,Proforma=$P($G(^HULP($J,"T",FANr)),D,2)
 .Kill B
 .Set R=^HULP(%J,"FNR",FANr),KLNr=$P(R,D)
 .Set Colli=$P(R,D,2)+$P(R,D,3)+$P(R,D,4),Palet=$P(R,D,2),Gewicht=$P(R,D,5)+.99\1
 .Set TotCol=TotCol+Colli,TotGew=TotGew+Gewicht,FakNrs=$P(R,D,7,99)
 .Set R="",BONNr=$O(@("^KFA"_Proforma_"(""F"",FANr,""U"")"))
 .Set:$E(BONNr)="U" R=$G(@("^KFA"_Proforma_"(""F"",FANr,BONNr,3)"))
 .If $P(R,D)
 .Else  Set KlantInd=^KK1(KLNr),R=^KKL(KlantInd,0)
 .Set Naam=$P(R,D,2),ToeNaam=$P(R,D,3),Aanspr=$P(R,D,4),Adres=$P(R,D,5)
 .Set PostNr=$P(R,D,6),Woonpl=$P(R,D,7),Land=$$LAND^vhRtn1($P(R,D,8))
 .Do BLOCK(L("B","S")_"`1``C")
 .Set T=$$FIRMANM^DCALG("K",KLNr)
 .If KLNr=8545,$L(T),$L(ToeNaam) Set R=T,T=ToeNaam,ToeNaam=R
 .Set R=L("B","B")
 .Do PASTER($$FN(FANr,0),"",10),PASTER($E(T,1,25),13)
 .Do PASTER($$FN(Colli,0),"",46) Do:Palet PASTER("p","",46)
 .Do PASTER($$FN(Gewicht,0),"",55),FAKNRS
 .Do BLOCK(R_"`1``C")
 .If $L(ToeNaam) Do
 ..Set R=L("B","B")
 ..Do PASTER(ToeNaam,13),FAKNRS,BLOCK(R_"`1``C")
 .Set R=L("B","B")
 .Do PASTER(Adres,13),FAKNRS,BLOCK(R_"`1``C")
 .Set R=L("B","B")
 .Do PASTER($E(PostNr_$S($L(PostNr):" ",1:"")_Woonpl,1,25),13),FAKNRS,BLOCK(R_"`1``C")
 .If Land'="BE" Do
 ..Set R=L("B","B")
 ..Do PASTER($$LAND^vhRtn1(Land,2,Taal),13),FAKNRS,BLOCK(R_"`1``C")
 .For I=1:1 Quit:FakNrs=""  Set R=L("B","B") Do FAKNRS,BLOCK(R_"`1``C")
 .Do PASTEB("")
 Quit
 ;
FAKNRS 
 Do PASTER($TR($P(FakNrs,D,1,2),D," "),76)
 Set FakNrs=$P(FakNrs,D,3,99)
 Quit
 ;
 ; Adruk titel
TITEL 
 New R,T
 Set PCount=PCount+1,LCount=0
 For I=1:1:6 Do CACHE("")
 Set T=$$TXT("AfhABX")
 Do PASTE(PCount,1,T,2,"","BU")
 Do PASTE(PCount,2,VH(1),45,"","B")
 Set T=$$TXT("Sektor")
 Do PASTE(PCount,2,T,2,"","B")
 Do PASTE(PCount,3,VH(2),45,"","B")
 Set T=$$TXT("Date")_":"_$$EXTDATE^vhLib.DataTypes($H)
 Do PASTE(PCount,3,T,2,"","B")
 Do PASTE(PCount,4,VH(3),45,"","B")
 Set T=$$TXT("Afzend")_":"_AfzendNr
 Do PASTE(PCount,4,T,2,"","B")
 Do PASTE(PCount,5,VH(4),45,"","B")
 Set T=$$TXT("Kontr")_":"_ContrNr
 Do PASTE(PCount,5,T,2,"","B")
 Quit
 ;
HEADER 
 New T,R
 Do CACHE("")
 Do PASTE(PCount,LCount,L("B","F"),1,"","C")
 Do CACHE("")
 Set R=L("B","B"),T=$$TXT("BullNr")
 Do PASTER(T,3)
 Set T=$$TXT("Bestem")
 Do PASTER(T,13)
 Set T=$$TXT("Colli")
 Do PASTER(T,"",45)
 Set T=$$TXT("Gew")
 Do PASTER(T,"",54)
 Set T=$$TXT("Remb")
 Do PASTER(T,"",64)
 Set T=$$TXT("Verz")
 Do PASTER(T,"",72)
 Set T=$$TXT("Opmerk")
 Do PASTER(T,76)
 Do PASTE(PCount,LCount,R,1,"","C")
 Quit
 ;
FOOTER(Type) 
 New T,R
 Set Type=$G(Type)
 Do CACHE("")
 Do PASTE(PCount,LCount,L("F","F"),1,"","C")
 Do CACHE("")
 Set R=L("F","B"),T=$$TXT("Page")
 Do PASTER(T,3)
 If Type="L" Do
 .Set T=$$TXT("TotCol")
 .Do PASTER(T,13)
 .Do PASTER($$FN(TotCol,0),"",46)
 .Do PASTER($$FN(TotGew,0),"",55)
 .Set T=$$TXT("Date")_" : "_$$EXTDATE^vhLib.DataTypes($H)
 .Do PASTER(T,58)
 Do PASTE(PCount,LCount,R,1,"","C")
 Do CACHE("")
 Set R=L("F","B")
 Do PASTER("PCount",3)
 If Type="L" Do
 .Set T=$$TXT("HandT")_":"
 .Do PASTER(T,58)
 Do PASTE(PCount,LCount,R,1,"","C")
 If Type="L" For I=1:1:2 Do CACHE(""),PASTE(PCount,LCount,L("F","B"),1,"","C")
 Do CACHE("")
 Do PASTE(PCount,LCount,L("F","L"),1,"","C")
 Quit
 ;
PRINT 
 New R,T,MaxPages,Copies
 Set MaxPages=PCount,Copies=2
 For Copies=1:1:Copies Do
 .For PCount=1:1 Quit:'$D(^HULP(%J,"ABX",PCount))  Do
 ..For LCount=1:1 Quit:'$D(^HULP(%J,"ABX",PCount,LCount))  Do
 ...Set R=^HULP(%J,"ABX",PCount,LCount)
 ...If R["PCount" Set T=PCount_"/"_MaxPages,R=$P(R,"PCount")_T_$J("",6-$L(T))_$P(R,"PCount",2)
 ...Write !,R
 ..Write #
 Quit
 ;
 ; Initialisatie
INIT 
 Set %J=$$%J^vhRtn1(),(TotCol,TotGew,PCount)=0,Taal="N",Marge=5
 Kill ^HULP(%J)
 Do ADD^vhLock("^abx")
 Merge ^HULP(%J,"FNR")=^abx
 Do REMOVE^vhLock("^abx")
 Kill ^abx
 If '$D(VH) Do VH^DCINIT
 If '$D(L) Do LINIT^DCINIT("X")
 If '$D(P) Do PINIT^DCINIT
 If '$D(PageLen)!'$D(V) Do FINIT^DCINIT("X")
 Set MaxLines=MaxLines-4
 Set R=^KBA(176),ContrNr=$P(R,D,2),AfzendNr=$P(R,D,3)
 Write P("D",0)
 Quit
 ;
CLEAN 
 Kill ^HULP(%J)
 Quit
 ;
 ; Ophalen taalafhankelijke tekst
TXT(Ref,Piece) 
 If '$D(Piece) Set Piece=2
 Quit $P($P($T(@("T"_Ref)),U,Piece),D,$F("NFDE",Taal)-1)
 ;
TAfhABX ;AFHALINGSLIJST GLS\AFHALINGSLIJST GLS\AFHALINGSLIJST GLS\AFHALINGSLIJST GLS
TSektor ;Sektor:159\Sektor:159\Sektor:159\Sektor:159
TDate ;Datum\Datum\Datum\Datum
TAfzend ;LR\LR\LR\LR
TKontr ;Nr BO\Nr BO\Nr BO\Nr BO
TBullNr ;Bull.nr\Bull.nr\Bull.nr\Bull.nr
TBestem ;Naam/adres bestemmeling\Naam/adres bestemmeling\Naam/adres bestemmeling\Naam/adres bestemmeling
TColli ;colli\colli\colli\colli
TGew ;gew.\gew.\gew.\gew.
TRemb ;remb.\remb.\remb.\remb.
TVerz ;verz.\verz.\verz.\verz.
TOpmerk ;opmerk.\opmerk.\opmerk.\opmerk.
TPage ;Blz\Blz\Blz\Blz
TTotCol ;Totaal der colli's\Totaal der colli's\Totaal der colli's\Totaal der colli's
THandT ;Handtekening chauffeur\Handtekening chauffeur\Handtekening chauffeur\Handtekening chauffeur