KLACHTS ;KLACHTEN (Selekteer) [ 11/20/2003  3:41 PM ]
 ;
 ; LimT   = Type limiet ("" (geen beperking), "K" (klant), "L" (leverancier), "O" (order), "B" (bon), "F" (factuur) of "V" (proforma))
 ; LimV   = Waarde indien LimT'=""
 ; LimS   = Beperking status (R, B, A of een combinatie)
 ; Titel  = Andere dan de standaard titel
 ; Keys   = Toegelaten keys
 ; Koppel = Te koppelen element
 ; Beperk = Eventuele extra beperking doogegeven als .Local vb om de orders of bons te beperken tot een klant
 ;          Beperk("KLNr")=KLNr
SELECT(LimT,LimV,LimS,Titel,Keys,Koppel,Beperk) 
 New KlachtId,X,Y,K,KLNr,LEVNr,ORDNr,BONNr,FANr,PRNr,Klacht,KLKey,LD,Count,LimO
 Set (LimO,LimT)=$G(LimT),LimV=$G(LimV),LimS=$G(LimS),Keys=$G(Keys)
 Do STORE^vhTERMINA()
 Set KlachtId=""
 For  Do  Quit:"\L\K\N\Z\"'[(D_$P(KlachtId,D)_D)
 .Do LIST(LimT,LimV):$L(LimT),LISTKL():'$L(LimT)
 .If '$L(LimO),KlachtId="L" Do
 ..Do STORE^vhTERMINA()
 ..Set KLKey=$$SELECT^LEVER(1,"","Incident betreffende leverancier : ")
 ..Set:KLKey LimT="L",LimV=KLKey
 ..Do REFRESH^vhTERMINA()
 .If '$L(LimO),KlachtId="K" Do
 ..Do STORE^vhTERMINA()
 ..Set KLKey=$$SELECT^KLANT6(1,"","Incident betreffende klant : ")
 ..Set:KLKey LimT="K",LimV=KLKey
 ..Do REFRESH^vhTERMINA()
 .If KlachtId="N" Do
 ..Do STORE^vhTERMINA()
 ..Set KlachtId=$$ASKL^vhINP("KLACHTS","NUMMER")
 ..Set:KlachtId LimT="N",LimV=KlachtId Set:'KlachtId KlachtId="N"
 ..Do REFRESH^vhTERMINA()
 .If '$L(LimO),KlachtId="Z" Set (LimT,LimV)=""
 .If KlachtId="*" Set KlachtId=KlachtId_D_LimT_D_LimV
 Do REFRESH^vhTERMINA()
 Quit KlachtId
 ;
LISTKL() ; Tonen van de volledige lijst
 Kill I,Y,X,KlachtId,Klacht,LD
 Do STORE^vhTERMINA()
 Do INIT^vhLIST("KLACHTS","SELECTKL",.LD)
 If $L($G(Keys)) Do
 .For I=1:1 Quit:'$D(LD("B",I))  Do KDISABLE^KLACHT(.LD,$P(LD("B",I),"`",6))
 .For I=1:1:$L(Keys) Do KENABLE^KLACHT(.LD,$E(Keys,I))
 .For I=1:1 Quit:$P(LD("B",I),"`",3)=""
 .Set $P(LD("B"),"`",5)=I
 Set LD("CM")="F`KLMORE^KLACHTS"
 Do KDISABLE^KLACHT(.LD,"Z")
 Set X=$P(LD("POS"),";",3)-$P(LD("POS"),";")+1
 Set X=$$KLMORE(0,X)
 If $O(Y(""))="" Set X="*"
 Else  Do WRITE^vhLIST(.LD) For  Set X=$$SCROLL^vhLIST(.LD) Quit:"TY"'[X  Do  Quit:$P(X,D)="Y"
 .If X="T" Do
 ..Do STORE^vhTERMINA()
 ..Set KlachtId=Y(LD("SELECT"))
 ..Set R=$$RAADPL^KLACHT(KlachtId,,,,"O")
 ..Do REFRESH^vhTERMINA()
 .Else  If X="Y" Set X=$$KOPPEL(Y(LD("SELECT"))) Set:$L(X) X="Y\"_Y(LD("SELECT"))_D_X
 Set KlachtId=$S(X:$G(Y(LD("SELECT"))),1:X)
 Do REFRESH^vhTERMINA()
 Quit
 ;
LIST(LimT,LimV) ; Tonen van de lijst volgens ...
 Kill I,Y,X,LevRef,KLNr,Klacht,LD
 Do STORE^vhTERMINA()
 Do INIT^vhLIST("KLACHTS","SELECT",.LD)
 If $L($G(Keys)) Do
 .For I=1:1 Quit:'$D(LD("B",I))  Do KDISABLE^KLACHT(.LD,$P(LD("B",I),"`",6))
 .For I=1:1:$L(Keys) Do KENABLE^KLACHT(.LD,$E(Keys,I))
 .For I=1:1 Quit:$P(LD("B",I),"`",3)=""
 .Set $P(LD("B"),"`",5)=I
 Set LD("CM")="F`"_LimT_"MORE^KLACHTS"
 Do KDISABLE^KLACHT(.LD,"L"),KDISABLE^KLACHT(.LD,"K")
 Do:$L(LimO) KDISABLE^KLACHT(.LD,"Z")
 Set X=$P(LD("POS"),";",3)-$P(LD("POS"),";")+1
 Xecute "Set X=$$"_LimT_"MORE(0,X)"
 If $O(Y(""))="" Set X="*"
 Else  Do WRITE^vhLIST(.LD) For  Set X=$$SCROLL^vhLIST(.LD) Quit:"TY"'[X  Do  Quit:$P(X,D)="Y"
 .If X="T" Do
 ..Do STORE^vhTERMINA()
 ..Set KlachtId=Y(LD("SELECT"))
 ..Set R=$$RAADPL^KLACHT(KlachtId,,,,"O")
 ..Do REFRESH^vhTERMINA()
 .Else  If X="Y" Set X=$$KOPPEL(Y(LD("SELECT"))) Set:$L(X) X="Y\"_Y(LD("SELECT"))_D_X
 Set KlachtId=$S(X:$G(Y(LD("SELECT"))),1:X)
 Do REFRESH^vhTERMINA()
 Quit
 ;
KLMORE(Max,Len,Ref)  ; Klacht MORE
 Quit:$G(KlachtId)=-1 Max
 If Max>200 w *7 Quit Max 
 Set Count=0 
 If 'Max Set Klacht="",KlachtId=LimV
 For  Quit:Count'<Len  Set Klacht=$O(^KlachtD(Klacht),-1) Quit:Klacht=""  Do
 .If $L(LimS) Quit:LimS'[$$STATUS^KLACHTO(Klacht,,1)
 .Set Count=Count+1,Y(Max+Count)=Klacht
 Set:Klacht="" KlachtId=-1
 Quit Max+Count
 ;
KMORE(Max,Len,Ref)  ; Klant MORE
 Quit:$G(KLNr)=-1 Max
 If Max>200 w *7 Quit Max 
 Set Count=0 
 If 'Max Set Klacht="",KLNr=LimV
 For  Quit:Count'<Len  Set Klacht=$O(^KlachtI("K",KLNr,Klacht),-1) Quit:Klacht=""  Do
 .If $L(LimS) Quit:LimS'[$$STATUS^KLACHTO(Klacht,,1)
 .Set Count=Count+1,Y(Max+Count)=Klacht
 Set:Klacht="" KLNr=-1
 Quit Max+Count
 ;
LMORE(Max,Len,Ref)  ; Leverancier MORE
 Quit:$G(LEVNr)=-1 Max
 If Max>200 w *7 Quit Max 
 Set Count=0 
 If 'Max Set Klacht="",LEVNr=LimV
 For  Quit:Count'<Len  Set Klacht=$O(^KlachtI("L",LEVNr,Klacht),-1) Quit:Klacht=""  Do
 .If $L(LimS) Quit:LimS'[$$STATUS^KLACHTO(Klacht,,1)
 .Set Count=Count+1,Y(Max+Count)=Klacht
 Set:Klacht="" LEVNr=-1
 Quit Max+Count
 ;
OMORE(Max,Len,Ref)  ; Order MORE
 Quit:$G(ORDNr)=-1 Max
 If Max>200 w *7 Quit Max 
 Set Count=0 
 If 'Max Set Klacht="",ORDNr=LimV
 For  Quit:Count'<Len  Set Klacht=$O(^KlachtI("O",ORDNr,Klacht),-1) Quit:Klacht=""  Do
 .New KLNr
 .If $G(Beperk("KLNr")) Set KLNr=$P($G(^KO1(ORDNr,"F")),D) Quit:KLNr'=Beperk("KLNr")  If KLNr,$P(^KlachtD(Klacht),D)="K",$P(^KlachtD(Klacht),D,2)'=KLNr Quit
 .If $L(LimS) Quit:LimS'[$$STATUS^KLACHTO(Klacht,,1)
 .Set Count=Count+1,Y(Max+Count)=Klacht
 Set:Klacht="" ORDNr=-1
 Quit Max+Count
 ;
BMORE(Max,Len,Ref)  ; Bon MORE
 Quit:$G(BONNr)=-1 Max
 If Max>200 w *7 Quit Max 
 Set Count=0 
 If 'Max Set Klacht="",BONNr=LimV
 For  Quit:Count'<Len  Set Klacht=$O(^KlachtI("B",BONNr,Klacht),-1) Quit:Klacht=""  Do
 .New KLNr
 .If $G(Beperk("KLNr")) Set KLNr=$P($G(^KU1(BONNr,"F")),D) Quit:KLNr'=Beperk("KLNr")  If KLNr,$P(^KlachtD(Klacht),D)="K",$P(^KlachtD(Klacht),D,2)'=KLNr Quit
 .If $L(LimS) Quit:LimS'[$$STATUS^KLACHTO(Klacht,,1)
 .Set Count=Count+1,Y(Max+Count)=Klacht
 Set:Klacht="" BONNr=-1
 Quit Max+Count
 ;
FMORE(Max,Len,Ref)  ; Factuur MORE
 Quit:$G(FANr)=-1 Max
 If Max>200 w *7 Quit Max 
 Set Count=0 
 If 'Max Set Klacht="",FANr=LimV
 For  Quit:Count'<Len  Set Klacht=$O(^KlachtI("F",FANr,Klacht),-1) Quit:Klacht=""  Do
 .If $L(LimS) Quit:LimS'[$$STATUS^KLACHTO(Klacht,,1)
 .Set Count=Count+1,Y(Max+Count)=Klacht
 Set:Klacht="" FANr=-1
 Quit Max+Count
 ;
VMORE(Max,Len,Ref)  ; Proforma MORE
 Quit:$G(FANr)=-1 Max
 If Max>200 w *7 Quit Max 
 Set Count=0 
 If 'Max Set Klacht="",FANr=LimV
 For  Quit:Count'<Len  Set Klacht=$O(^KlachtI("V",FANr,Klacht),-1) Quit:Klacht=""  Do
 .If $L(LimS) Quit:LimS'[$$STATUS^KLACHTO(Klacht,,1)
 .Set Count=Count+1,Y(Max+Count)=Klacht
 Set:Klacht="" FANr=-1
 Quit Max+Count
 ;
TIT(LimT,LimV,Titel) ; Titel afhankelijk van LimT en Titel
 New StdTitel
 Set StdTitel='$D(Titel),Titel=$G(Titel,"Selecteer een incident")
 If LimT="L" Do
 .Set:StdTitel Titel=Titel_" betreffende leverancier :"
 .Set:$L(Titel) Titel=Titel_" "
 .Set Titel=Titel_$P(^KLE(^KL1(LimV),0),D,2)
 If LimT="K" Do
 .Set:StdTitel Titel=Titel_" betreffende klant :"
 .Set:$L(Titel) Titel=Titel_" "
 .Set Titel=Titel_$P(^KKL(^KK1(LimV),0),D,2)
 If LimT="O" Do
 .Set:StdTitel Titel=Titel_" betreffende order :"
 .Set:$L(Titel) Titel=Titel_" "
 .Set Titel=Titel_LimV
 If LimT="B" Do
 .Set:StdTitel Titel=Titel_" betreffende bon :"
 .Set:$L(Titel) Titel=Titel_" "
 .Set Titel=Titel_LimV
 If LimT="F" Do
 .Set:StdTitel Titel=Titel_" betreffende factuur :"
 .Set:$L(Titel) Titel=Titel_" "
 .Set Titel=Titel_LimV_$S($D(^KFA("F",LimV)):" van "_$P(^KKL(^KK1($P(^KFA("F",LimV,0,0),D)),0),D,2),1:"")
 If LimT="V" Do
 .Set:StdTitel Titel=Titel_" betreffende proforma :"
 .Set:$L(Titel) Titel=Titel_" "
 .Set Titel=Titel_LimV_$S($D(^KFAP("F",LimV)):" van "_$P(^KKL(^KK1($P(^KFAP("F",LimV,0,0),D)),0),D,2),1:"")
 Set Titel=$E(Titel,1,80)
 Quit Titel
 ;
 ;Nakijken of de klacht voldoet aan limiet
CHECK(KlachtId,LimT,LimV) 
 Quit:'$L(LimT) 1
 If LimT="K" Quit $D(^KlachtI("K",LimV,KlachtId))
 If LimT="L" Quit $D(^KlachtI("L",LimV,KlachtId))
 Quit 0 
 ;
KOPPEL(KlachtId) 
 New I,R,Koppel,PopPos,Count
 For I=1:1 Set R=$G(LD("B",I)) Quit:R=""  If $P(R,"`",6)="Y" Set PopPos=$P($P(R,"`",4),";",1,2) Quit
 Set Count=0
 Set Count=Count+1,Koppel(Count)="B`Registratie"
 Set Count=Count+1,Koppel(Count)="R`Behandeling"
 Set $P(PopPos,";")=$P(PopPos,";")-Count+17,$P(PopPos,";",2)=$P(PopPos,";",2)+2
 New FMTI Set FMTI=FMTi
 Set Koppel=$$WILD^vhPOPUP(PopPos,"O1-","",.Koppel)
 Quit Koppel
 ;
CHKNUM(KlachtId,LimT,LimV) 
 New Ok
 Set Ok=0
 Do:$L(KlachtId)
 .Quit:'$D(^KlachtD(KlachtId))
 .If $L(LimT),$L(LimV),'$D(^KlachtI(LimT,LimV,KlachtId)) Quit
 .Set Ok=1
 Quit Ok
 ;
KLACHTID(Value,Select)
 New I,J,R,Type,KlachtId,KlachtIds
 For I=1:1 Quit:'$D(Value(I))  Do
 . Set R=Value(I),Type=$P(R,D),Value=$P(R,D,2),(KlachtIds,KlachtId)=""
 . For  Set KlachtId=$O(^KlachtI(Type,Value,KlachtId)) Quit:KlachtId=""  Set KlachtIds=KlachtIds_"#"_KlachtId
 . Set $E(KlachtIds)="",$P(Value(I),D,3)=KlachtIds
 Set Value=""
 For I=1:1 Quit:'$D(Value(I))  Do
 . Set KlachtIds=$P(Value(I),D,3)
 . For  Set KlachtId=$P(KlachtIds,"#") Quit:KlachtId=""  Do
 . . Set KlachtIds=$P(KlachtIds,"#",2,99999)
 . . For J=1:1 Quit:'$D(Value(J))  Quit:"#"_$P(Value(J),D,3)_"#"'[("#"_KlachtId_"#")
 . . If '$D(Value(J)),"#"_Value_"#"'[("#"_KlachtId_"#") Set Value=Value_"#"_KlachtId
 Set $E(Value)=""
 Quit
 ;