FAKTCRED ;Lijsten van credietnotas in een bep. maand [ 09/11/2000  4:40 PM ]
 If '$D(Q) S Q="K" D ^cA604
 Set %J=$J
 Kill ^HULP(%J)
 Write @F11,@F1,@FMTI,"Overzicht KREDIETNOTA's - ",QN,@FMTi
ASK Set Mnd=$$CALCDATE^vhLib.DataTypes($H,"M",-1,"MD")
 Set Mnd=$$ASK^vhINP("Voor welke maand wenst U de KREDIETNOTA's : ",5,$$EXTDATE^vhLib.DataTypes(Mnd,"DM"))
 Quit:Mnd="-"!(Mnd=".")
 Set Mnd=$$INTDATE^vhLib.DataTypes(Mnd,"DM")
 Goto ASK:'Mnd
 Set Begin=-$$CALCDATE^vhLib.DataTypes(Mnd,"M","FD")
 Set End=-$$CALCDATE^vhLib.DataTypes(Mnd,"M","LD")-1
 Set BJaar=$$EXTDATE^vhLib.DataTypes($$CALCDATE^vhLib.DataTypes(Mnd,"M",7),"J4")#100
 Set:BJaar>93 BJaar=BJaar#10
 Set KLNr=0
 Set (Cnt,CntKL)=0
 Set FP=2101 Write @F,@F1,"Kredietnota's voor de maand : ",$$EXTDATE^vhLib.DataTypes(Mnd,"DM"),!!,"Aantal klanten verwerkt : ",@FCH
 For  Set KLNr=$O(^KFA1("F",KLNr)) Quit:'KLNr  Do
 .Set CntKL=CntKL+1
 .If CntKL#7 Set FP=2327 Write @F,CntKL,@F2
 .Set Dat=End
 .For  Set Dat=$O(^KFA1("F",KLNr,Dat)) Quit:'Dat  Quit:Dat>Begin  Do
 ..Set FANr=""
 ..For  Set FANr=$O(^KFA1("F",KLNr,Dat,FANr)) Quit:'FANr  Do
 ...Set Rec=^KFA("F",FANr,0,0)
 ...Set IsCredit=$P(Rec,D,2)="C"
 ...Set Sign=$S($P(Rec,D,2)="C":-1,1:1)
 ...Set ULNr="U"
 ...For  Quit:IsCredit  Set ULNr=$O(^KFA("F",FANr,ULNr)) Quit:ULNr=""  Do
 ....Set Lijn=99
 ....For  Quit:IsCredit  Set Lijn=$O(^KFA("F",FANr,ULNr,Lijn)) Quit:'Lijn  Do
 .....Set IsCredit=$P(^KFA("F",FANr,ULNr,Lijn),D,3)<0
 ...Quit:'IsCredit
 ...Set ^HULP(%J," "_FANr)=FANr_D_KLNr_D_$P(^KKL(^KK1(KLNr),0),D,2)_D_$P(Rec,D,6)_D_$P(Rec,D,5)_D_(Sign*$P(Rec,D,7))
 W @FCS
 Do INIT^PROC("FAKTCRED")
 Set FAKTCRED(11)="KREDIETNOTA's van de maand "_$$EXTDATE^vhLib.DataTypes(Mnd,"DM")
 Do RL^PROC1
 Do PRINT^OUTPUT(.FAKTCRED,"SPT","S")
 Kill ^HULP(%J)
 Quit