DCFAX ;AFDRUKKEN TELEFAX [ 10/23/2003  9:10 AM ]
 ;
 ; Het afdrukken van een telefax kan met volgende oproep --> Do PRINT^DCRBON(.Data)
 ;
 ; Opbouwen local C en afdrukken van de fax
PRINT(Data,NoSave) 
 New I,J,R,Ref,Taal,FreeFax,Tekst,HLines,HCount,LCount,PCount,Next,Vervolg
 New FromFax,IntPers,Subject,ExtPers,ToFax,ToName,WLength,MaxLines,Mail
 Quit:"\T\E\P\A\O\L\V\F\H\?\"'[(D_Data("Document")_D)
 Set Print("LMARG")=6,Taal=Data("Taal"),FreeFax=+$G(Data("FreeFax")),NoSave=$G(NoSave)
 Do:'NoSave SAVE(.Data)
 Set Data("Pages")=$G(Data("Pages"))+1_" ("_$$TXT("Incl")_")"
 Set Data("FAdres")=^KBA(99,2),Data("FWoonpl")=^KBA(99,3)
 Set Data("FTel")=^KBA(99,5),Data("FFax")=^KBA(99,6)
 Set Data("FTel")=$TR($P(Data("FTel"),":",2)," ","")
 Set Data("FTel")=" (32-"_+Data("FTel")_") "_$P(Data("FTel"),"/",2)
 Set Data("FFax")=$TR($P(Data("FFax"),":",2)," ","")
 Set Data("FFax")=" (32-"_+Data("FFax")_") "_$P(Data("FFax"),"/",2)
 Set WLength=69 If $G(%Fax),$G(%FaxNr) Set WLength=83
 Do MERGSLOT^DCFAX2
 Do GETWRAP^vhBIGEDIT("^HULP(%J,""T"")",WLength,.Tekst,"G","~","","")
 Set HLines=$$HLINES^vhFAX($S($D(Data("TermUser")):Data("TermUser"),1:Data("Van")))
 Kill ^HULP(%J,"T")
 For I=1:1:$O(Tekst(""),-1) Set Tekst(I)=$J("",$P(Tekst(I),"`",4))_$P(Tekst(I),"`",5)
 Set (Tekst,Next)="",(HCount,LCount)=0,MaxLines=44
 For  Set Next=$O(Tekst(Next)) Quit:Next=""  Do  Quit:LCount>MaxLines
 .Set:Tekst'="" Tekst=Tekst_"~" Set R=Tekst(Next)
 .If $$UPCASE^vhRtn1($TR(R," ",""))="«HANDTEKENING»" Do
 ..Set HCount=HCount+1,LCount=LCount+HLines
 ..If $G(%Fax),$G(%FaxNr) Do
 ...Set R=$P(R,"»")_" "
 ...If $D(Data("TermUser")),Data("TermUser")'=Data("VanUser") Set R=R_$P(^vhUSER("D",Data("TermUser")),D,5)
 ...Else  Set R=R_Data("Van")
 ...Set R=R_"»",Tekst=Tekst_R
 ..Else  Do
 ...For J=1:1:HLines-1-(HLines-1\2) Set Tekst=Tekst_"~"
 ...Set Tekst=Tekst_"~"
 ...For J=1:1:HLines-1\2 Set Tekst=Tekst_"~"
 .Else  Set Tekst=Tekst_R,LCount=LCount+1
 Do HULP^DCFAX2(Tekst,"")
 If Next,$O(Tekst(Next))'="" Do
 .Set Vervolg=0,MaxLines=52 If $G(%Fax),$G(%FaxNr) Set MaxLines=50
 .For  Do  Quit:Next=""
 ..Set Data("Pages")=Data("Pages")+1,Vervolg=Vervolg+1
 ..Set Tekst="",LCount=0
 ..For  Set Next=$O(Tekst(Next)) Quit:Next=""  Do  Quit:LCount>MaxLines
 ...Set:Tekst'="" Tekst=Tekst_"~" Set R=Tekst(Next)
 ...If $$UPCASE^vhRtn1($TR(R," ",""))="«HANDTEKENING»" Do
 ....Set HCount(Vervolg)=$G(HCount(Vervolg))+1,LCount=LCount+HLines
 ....If $G(%Fax),$G(%FaxNr) Set R=$P(R,"»")_" "_Data("Van")_"»",Tekst=Tekst_R
 ....Else  Do
 .....For J=1:1:HLines-1-(HLines-1\2) Set Tekst=Tekst_"~"
 .....Set Tekst=Tekst_"~"
 .....For J=1:1:HLines-1\2 Set Tekst=Tekst_"~"
 ...Else  Set Tekst=Tekst_R,LCount=LCount+1
 ..Do HULP^DCFAX2(Tekst,Vervolg)
 Kill Tekst
 Set PCount=1
 If $G(Data("TextId"))'="Z" Do
 .Do PRINT^vhScherm3("DCFAX","",1)
 .For Tekst=1:1 Quit:'$D(@("^HULP(%J,""T"",""T"_Tekst_""")"))  Do
 ..If $G(%Fax),$G(%FaxNr) Do FOOTER(HLines,HCount,PCount),NEWPAGE^vhFAX(%FaxNr)
 ..For I=1:1 Quit:'$D(^HULP(%J,"T",I))  Kill ^HULP(%J,"T",I)
 ..For I=1:1 Quit:'$D(@("^HULP(%J,""T"",""T"_Tekst_""",I)"))  Set ^HULP(%J,"T",I)=@("^HULP(%J,""T"",""T"_Tekst_""",I)")
 ..If $G(%Fax),$G(%FaxNr) Set HCount=$G(HCount(Tekst))
 ..Else  Write #
 ..Set Print("LIJN")=0,PCount=PCount+1
 ..Do PRINT^vhScherm3("DCFAXV","",1)
 If $G(%Fax),$G(%FaxNr) Do
 .Do:$G(Data("TextId"))'="Z" FOOTER(HLines,HCount,PCount)
 .Set I=""
 .For  Set I=$O(%FaxNr(I)) Quit:I=""  Do MERGE^vhFAX(%FaxNr,I)
 .Set FromFax=Data("FFax"),IntPers=Data("VanUser"),Subject=Data("Betreft")
 .Set ExtPers=Data("Tav"),ToName=Data("Aan"),ToFax=Data("Fax")
 .If $D(Data("Aanspr")),$E(ToName,1,$L(Data("Aanspr"))+1)=(Data("Aanspr")_" ") Do
 ..Set ToName=$E(ToName,$L(Data("Aanspr"))+2,99)
 .Set Mail=$G(Print("FAX","MAIL"))
 .If $G(Data("VanUser")) Set Mail(Data("VanUser"))=""
 .Else  Set Mail(Data("Van"))=""
 .Set:$G(Data("TermUser")) Mail(Data("TermUser"))=""
 .Do VERWERK^vhFAX(%FaxNr,QN,FromFax,IntPers,Subject,ExtPers,ToFax,ToName,$G(Print("FAX","COPYINT")),.Mail,$G(Print("FAX","PRINT")),$G(Print("FAX","COPYBV")))
 Quit
 ;
SAVE(Data,Bewaar) 
 New TempData
 Set Bewaar=$G(Bewaar)
 Merge TempData=Data
 Kill Data("FAdres"),Data("FWoonpl"),Data("FTel"),Data("FFax")
 Do SAVE^FAX(.Data,Bewaar)
 Merge Data=TempData
 Quit
 ;
FREEFAX(Type,Nummer) 
 New I,R,Print,Data,FreeFax,UserId,TextId,Count,Text,Tlength,%Fax,%FaxNr,%J,Param,Bewaar,FaxId
 Set %J=$$%J^vhRtn1()
 Lock +^FAX($I)
 Kill ^HULP(%J,"T"),^HULP(%J,"S")
 Set Type=$G(Type),Nummer=$G(Nummer),R=$$SELECT^FAX(Type,Nummer)
 Quit:$P(R,";")="-"
 Set Text=$P(R,";"),FaxId=$P(R,";",2)
 If FaxId Do
 .Set Data("FaxId")=FaxId,Text=1
 .Kill ^DEVSAVE($I,"FAX",Text)
 .Merge ^DEVSAVE($I,"FAX",Text)=^FAX("D",FaxId)
 .Do
 ..New Data
 ..Set Data("FAdres")=^KBA(99,2),Data("FWoonpl")=^KBA(99,3)
 ..Set Data("FTel")=^KBA(99,5),Data("FFax")=^KBA(99,6)
 ..Set Data("FTel")=$TR($P(Data("FTel"),":",2)," ","")
 ..Set Data("FTel")=" (32-"_+Data("FTel")_") "_$P(Data("FTel"),"/",2)
 ..Set Data("FFax")=$TR($P(Data("FFax"),":",2)," ","")
 ..Set Data("FFax")=" (32-"_+Data("FFax")_") "_$P(Data("FFax"),"/",2)
 ..Merge ^DEVSAVE($I,"FAX",Text)=Data
 If 2'[Text Set TextId="^",FreeFax=Text,UserId=$G(^DEVSAVE($I,"FAX",FreeFax,"VanUser"))
 If '$G(UserId) Do
 .Set UserId=$$USELECT("LVH") Quit:'UserId
 .Set FreeFax=1,TextId="?"
 .If Type="" Do FREE^DCFAX2(Nummer)
 .If Type="K" Do KLANT^DCFAX2(Nummer)
 .If Type="L" Do LEVER^DCFAX2(Nummer)
 Set Data("FreeFax")=FreeFax
 Set Data("FAdres")=^KBA(99,2),Data("FWoonpl")=^KBA(99,3)
 Set Data("FTel")=^KBA(99,5),Data("FFax")=^KBA(99,6)
 Set Data("FTel")=$TR($P(Data("FTel"),":",2)," ","")
 Set Data("FTel")=" (32-"_+Data("FTel")_") "_$P(Data("FTel"),"/",2)
 Set Data("FFax")=$TR($P(Data("FFax"),":",2)," ","")
 Set Data("FFax")=" (32-"_+Data("FFax")_") "_$P(Data("FFax"),"/",2)
 Do VERWFAX()
 Kill ^HULP(%J,"T"),^HULP(%J,"S")
 Lock -^FAX($I)
 Quit
 ;
VERWFAX(Edit,FldEd) 
 New KLNr,Fax
 Set Edit=$G(Edit),FldEd=$G(FldEd)
 Do STORE^vhTERMINA()
 Do @($S(Edit:"EDIT",TextId="?":"NIEUW",1:"EDIT")_"^vhScherm(""DCFAX"","""","""","""",FldEd)")
 If '$$TEKST() Do REFRESH^vhTERMINA() Quit
 If '%SC,$$^vhTXTPOP("DCFAX","SENDNOMOD")'="J" Quit
 If $G(Bewaar),$D(Data("FaxId")) Do DELOBJ^FAX(Data("FaxId"))
 Do SAVE(.Data,$G(Bewaar))
 Set Fax=1,KLNr=$G(Data("KLNr")) Set:KLNr R=^KKL(^KK1(KLNr),1),Fax='$P(R,D,26)
 Set FP=2201 Write @F,@F1
 Set R="" If Fax,Data("Fax")="" Set R="F"
 Set R=$S(Data("Fax")=""&($G(Data("Type"))'="S"):"F",1:"")
 Do INIT^vhPRINTER("L","",$S(Fax:"F",1:"")_"P",R)
 If $D(Print) Do
 .If $G(Data("Type"))'="S" Do
 ..Set:Data("Fax")="" Data("Fax")=$G(Print("FAX","NR"))
 ..Do PRINT(.Data)
 ..If $G(%Fax),$G(%FaxNr)
 ..Else  Write #
 .Else  Do
 ..New R,Next,LEVNr,KLNr,Persoon,FaxNr
 ..Set:",)"[$E(SRef,$L(SRef)) SRef=$E(SRef,1,$L(SRef)-1)_",Next)"
 ..Set Next=0
 ..Kill ^HULP(%J,"TT")
 ..Merge ^HULP(%J,"TT")=^HULP(%J,"T")
 ..For  Set Next=$O(@SRef) Quit:Next=""  Do
 ...Set R=@SRef,Data("Type")=$P(R,";"),(LEVNr,KLNr)=$P(R,";",2),Persoon=$P(R,";",3),FaxNr=$P(R,";",4)
 ...Set Data("Fax")=FaxNr,Data("Verantw")=Persoon
 ...If $P(R,";")="K" Kill Data("LEVNr") Do KLANT^DCFAX2(KLNr)
 ...If $P(R,";")="L" Kill Data("KLNr") Do LEVER^DCFAX2(LEVNr)
 ...Set Persoon=Data("Verantw"),FaxNr=Data("Fax")
 ...Set Date=$$EXTDATE^vhLib.DataTypes($H,"DC",Data("Taal"))_", "_$$EXTDATE^vhLib.DataTypes($H,"DL",Data("Taal"))
 ...Set Data("Datum")=Date
 ...Set Data("Aan")=Data("Aanspr") Set:$L(Data("Aan")) Data("Aan")=Data("Aan")_" "
 ...Set Data("Aan")=Data("Aan")_Data("Naam"),Data("Tav")=Persoon,Data("Pages")=""
 ...Kill Data("FaxId")
 ...Set Print("LIJN")=0,^FAX(%FaxNr,.015)="VT220"
 ...Do SAVE(.Data,$G(Bewaar))
 ...Kill ^HULP(%J,"T")
 ...Merge ^HULP(%J,"T")=^HULP(%J,"TT")
 ...Do PRINT(.Data)
 ...If $G(%Fax),$G(%FaxNr)
 ...Else  Write #
 ..Kill ^HULP(%J,"TT")
 .Do CLOSE^vhPRINTER
 Do REFRESH^vhTERMINA()
 Quit
 ;
TEKST() 
 New Next
 Set Next=""
 For  Set Next=$O(^HULP(%J,"T",Next)) Quit:Next=""  Quit:$L(^HULP(%J,"T",Next))
 Kill:'Next ^HULP(%J,"T")
 Quit Next
 ;
EXTERN(Data,TRef) 
 New %J,%SC,TextId,FreeFax,UserId,ExtFax,Bewaar
 Set %J=$$%J^vhRtn1(),%SC=1,ExtFax=1,(TextId,Data("TextId"))="?",(FreeFax,Data("FreeFax"))=1
 Set UserId=$$USELECT("LVH")
 Set Data("VanUser")=UserId
 Lock +^FAX($I)
 Kill ^HULP(%J,"T"),^HULP(%J,"S")
 Merge ^HULP(%J,"T")=@TRef
 Do VERWFAX(1)
 Kill ^HULP(%J,"T"),^HULP(%J,"S")
 Lock -^FAX($I)
 Quit
 ;
MENU 
 Write @F11,@F1,@FMTB,"TELEFAX",@FMTb
 Set Extern=1
 Do FREEFAX()
 Quit
 ;
MAIL(MailId) 
 New I,R,Print,Data,FreeFax,UserId,TextId,Count,Text,Tlength,%Fax,%FaxNr,%J,Param,Bewaar,FaxId,Mail
 New VerslId,Type,Onderw
 Set R=^vhMAIL("D",MailId),Type=$P(R,D),Onderw=$$ONDERW^vhMAIL4(MailId)
 Set %J=$$%J^vhRtn1()
 Lock +^FAX($I)
 Kill ^HULP(%J,"T"),^HULP(%J,"S")
 Set R=$$FBETREFT^vhMAIL4("","",MailId,1)
 If $L(R) Set R="Intern bericht :"_$C(9)_R Set:$L(Onderw) R=R_", "_Onderw Set R=R_"~~"
 Set ^HULP(%J,"T",1)=R,I=""
 For  Set I=$O(^vhMAIL("D",MailId,"T",I)) Quit:I=""  Set ^HULP(%J,"T",I+1)=^vhMAIL("D",MailId,"T",I)
 Set R="~~ȘUVerzonden doorȘu : "_$$SENDFROM^vhMAIL(MailId)
 Set I=$O(^HULP(%J,"T",""),-1)+1,^HULP(%J,"T",I)=R
 Set R=$$TUSER^vhMAIL($$TUSERID^vhMAIL(MailId,"","",1),1) Set:$L(R) R="~~ȘUcc naarȘu        : "_R
 Set R="~~ȘUVerzonden naarȘu : "_$$TUSER^vhMAIL($$TUSERID^vhMAIL(MailId),1)_R
 Set I=$O(^HULP(%J,"T",""),-1)+1,^HULP(%J,"T",I)=R
 Set TextId="?",FreeFax=1,UserId=CUserId
 Set Mail=1
 Set Data("FreeFax")=FreeFax,(Data("Aanspr"),Data("Naam"))="",Extern=1
 Set Data("Betreft")="Interne mail",Data("Verantw")=""
 Do VERWFAX(1,1)
 Kill ^HULP(%J,"T"),^HULP(%J,"S")
 Lock -^FAX($I)
 Quit
 ;
TAAL(Taal) 
 New R
 Set FP=2201 Write @F,@F1
 Set R=$$PI^vhPOPUP("2;58","1O-","Taal","DCFAX","TAAL",Taal)
 If $L(R),R'=Taal Set (Taal,Data("Taal"))=R Do PAINT^vhScherm
 Quit Taal
 ;
DTAAL(Taal) 
 Quit $P(^RES("DCFAX","PI","TAAL","D",Taal),"`",2)
 ;
HEADER(X,Vervolg) 
 New Taal,FromName,FromFax,IntPers,Subject,ToName,ToFax,ExtPers,Date,Pages
 Set Vervolg=$G(Vervolg)
 If $G(%Fax),$G(%FaxNr) Do  Quit ""
 .Do TITEL^vhFAX(%FaxNr)
 .Set Taal=Data("Taal"),FromName=QN,FromFax=Data("FFax"),IntPers=Data("Van"),Subject=Data("Betreft")
 .Set ToName=Data("Aan"),ToFax=Data("Fax"),ExtPers=Data("Tav"),Date=Data("Datum"),Pages=Data("Pages")
 .Do FONT^vhFAX(%FaxNr,"D")
 .Do HEADER^vhFAX(%FaxNr,Taal,FromName,FromFax,IntPers,Subject,ToName,ToFax,ExtPers,Date,Pages,Vervolg) 
 I $D(Print) W !!! Write:'$D(Print("LADE")) !! Write:'Vervolg !
 If $G(Print("PRINTER"))'["CA",$G(Print("PRINTER"))'["BL" Quit X
 Quit $C(27)_"[@"_$C(4)_$C(0)_$C(0)_$C(0)_$C(18)_$C(2)_$C(27)_":"_X_$C(27)_"[@"_$C(4)_$C(0)_$C(0)_$C(0)_$C(17)_$C(1)_$C(18)_$C(27)_$C(87)_$C(0)_$C(27)_$C(73)_$C(0)
 Quit $S($G(Print("PRINTER"))'["CA":X,1:$C(27)_"[@"_$C(4)_$C(0)_$C(0)_$C(0)_$C(18)_$C(2)_$C(27)_":"_X_$C(27)_"[@"_$C(4)_$C(0)_$C(0)_$C(0)_$C(17)_$C(1)_$C(18)_$C(27)_$C(87)_$C(0)_$C(27)_$C(73)_$C(0))
 ;
FOOTER(HLines,HCount,PCount) 
 New R,Taal,FromFax,FromTel,FromAdr,FromLoc,MaxLines
 Set MaxLines=$S(PCount=1:56,1:56),R=$$LASTLINE^vhFAX(%FaxNr)+(HLines*HCount)
 Do REPEAT^vhFAX(%FaxNr,"",0,MaxLines-R)
 Set Taal=Data("Taal"),FromFax=Data("FFax"),FromTel=Data("FTel"),FromAdr=Data("FAdres"),FromLoc=Data("FWoonpl")
 Do FOOTER^vhFAX(%FaxNr,Taal,FromFax,FromTel,FromAdr,FromLoc) 
 Quit
 ;
AAN(Aan) 
 New R,Select,KLNr,LEVNr
 Set R=$$SELECT^KONTAKT("KLDA","D","","Aan : ","","","","$$MULTI^DCFAX2(%J);Bepaalde klanten") Quit:R="-" ""
 Set Select=$P(R,";"),(KLNr,LEVNr,SRef)=$P(R,";",2)
 If Select="S" Do
 .Kill Data("KLNr"),Data("LEVNr")
 .Kill Data("Verantw"),Data("Fax")
 .Do SERIE^DCFAX2(SRef)
 If Select="D" Do
 .Set Data("Aan")=$P(R,";",2)
 .Kill Data("KLNr"),Data("LEVNr"),Data("Type")
 If Select="K" Do  Quit:'KLNr ""
 .Kill Data("KLNr"),Data("LEVNr")
 .Kill Data("Verantw"),Data("Fax")
 .Do KLANT^DCFAX2(KLNr)
 If Select="L" Do  Quit:'LEVNr ""
 .Kill Data("KLNr"),Data("LEVNr")
 .Kill Data("Verantw"),Data("Fax")
 .Do LEVER^DCFAX2(LEVNr)
 If Select'="D" Do
 .Set NewLevKl=1
 .Do SINIT,PAINT^vhScherm
 .Set (TextId,Data("TextId"))="?"
 Quit Data("Aan")
 ;
TAV(Old) 
 New R,Type,Number,Optie,FaxNr,Persoon
 If $L($G(Data("Type"))) Do
 .Set Optie("CASE")="L",Optie("SELECT")=$G(Old),Optie("CONNECT")="F",Optie("PIECE")="5,6",FP=2201 
 .Write @F,@F1
 .Set Type=Data("Type") Set:Type="K" Number=Data("KLNr") Set:Type="L" Number=Data("LEVNr")
 .Set R=$$SELECT^PERS(Type,Number,.Optie),Persoon=$P(R,D),FaxNr=$P(R,D,2)
 .Set FaxNr=$S($L(FaxNr):FaxNr,1:$$FAXNR(Data("Type"),Data($S(Data("Type")="K":"KLNr",1:"LEVNr"))))
 .If FaxNr'=Data("Fax") Set Data("Fax")=FaxNr Do REPAINT^vhScherm("FAXNR")
 Quit $G(Persoon)
 ;
TAVHELP() 
 New Help
 Set Help=$S("D"[$G(Data("Type")):"",$G(Menu)&'$G(Data("KLNr"))&'$G(Data("LEVNr")):"",1:"            page up (SEL) voor lijst")
 Quit Help
 ;
 ; Opvragen van de tekst
TSELECT(OrdBev) 
 New Count,Text,TextId,TLength,Titel
 If $G(OrdBev) Quit "S"
 Set Titel="Voorblad"
 Set Count=0,TLength=$L(Titel)+2 Set:'$G(AutoFax) Count=Count+1,Text(Count)="0`Geen"
 If +$G(^DEVSAVE($I,"FAX",0))=+$H,$G(^DEVSAVE($I,"FAX",0,"KLNr"))=$G(KLNr,$G(KC)) Set Count=Count+1,Text(Count)="^`Vorig voorblad",Count=Count+1,Text(Count)="^?`Vorig voorblad met aanvulling"
 Set Count=Count+1,Text(Count)="?`Vrije tekst",TextId=""
 For  Set TextId=$O(^POP("DCFAX","D",TextId)) Quit:TextId=""  Do
 .Quit:'$$INCLUDE(TextId)
 .Set Count=Count+1,Text(Count)=TextId_"`"_$P(^POP("DCFAX","D",TextId),D,2)
 .Set:$L($P(Text(Count),"`",2))>TLength TLength=$L($P(Text(Count),"`",2))
 Quit $$WILD^vhPOPUP(12-($O(Text(""),-1)\2)_";"_(40-(TLength\2)),"O1-",Titel,.Text,"")
 ;
 ; Include tekst voor selektie
INCLUDE(TextId) 
 New R,Include,InclDoc,InclTyp,InclExec,KLNr
 Set R=^POP("DCFAX","D",TextId),InclDoc=$P(R,D,3),InclTyp=$P(R,D,4),InclExec=$P(R,D,5)
 Set Include=1
 If $L(InclDoc),$L(InclTyp) Do
 .If Document'=InclDoc Set Include=0 Quit
 .If Document="A",$G(DocNum) Do
 ..Set KLNr=$P(^KOFKL1(DocNum,"F"),D),R=^KOFKL(KLNr,"F",DocNum,1)
 ..Set:InclTyp'=$P(R,D,25) Include=0
 If Include,$L(InclExec) Xecute "Set Include="_InclExec
 Quit Include
 ;
 ; Opvragen van de gebruiker
USELECT(Groep,Titel) 
 New User,UserId,DevUser,ULength,Select
 Set:'$D(Titel) Titel="Fax verzonden door"
 Set ULength=$L(Titel)+2,Select=0
 Set UserId=$$USELECT^vhUSER("","","",Groep,"","","","",1,0),DevUser=$P($$DEVUSER^vhUSER($$IO^cQ5),";")
 If $L(UserId) For I=1:1:$L(UserId,";") Do
 .Set User(I)=$P(UserId,";",I)_"`"_$P(^vhUSER("D",$P(UserId,";",I)),D,5)
 .Set:$L($P(User(I),"`",2))>ULength ULength=$L($P(User(I),"`",2))
 .If 'Select,$P(UserId,";",I)=DevUser Set Select=$P(UserId,";",I)
 Quit $$WILD^vhPOPUP(12-($O(User(""),-1)\2)_";"_(40-(ULength\2)),"O1-",Titel,.User,Select)
 ;
LINE(sFR,Type,Len,Vert) 
 Set FP=$P(sFR,"`",5)*100+$P(sFR,"`",6)
 Write @F,@F7,$$LINE^vhRtn1(Type,Len,Vert),@F8
 Quit
 ;
SINIT 
 Do SINIT^DCFAX2
 Quit
 ;
VINIT 
 Do VINIT^DCFAX2
 Quit
 ;
MERGETXT(TextId,Data) 
 New I,R,Text,Taal,FreeFax,Type
 If '$D(Document) New Document Set Document=$G(Data("Document"))
 Set Taal=Data("Taal"),FreeFax=+$G(Data("FreeFax")),R="",Type=$G(Data("Type"))
 
 Do ##class(BL.Legacy.MailTroep).VulIn(.Param,.Data)
 
 Set Param("Kontakt")=$S(Type="":"","KL"[Type:$$TXT($S(Type="K":"Klant",1:"Lever")),1:"")
 If $D(Data("TermUser")),Data("TermUser")'=Data("VanUser") {
	Set Param("InOpdr")=$P(^vhUSER("D",Data("TermUser")),D,5)
 }
 Quit:$G(Mail)  Quit:$G(ExtFax)

	If $E(TextId)="^" Merge ^HULP(%J,"T")=^DEVSAVE($I,"FAX",FreeFax,"Tekst") Quit

	If (TextId="?") {
		Set Text="~~"_$$USERNAME^vhUSER(,2)
	}
	Else {
		Do VulInDataViaIndienNodig(.Data)
		New SubNodeVoorDCFAXTekst
		Set SubNodeVoorDCFAXTekst=$$GeefSubNodeVoorDCFAXTekst(TextId,.Data)
		Set Text=$G(^POP("DCFAX","D",SubNodeVoorDCFAXTekst,Taal))
		For I=1:1 Set R=$G(^POP("DCFAX","D",SubNodeVoorDCFAXTekst,Taal,I)) Quit:R=""  Set Text=Text_R Quit:R=""
	}

 If "SCTU"[$E(TextId) Do
 .Set Param("Ons")=$$TXT("Onze",$S(Document'="A":2,"D"[$G(OffTyp):2,1:3))
 .If Taal'="D" Set Param("DocNaam")=$$LOCASE^vhRtn1(Data("DOCNaam"))
 .If Taal="D" Set Param("DocNaam")=Data("DOCNaam")
 .Set Param("DocNummer")=$$EXTNUM^vhLib.DataTypes(Data("DocNum"),0,".-",0)
 .Set I=""
 .For  Set I=$O(DocNum(I)) Quit:I=""  Set Param("DocNummer")=Param("DocNummer")_", "_$$EXTNUM^vhLib.DataTypes(I,0,".-",0)
 .If Document="A",OffTyp="C" Set Param("Document")=$$LOCASE^vhRtn1($$TXT^DCALG("Offer"_OffTyp,"DCOFFD"))
 Set Text=$$CONVERT^vhBIGEDIT(.Text,.Param)
 Kill ^HULP(%J,"T")
 For I=1:1 Set ^HULP(%J,"T",I)=$E(Text,1,500),Text=$E(Text,501,9000) Quit:Text=""
 Quit
 ;
 ; Rubriek xecute
 
GeefSubNodeVoorDCFAXTekst(TextId,Data)
	Set TextId=$TR(TextId,"?","")
	New Oorsprong
	Set Oorsprong = ##class(BL.Legacy.MailTroep).GeefOorsprongVoorDocument($G(Data("Via")),$G(Data("DocNum")))
	If Oorsprong = ##class(BL.Flow.Offerte.enu.Oorsprong).NotebornTaorCubicsWebshop() {
		If $G(Data("Via")) = "BON" {
			Set TextId = "BON_"_Oorsprong
		} Else {
			Set TextId=TextId_"_"_Oorsprong
		}
	}
	Quit TextId

/// Omdat via specifiek code pad de Via niet altijd is ingevuld, hier een kleine fix schrijven zodat we toch klant specifieke tekst kunnen ophalen.
VulInDataViaIndienNodig(Data)
	If ($G(Data("Via")) = "") {
		If ($G(Data("DOCNaam"))="Factuur") {
			Set Data("Via") = "FACT"
		} ElseIf ($G(Data("DOCNaam"))="Leveringsbon") {
			Set Data("Via") = "BON"
		}
	}
	Quit

XRUBRIEK 
 New Date
 If X="." Kill ^HULP(%J,"T")
 If X="-" Do
 .If $G(Data("Type"))'="S" Do
 ..If Data("Aan")="" Do FIELDI^vhScherm(4) Set:Data("Aan")="" X=""
 ..Quit:X=""
 ..If Data("Fax")="" Do FIELDI^vhScherm(8) Set:Data("Fax")="" X=""
 .Quit:X=""
 .If '$G(Data("FreeFax")),$G(Document)'="O",$G(Document)'="A",$G(Document)'="T" Quit
 .Set FP=2201
 .Write @F,@F1
 .If $G(Data("FaxId")) Do
 ..If $G(Data("KLNr"))=$G(^FAX("D",Data("FaxId"),"KLNr")),$G(Data("LEVNr"))=$G(^FAX("D",Data("FaxId"),"LEVNr"))
 ..Else  Set %SC=1 Kill Data("FaxId")
 .If %SC Do  Quit:X=""
 ..Set Date=$$EXTDATE^vhLib.DataTypes($H,"DC",Data("Taal"))_", "_$$EXTDATE^vhLib.DataTypes($H,"DL",Data("Taal"))
 ..If Date'=Data("Datum") Do
 ...Set X=$$^vhTXTPOP("DCFAX","DATUM","",Data("Datum"),Date)
 ...If X="W" Set Data("Datum")=Date Do DISPVAL^vhScherm(12)
 .Set X=$S('$G(Data("FaxId")):0,1:1)
 .If '%SC,'$G(Mail),'$G(ExtFax) Set X="N"
 .Else  Set X=$$TEKST(),X=$S(X:$$^vhTXTPOP("DCFAX","SAVE"_$S($G(Edit):"MOD",$G(TextId)="?":"NEW",1:"MOD")),1:".")
 .If $L(X),X'="." Do
 ..If X="A" Kill Data("FaxId") Set X="J"
 ..Set Bewaar=X="J",X="-"
 Quit
 ;
FAXNR(Type,Nummer,Persoon) 
 New I,R,Global,IGlobal,FaxNr
 Set Global=$S(Type="K":"KL",Type="L":"LE",1:""),IGlobal=$S(Type="K":"K1",Type="L":"L1",1:"")
 Set FaxNr=$P(@("^"_Q_Global_"(@(""^""_Q_IGlobal_""(Nummer)""),1)"),D,24)
 Quit FaxNr
 ;
CHECK(EMAdres) 
 ;
 ; Ophalen taalafhankelijke tekst
TXT(Ref,Piece) 
 If '$D(Piece) Set Piece=2
 Quit $P($P($T(@("T"_Ref)),U,Piece),D,$F("NFDE",Taal)-1)
 ;
TFAX ;TELEFAX\TELEFAX\TELEFAX\TELEFAX
TVerv ;vervolg\suite\fortsetzung\continue
TAan ;Aan\A\An\To
TTav ;T.a.v.\A l'att.\z. Hd.\Attn.
TAank ;Aankoopdienst\Service achats\Ankauf\Purchase department
TVerk ;Verkoopdienst\Service de vente\Verkauf\Sales department
TBetr ;Betreft\Concernant\Betrifft\Concerning
TDate ;Datum\Date\Datum\Date
TVan ;Van\De\Von\From
TPages ;#Pag(s)\#Pag(s)\#Pag(n)\#Pag(s)
TIncl ;incl. dit blad\incl. cette page\incl. diese Seite\incl. this page
TOnze ;onze\notre\unser\our;ons\notre\unser\our
TTekst ;Tekst\Tekst\Tekst\Tekst
TKlant ;klant\client\Kunde\customer
TLever ;