KFWISC ;AFDRUKKEN WISSELS ;KFWISC; Do naar PROC [ 11/29/2003   1:16 PM ]
 G BEGIN
 ;
T1 ;"Klant";C;L;23;;|\"Woonplaats";C;L;20;;|\"#F";C;R;2;;|\"#W";C;R;2;;|\"#V";C;R;2;;|\" Bedr wissel";C;L;13;;|\"Mnt";C;L;3;;|\"Verv dat";C;L;8;;
T2 ;8;C;L;23;;|\9;C;L;20;;|\1;N+;R;2;;|\2;N+;R;2;;|\3;N+;R;2;;|\5;N;R;13;2;|\10;C;L;3;;|\12;C;L;8;;
T3 ;"Faktuur";C;L;10;;| \"Fakt dat";C;L;9;;| \"Verv dat";C;L;9;;|\"Bedrag ";C;R;11;;|\"Mnt";C;C;5;;|\" Onbetaald";C;L;11;;|\"";C;L;9;;|\"W";C;C;3;;|\"V";C;C;3;;
T4 ;4;C;R;1;; \3;N;L;8;;| \5;C;L;9;;| \6;C;L;9;;|\7;N;R;11;2;| \9;C;L;3;; |\8;N;R;11;2;|\"";C;L;9;;|\1;C;C;3;;|\2;C;C;3;;
T5 ;SINT NIKLAAS
T6 ;MEUBELBESLAG;QUINC PR MEUBLES;MEUBELBESLAG;MEUBELBESLAG
T7 ;GOED VOOR AVAL VOOR;BON POUR AVAL POUR;GOED VOOR AVAL VOOR;GOED VOOR AVAL VOOR
T8 ;DE BETROKKENE;LE TIRE;DE BETROKKENE;DE BETROKKENE
T9 ;DUPLICAAT;DUPLICATE;DUPLICAAT;DUPLICAAT
T10 ;FAKTUURNR(S);FAKTUURNR(S);FAKTUURNR(S);FAKTUURNR(S)
T11 ;440 085 040;Btw-nummer
T17 ;*** I'm thinking ***
T18 ;Klanten;Detail
T20 ;WISSELS GOED AFGEDRUKT : .
T21 ;VERWIJDEREN GEMARKEERDE FAKTUREN : .
T22 ;[] = ok;   , = hernemen
 ;
 ; Schermaanduiding
SA S FP=255 W @F,@FMTB,$J($P($T(T18),U,$F("KD",U4)),25),@FMTb
 Q
 ;
SA1 S FP=255 W @F,$J("",5),@FMTK,$P($T(T17),U,2),@FMTk
 Q
 ;
 ; Initialisatie
INIT S K=$P($T(+1),U,2)_QN_" ",FP=203+$L(K) W @F61,@F11,@F1,@F,@F5 S FP=202 W @F,@F4,K,@F5
 L ^KFBWC:2 E  X ^cTXT(0,"N",46) R K Q
 S KL(1)="KLT",KL(2)=$P($T(T2),U,2,99),KL(3)=5,KL(4)=10,KL(6)=1,KL(8)=$P($T(T1),U,2,99)
 S FA(1)="FAT",FA(2)=$P($T(T4),U,2,99),FA(3)=16,FA(8)=$P($T(T3),U,2,99)
 S US="F",U4="K"
 S NM2=^KBA(99,2),NM3=^KBA(99,3)
 D SA1
 K ^HULP($J) S FNR=""
 F  S FNR=$O(^KFBWC(US,FNR)) Q:FNR=""  D
 .S K=^KFA(US,FNR,0,0),KC=$P(K,D),MNT=$P(K,D,5) I MNT="" S MNT=" "
 .S KI=^KK1(KC)
 .I '$D(^KKL(KI,FNR)) K ^KFBWC(US,FNR) Q
 .I '$D(KLT(KI_MNT)) S K=^KKL(KI,0),$P(KLT(KI_MNT),D,7)=$P(K,D,1,2)_D_$P(K,D,7)_D_MNT
 .S K=^KKL(KI,FNR)
 .S R=KLT(KI_MNT),$P(R,D)=$P(R,D)+1,$P(R,D,4)=$P(R,D,4)+$P(K,D,5),KLT(KI_MNT)=R
 .S ^HULP($J,KC,MNT,FNR)=D
 S DL(1)="KL" D RL^PROC1,WL^PROC
 Q
 ;
 ; Selektie klant
KLANT D SA K DL S DL(1)="KL",DL(3)=-3
K1 D SL^PROC
 S:R=""!(R="ENTER") R="D"
 I R="K" S DL(2)="DO" D ML^PROC K DL(2) G K1
 I "\-\A\D\P\V\"'[(D_R_D) G K1
 S U4=R
 Q
 ;
 ; Detail klant
DETAIL K FAT,FA(7),FA(9) S R=KLT(KL(6)),KC=$P(R,D,7),MNT=$P(R,D,10),KI=^KK1(KC)
 S FNR="",CNT=0
 F  S FNR=$O(^HULP($J,KC,MNT,FNR)) Q:FNR=""  D
 .S R=^HULP($J,KC,MNT,FNR)
 .S K=^KKL(KI,FNR),$P(R,D,3)=FNR_D_$P(K,D,1,5)_D_$P(K,D,9)
 .S CNT=CNT+1,FAT(CNT)=R
 D SA K DL S DL(1)="FA",FA(6)=1 D WL^PROC
D1 D SL^PROC
 I R="W" G D1:$D(PRT) D MWISSEL G D1
 I R="V" D MVERW G D1
 I R="A" D AUTOSEL G DETAIL
 I "\-\K\P\"'[(D_R_D) G D1
 D CL^PROC1 S U4=R
 I R="K" K DL S DL(1)="KL",DL(2)="DO" D ML^PROC
 Q
 ;
 ; Markeer voor afdruk op wissel
MWISSEL S K=KLT(KL(6)),R=FAT(FA(6))
 I $P(R,D)="" S $P(R,D)="*",$P(K,D,2)=$P(K,D,2)+1,$P(K,D,5)=$P(K,D,5)+$$FSALDO($P(R,D,4),$P(R,D,8))
 E  S $P(R,D)="",$P(K,D,2)=$P(K,D,2)-1,$P(K,D,5)=$P(K,D,5)-$$FSALDO($P(R,D,4),$P(R,D,8))
 S FNR=$P(R,D,3)
 I $L($P(R,D,2)) S $P(R,D,2)="",$P(K,D,3)=$P(K,D,3)-1,$P(K,D,6)=$P(K,D,6)-$$FSALDO($P(R,D,4),$P(R,D,8))
 S ^HULP($J,KC,MNT,FNR)=$P(R,D,1,2)
 S FAT(FA(6))=R D UVDAT S KLT(KL(6))=K
 K DL S DL(1)="KL" D EL^PROC
 K DL S DL(1)="FA" D EL^PROC
 S DL(2)="DO" D ML^PROC K DL(2)
 Q
 ;
 ; Markeer voor verwijderen zonder afdruk
MVERW S K=KLT(KL(6)),R=FAT(FA(6))
 I $D(PRT),$L($P(R,D)) Q
 I $P(R,D,2)="" S $P(R,D,2)="*",$P(K,D,3)=$P(K,D,3)+1,$P(K,D,6)=$P(K,D,6)+$$FSALDO($P(R,D,4),$P(R,D,8))
 E  S $P(R,D,2)="",$P(K,D,3)=$P(K,D,3)-1,$P(K,D,6)=$P(K,D,6)-$$FSALDO($P(R,D,4),$P(R,D,8))
 S FNR=$P(R,D,3)
 I $L($P(R,D)) S $P(R,D)="",$P(K,D,2)=$P(K,D,2)-1,$P(K,D,5)=$P(K,D,5)-$$FSALDO($P(R,D,4),$P(R,D,8))
 S ^HULP($J,KC,MNT,FNR)=$P(R,D,1,2)
 S FAT(FA(6))=R D UVDAT S KLT(KL(6))=K
 K DL S DL(1)="KL" D EL^PROC
 K DL S DL(1)="FA" D EL^PROC
 S DL(2)="DO" D ML^PROC K DL(2)
 Q
 ;
 ; Automatisch markeren voor afdruk op wissel
AUTOSEL S K=KLT(KL(6)),KC=$P(K,D,7),MNT=$P(K,D,10),KI=^KK1(KC)
 S FNR=""
 F  S FNR=$O(^HULP($J,KC,MNT,FNR)) Q:FNR=""  D
 .S R=^KKL(KI,FNR),FDT=$P(R,D,2),R=^HULP($J,KC,MNT,FNR)_D_FNR_D_$P(R,D,1,5)_D_$P(R,D,9)
 .I $L($P(R,D)) S $P(K,D,2)=$P(K,D,2)-1,$P(K,D,5)=$P(K,D,5)-$$FSALDO($P(R,D,4),$P(R,D,8))
 .I $$CALCDATE^vhLib.DataTypes($$INTDATE^vhLib.DataTypes(FDT),"M","FD")'<$$CALCDATE^vhLib.DataTypes($$INTDATE^vhLib.DataTypes(DT),"M","FD")  S $P(R,D)=""
 .E  S $P(R,D)="*" I $L($P(R,D,2)) S $P(R,D,2)="",$P(K,D,3)=$P(K,D,3)-1,$P(K,D,6)=$P(K,D,6)-$$FSALDO($P(R,D,4),$P(R,D,8))
 .I $L($P(R,D)) S $P(K,D,2)=$P(K,D,2)+1,$P(K,D,5)=$P(K,D,5)+$$FSALDO($P(R,D,4),$P(R,D,8))
 .S ^HULP($J,KC,MNT,FNR)=R
 D UVDAT S KLT(KL(6))=K
 K DL S DL(1)="KL" D EL^PROC
 Q
 ;
 ; Bepalen uitgifte- en vervaldatum wissel
UVDAT S (DDT,UDT,VDT,FNR)=""
 F  S FNR=$O(^HULP($J,KC,MNT,FNR)) Q:FNR=""  D
 .S R=^HULP($J,KC,MNT,FNR) Q:$P(R,D)=""
 .S R=$P(^KKL(KI,FNR),D,2)
 .I $$INTDATE^vhLib.DataTypes(UDT)<$$INTDATE^vhLib.DataTypes(R) S UDT=R
 .S R=$TR(R,".","/") I DDT'[$E(R,4,8) S:$L(DDT) DDT=DDT_" - " S DDT=DDT_$E(R,4,8)
 .S R=$P(^KKL(KI,FNR),D,3)
 .I $$INTDATE^vhLib.DataTypes(VDT)<$$INTDATE^vhLib.DataTypes(R) S VDT=R
 S $P(K,D,11)=UDT,$P(K,D,12)=VDT,$P(K,D,13)=DDT
 Q
 ;
 ; Nazicht print en of verwijderen
CHECK S KC=""
 I $D(PRT),'PRT K PRT
 I $D(DEL),'DEL K DEL
 F  S KC=$O(^HULP($J,KC)) Q:KC=""!($D(PRT)&$D(DEL))  D
 .S MNT=""
 .F  S MNT=$O(^HULP($J,KC,MNT)) Q:MNT=""!($D(PRT)&$D(DEL))  D
 ..S FNR=""
 ..F  S FNR=$O(^HULP($J,KC,MNT,FNR)) Q:FNR=""!($D(PRT)&$D(DEL))  D
 ...S R=^HULP($J,KC,MNT,FNR)
 ...I $L($P(R,D)),'$D(PRT) S PRT=0
 ...I $L($P(R,D,2)),'$D(DEL) S DEL=0
 Q
 ;
FSALDO(FCODE,BEDRAG) 
 Q $S(FCODE="C":-BEDRAG,1:BEDRAG)
 ;
 ; Afdrukken wissels (vraagstelling)
PRINT I PRT Q
P1 S FP=2201 W @F,@F1
 D INIT^vhPRINTER("","")
 I '$D(Print) G P2:PRT S R=",",U4="K" K PRT Q
 D PWISSEL
P2 S FP=2203 W @F,@F1,$P($T(T20),U,2),!?2,$P($T(T22),U,2),$P($T(T22),U,3)
P3 W @F0 K IK D IK^PROC1 G P1:R=","
 G P3:R'="ENTER"
 Q
 ;
 ; Afdrukken wissels (print)
PWISSEL S PRT=1
 S:'$D(V) V=0
 S R=24 D ^KFOLE
 B 0
 S CNT=0
 F  S CNT=$O(KLT(CNT)) Q:CNT=""  D
 .S R=KLT(CNT),KC=$P(R,D,7),MNT=$P(R,D,10),UDT=$P(R,D,11),VDT=$P(R,D,12),DDT=$P(R,D,13),KI=^KK1(KC)
 .S DEC=$$MUNT^vhRtn1(MNT,4)
 .S:DDT[" - " DDT=$P(DDT," - ")_"-"_$P(DDT," - ",$L(DDT," - "))
 .S UDT=$$CALCDATE^vhLib.DataTypes($$INTDATE^vhLib.DataTypes(UDT,"DK"),"M","LD")
 .S:UDT>$H UDT=$H S UDT=$TR($$EXTDATE^vhLib.DataTypes(UDT,"DK"),"-",".")
 .S K=^KKL(KI,0),KN=$P(K,D,2),KA=$P(K,D,4)
 .S KS=$P(K,D,5),KP=$P(K,D,6),KW=$P(K,D,7)
 .S KT=$P(K,D,9),TL=$F("NFDE",KT)-1,KBN=$P(K,D,16),KX=$P(K,D,18)
 .S K=^KKL(KI,1),KBR=$P(K,D,1),KBT=$P(K,D,16),KHR=$P(K,D,21)
 .K FNR,FREF,CREF S (FNR,FREF,CREF)="",TTB=0
 .F  S FNR=$O(^HULP($J,KC,MNT,FNR)) Q:FNR=""  D
 ..S R=^HULP($J,KC,MNT,FNR) Q:$P(R,D)=""
 ..S FNR(FNR)=""
 ..S REF="FREF" ;I $L(FREF)>28 S REF="CREF"
 ..S:$L(@REF) @REF=@REF_","
 ..S @REF=@REF_FNR
 ..;I '$D(@(REF_"($E(FNR,1,2))")) S @(REF_"($E(FNR,1,2))")="",@REF=@REF_FNR
 ..;E  S @REF=@REF_$E(FNR,3,6)
 ..S R=^KKL(KI,FNR),TTB=TTB+$$FSALDO($P(R,D),$P(R,D,5))
 .Q:TTB'>0
 .S WNR=$P(KLT(CNT),D,14) I 'WNR D
 ..S WNR=^KBA(177),^(177)=WNR+1,FNR=""
 ..S $P(KLT(CNT),D,11)=UDT,$P(KLT(CNT),D,14)=WNR
 ..F  S FNR=$O(FNR(FNR)) Q:FNR=""  S $P(^KFA(US,FNR,0,3),D,25)=WNR_"#1"
 .Write *27,0 ; 8 lijnen per inch
 .Write !
 .Write *27,2 ; 6 lijnen per inch
 .Write !!!
 .Set R="+ "_$TR($$EXTNUM^vhLib.DataTypes(TTB,0,".",DEC),"."," ")_" +"
 .Write ?V+3,$P($T(T5),U,2),?V+24,$TR($$EXTDATE^vhLib.DataTypes($$INTDATE^vhLib.DataTypes(UDT),"DK4"),".","-")
 .Write ?V+41,$TR($$EXTDATE^vhLib.DataTypes($$INTDATE^vhLib.DataTypes(VDT),"DK4"),".","-"),?V+65-($L(R)\2),R
 .Write:$E(KX,$L(KX))="A" ?V+83,$P($T(T7),U,TL+1)
 .Write ! Write:$E(KX,$L(KX))="A" ?V+82,$P($T(T8),U,TL+1)
 .Set R=TTB D @("^KY125"_$S(KT="F":"F",1:"N")) Set:$L(R1) R=R_R1
 .Set:$E(R,$L(R))'=" " R=R_" " Set $P(R,"*",68-$L(R))="*"
 .Write !!!?V+6,R,$C(13),?V+6,R,$C(13),?V+6,R
 .Set:FREF["," FREF=$P(FREF,",")_"/"_$P(FREF,",",$L(FREF,","))
 .Set R=$P($T(T6),U,TL+1)_" - "_$P($T(T10),U,TL+1)_" "_FREF_" DD "_DDT
 .Write !?V+17,$E(R,1,58)
 .Write ?V+82,KA Write:$L(KA) " " Write $E(KN,1,30-$L(KA))
 .Write !?V+82,KS
 .Write !?V+82,KP,"  ",KW
 .Write ! ;?V+5,QN,?V+52,$P($T(T11),U,2)
 .Write ?V+82,KHR
 .Write ! ;?V+5,NM2
 .Write ! ;?V+5,NM3,?V+45,$P($T(T5),U,2),"  ",$P($T(T12),U,2)
 .Write ?V+93,$E(KBN,1,3)," ",$E(KBN,4,6)," ",$E(KBN,7,9)
 .Write !!?V+58,QN
 .If $L(KBR) Write ?V+93,$E(KBR,1,3),"-",$E(KBR,4,10),"-",$E(KBR,11,12)
 .Write #
 S R=$P(^cLOG(boot,"DEV",$$DEV^vhPRINTER($I,1)),D,11) S:'R R=66 D ^KFOLE D CLOSE^vhPRINTER
 Q
 ;
 ; Verwijderen wissels (vraagstelling)
VERW S FP=2203 W @F,@F1,$P($T(T21),U,2),!?2,$P($T(T22),U,2),$P($T(T22),U,3)
V1 W @F0 K IK D IK^PROC1 I R="," S U4="K",FP=2203 W @F,@F1 Q
 G V1:R'="ENTER"
 Q
 ;
 ; Opkuis van het cumulbakje
CLEAN S KC=""
 F  S KC=$O(^HULP($J,KC)) Q:KC=""  D
 .S MNT=""
 .F  S MNT=$O(^HULP($J,KC,MNT)) Q:MNT=""  D
 ..S FNR=""
 ..F  S FNR=$O(^HULP($J,KC,MNT,FNR)) Q:FNR=""  D
 ...S R=^HULP($J,KC,MNT,FNR)
 ...I '$L($P(R,D)),'$L($P(R,D,2)) Q
 ...I $L($P(R,D,2)),'$D(DEL) Q
 ...K ^KFBWC(US,FNR)
 Q
 ;
BEGIN D INIT G END:'$D(^HULP($J))
INPUT I U4="-" G END:'$D(PRT) K DEL D CLEAN G END
 I U4="K" D KLANT G INPUT
 I U4="D" D DETAIL G INPUT
 I U4="A" D AUTOSEL S U4="D" G INPUT
 I U4="P" D CHECK,PRINT:$D(PRT) G INPUT:R="," D VERW:$D(DEL) G INPUT:R="," D CLEAN G END
 I U4="V" D CHECK,PRINT:$D(PRT) G INPUT:R="," D VERW:$D(DEL) G INPUT:R="," D CLEAN G END
 S U4="K" G INPUT
 ;
END K ^HULP($J) Q
 ;
R3 S R1=$P(R,D,2),R2=$P(R,D,4),R0=$J($P(R,D,1),0,R2),R3=" ",R4="" S:R2 R4=","_$P(R0,".",2),R1=R1-1-R2 S:R0<0 R3="-",R0=-R0
R3A S R0=+$P(R0,".",1) F R5=3,7 S R6=$L(R0) G R3B:R6'>R5 S R0=$E(R0,1,R6-R5)_"."_$E(R0,R6-R5+1,R6)
R3B W ?$P(R,D,3),$J(R0,R1),R4,R3
R3Z K R0,R1,R2,R3,R4,R5,R6 Q  ;V1 26.11.84
 ;
T12 ;48.193;Handelsregister
 ;