EWRCPST3 ;E'WMS Status receptie [ 11/06/2003  11:03 AM ]
 ;
CHKMENU(Menu,Aktie) 
 New R,Ok,KLNr
 Set Aktie=$G(Aktie),Ok=0
 If Menu="F" Do  ; File menu
 .Quit:'$D(^RCP("D"))
 .If Aktie="" Do
 ..Set Ok=1
 .Else  If Aktie="S" Do  ; Nieuwe selektie
 ..Set:$D(^RCP("D")) Ok=1
 .Else  If Aktie="M" Do  ; Selekteer macro
 ..Set:$D(^EWSEL("RCPST")) Ok=1
 .Else  If Aktie="T" Do  ; Toon ...
 ..Quit:'$D(^HULP(%J,"L"))  ; Geen gegevens om te tonen
 ..Set Ok=1
 .Else  If Aktie="TS" Do  ; Toon selektie
 ..Quit:'$D(^HULP(%J,"L"))  ; Geen gegevens om te tonen
 ..If Krit("A","DISPLAY")'="S",Krit("M","A","DISPLAY")="S" Set Ok=1
 .Else  If Aktie="TR" Do  ; Toon receptieoverzicht
 ..Quit:'$D(^HULP(%J,"L"))  ; Geen gegevens om te tonen
 ..If Krit("A","DISPLAY")'="R" Set Ok=1
 .Else  If Aktie="TD" Do  ; Toon receptiedetails
 ..Quit:'$D(^HULP(%J,"L"))  ; Geen gegevens om te tonen
 ..If Krit("A","DISPLAY")'="D" Set Ok=1
 .Else  If Aktie="GP" Do  ; Goederen gecontroleerd op pallet
 ..Quit:'$D(^HULP(%J,"L"))  ; Geen gegevens om te tonen
 ..Quit:'$P($G(^HULP(%J,"L",LD("SELECT"))),D,6)  ; Geen sublijn
 ..Quit:$P($G(^HULP(%J,"L",LD("SELECT"))),D,19)=""
 ..If Krit("A","DISPLAY")="D" Set Ok=1
 .Else  If Aktie="R" Do  ; Refresh
 ..If RCPNr,$D(^RCP("D",RCPNr)) Set Ok=1
 .Else  If Aktie="O" Do  ; Open receptie
 ..Set:$D(^RCP("D")) Ok=1
 .Else  If "\)\(\"[(D_Aktie_D) Do  ; Volgende/vorige receptie/terugname
 ..If Krit("A","DISPLAY")="S" Do
 ...If $$NEXTREF^EWRCPST(LD("SELECT"),$S(Aktie=")":+1,1:-1)) Set Ok=1
 ..Else  Do
 ...If RCPTyp="L",$O(^RCP("IL",LKNr,RCPNr),$S(Aktie=")":+1,1:-1))'="" Set Ok=1
 Else  If Menu="E" Do  ; Edit menu
 .Quit:'$D(^RCP("D"))
 .If Aktie="" Do
 ..Set:$D(^HULP(%J,"L")) Ok=1
 .Else  If Aktie="UM" Do  ; Urgentie markering
 ..;If Krit("A","DISPLAY")'="D",$D(^HULP(%J,"L")) Set Ok=1 ; steeds toelaten PV 23-11-05
 ..If Krit("A","DISPLAY")'="D",$D(^HULP(%J,"L")) Do
 ...Set R=^HULP(%J,"L",LD("SELECT"))
 ...Quit:"\\W\P\"'[(D_$P(R,D,12)_D)
 ...Quit:$$IsUrgent^FLOWTOE($P(R,D,4),$P(R,D,5))
 ...Set Ok=1
 .Else  If Aktie="UV" Do  ; Urgentie verwijderen
 ..;If Krit("A","DISPLAY")'="D",$D(^HULP(%J,"L")) Set Ok=1 ; steeds toelaten PV 23-11-05
 ..If Krit("A","DISPLAY")'="D",$D(^HULP(%J,"L")) Do
 ...Set R=^HULP(%J,"L",LD("SELECT"))
 ...Quit:"\\W\P\"'[(D_$P(R,D,12)_D)
 ...Quit:'$$IsUrgent^FLOWTOE($P(R,D,4),$P(R,D,5))
 ...Set Ok=1
 .Else  If Aktie="Z" Do  ; Doorsturen receptie
 ..If $D(^HULP(%J,"L")),$P(^RCP("D",RCPNr),D,20)="" Set Ok=1
 .Else  If "\VL\VK\"[(D_Aktie_D) Do  ; Verwijderen toelevering of terugname
 ..If RCPTyp=$E(Aktie,2),$D(^HULP(%J,"L")),$P(^HULP(%J,"L",LD("SELECT")),D,4) Set Ok=1
 .Else  If Aktie="X" Do  ; Verwijderen receptie
 ..Set:$D(^HULP(%J,"L")) Ok=1
 .Else  If $E(Aktie)="I" Do  ; Inboeken receptie
 ..Quit:'$D(^HULP(%J,"L"))
 ..If $P(^RCP("D",RCPNr),D)="K",$P(^RCP("D",RCPNr),D,20)'="A" Quit
 ..If Aktie="IR",'$P(^HULP(%J,"L",LD("SELECT")),D,4),$P(^RCP("D",RCPNr),D,20)="A" Set Ok=1
 ..If Aktie="IS",$P(^HULP(%J,"L",LD("SELECT")),D,4) Set Ok=1
 ..If Aktie="ISR",$P(^RCP("D",RCPNr),D,20)="A" Set Ok=1
 ..If Aktie="IST",$P(^RCP("D",RCPNr),D,20)="A" Set Ok=1
 ..If Aktie="ISL" Do
 ...Quit:$P(^RCP("D",RCPNr,"D",TBNr,TBLUNr),D,2)'="S"
 ...Quit:"\G\E\S\"[(D_$P(^RCP("D",RCPNr,"D",TBNr,TBLUNr),D,3)_D)
 ...Set Ok=1
 ...Set R=^RCP("D",RCPNr)
 ...Quit:$P(R,D)'="K"                                                   
 ...Set KLNr=$P(R,D,2),R=$G(^KUL(KLNr,"F",TBNr,1)),Ok=$P(R,D,25)'="T"
 .Else  If Aktie="AP" Do  ; Ander product
 ..Set Ok=$$CHKMENU^EWRCPAP(Menu,Aktie)
 Else  If Menu="L" Do  ; Link menu
 .Quit:'$D(^RCP("D"))
 .If Aktie="" Do
 ..Set:RCPTyp="K"!$D(^HULP(%J,"L")) Ok=1
 .Else  If Aktie="K" Do  ; Raadplegen klant
 ..Set:RCPTyp="K" Ok=1
 .Else  If Aktie="P" Do  ; Raadplegen produkt
 ..Set:$P($G(^HULP(%J,"L",LD("SELECT"))),D,11) Ok=1
 .Else  If Aktie="L" Do  ; Raadplegen terugname
 ..If RCPTyp="K",$D(^HULP(%J,"L")) Set Ok=1
 .Else  If Aktie="J" Do  ; Raadplegen kom-order
 ..Set:$P($G(^HULP(%J,"L",LD("SELECT"))),D,7) Ok=1
 .Else  If Aktie="G" Do  ; Raadplegen toelevering
 ..If RCPTyp="L",$D(^HULP(%J,"L")) Set Ok=1
 Quit Ok
 ;
PRINT
 New Rcp,Print
 Do STORE^vhTERMINA()
 Do INIT^vhLISTO("EWRCPST","LIJST",.Rcp)
 Set Rcp(5)=80
 Xecute "Set Rcp(8)="_$E(Rcp(8),3,999)
 Set Rcp(2)=Rcp(2,"R"),Rcp(2,1)=Rcp(2,"S"),Rcp(2,2)=Rcp(2,"W"),Rcp(2,3)=Rcp(2,"D")
 Kill Rcp(2,"R"),Rcp(2,"S"),Rcp(2,"W"),Rcp(2,"D")
 Set Rcp(10)="CBPRINT^"_$ZN,Rcp(11)="Receptie"
 Do PRINT^OUTPUT(.Rcp,"P")
 Do REFRESH^vhTERMINA()
 Quit
 ;
CBPRINT(Ref) 
 If $E(Ref)'="^" Quit ""
 Set sRec=$G(@Ref)
 Quit:$P(sRec,D)=$P(sRec,D,11) ";1"
 Quit:$P(sRec,D,12)="W" ";2"
 Quit ""
 ;
 ; Versturen van een 'ADMIN'-mail i.v.m. een receptie
SendMail(RCPNr)
 New R
 Set R=^RCP("D",RCPNr)
 Do:$P(R,D)="K" ; Klant, terugname
 . New BONNr,KLNr,TUserId,Tekst,RefLink,Optie
 . Set KLNr=$P(R,D,2)
 . Set BONNr=$O(^RCP("D",RCPNr,"D",""))
 . Quit:BONNr=""
 . Set TUserId=$$SendMailTUserId()
 . Set RefLink(1)="KL\"_KLNr_"\R\L"
 . Set RefLink(2)="EWRCPST\"_RCPNr_"\R"
 . Set RefLink(3)="BON\"_BONNr_"\R"
 . Set Optie("URG")="U"
 . Set Optie("TYPE")="I"
 . Set Optie("RESP")="G"
 . Set Optie("INITEXEC")="D`INITEXECSendMail^EWRCPST3"
 . Do EXTERN^vhMAIL("KL",KLNr,"Terugname "_BONNr,TUserId,.Tekst,.RefLink,.Optie)
 Do:$P(R,D)="L" ; Leverancier, levering
 . New I,TOENr,LEVNr,TUserId,Tekst,RefLink,Optie
 . Set LEVNr=$P(R,D,2)
 . Set TUserId=$$SendMailTUserId()
 . Set I=1,RefLink(I)="EWRCPST\"_RCPNr_"\R",TOENr=""
 . For  Set TOENr=$O(^RCP("D",RCPNr,"D",TOENr)) Quit:TOENr=""  Set:$D(^KTO(LEVNr,TOENr)) I=I+1,RefLink(I)="TL\"_TOENr_"\R"
 . Set Optie("URG")="U"
 . Set Optie("TYPE")="I"
 . Set Optie("RESP")="G"
 . Set Optie("INITEXEC")="D`INITEXECSendMail^EWRCPST3"
 . Do EXTERN^vhMAIL("LE",LEVNr,"Receptie "_RCPNr,TUserId,.Tekst,.RefLink,.Optie)
 Quit
 ;
 ; Uit te voeren INITEXEC i.p.v. INITEXEC^vhMAIL4
INITEXECSendMail()
 New I
 For I=1:1:$O(sScrnDef(""),-1) Do PUTATTR^vhScherm(I,"D","D")
 For I="CC","ANTWOORD","DRINGEND" Do PUTATTR^vhScherm(I,"H","H")
 Do REMATTR^vhScherm("TEKST","D","D")
 Quit
 ;
SendMailTUserId()
 New TUserId,RerouteMailToUserID
 Set TUserId=1091 ; Receptie
 Set RerouteMailToUserID = ##class(TECH.Config.ConfigMgr).Instance().GetString("EWRCPST3_RerouteMailToUserID")
 If (RerouteMailToUserID '= "") Set TUserId=RerouteMailToUserID ; CW indien niet CACHE01
 Quit TUserId