KLChanged ;Gewijzigde klanten
 ;
Test
 New %J,FromDate,ToDate,Rubrieken,Dev
 Set %J=$J ;$$%J^vhRtn1()
 Set FromDate=20060701,ToDate=$$EXTDATE^vhLib.DataTypes(,"DSN"),Rubrieken="120;310"
 Do Fetch(%J,FromDate,ToDate,Rubrieken)
 Do:$D(^HULP(%J))
 . Set Dev=$$OPEN^vhDEV(,"KLLijstPV.TXT","W","A")
 . Quit:0[Dev
 . Use Dev
 . Write $C(9),"Klant",$C(9),"Datum wijz",$C(9),"Rubriek",$C(9),"Oud",$C(9),"Nieuw",$C(9),"Gebruiker",$C(10)
 . Set KLKey=""
 . For  Set KLKey=$O(^HULP(%J,"S",KLKey)) Quit:KLKey=""  Do
 . . Set R=^HULP(%J,"S",KLKey)
 . . If $P(R,D,4)=120 Set $P(R,D,4)="Regio",$P(R,D,7,8)=$P(R,D,7),$P(R,D,5,6)=$P(R,D,5)
 . . Else  Set $P(R,D,4)="NON akt",$P(R,D,7,8)=$P(R,D,8),$P(R,D,5,6)=$P(R,D,6)
 . . Use Dev
 . . Write $TR(R,D,$C(9)),$C(10)
 . Close Dev
 . Kill ^HULP(%J)
 Quit
 ;
 ; Ophalen van de gegevens uit de log
Fetch(%J,FromDate,ToDate,Rubrieken)
 New R,KLKey,KLNaam,KLNr,Rubriek,OldValue,NewValue,OldValueTxt,NewValueTxt,Date,DateMod,User
 Kill ^HULP(%J)
 Set Rubrieken=";"_Rubrieken_";"
 Set KLNr=""
 For  Set KLNr=$O(^DLOG("K","KL",KLNr)) Quit:KLNr=""  Do
 . Set KLKey=$G(^KK1(KLNr))
 . Quit:KLKey=""
 . Set KLNaam=$P(^KKL(KLKey,0),D,2)
 . Set Date=$O(^DLOG("K","KL",KLNr,FromDate),-1)
 . For  Set Date=$O(^DLOG("K","KL",KLNr,Date)) Quit:Date=""  Quit:(Date\1)>ToDate  Do
 . . Set R=^DLOG("K","KL",KLNr,Date),Rubriek=$P(R,D,2)
 . . Quit:Rubrieken'[(";"_Rubriek_";")
 . . Set OldValue=$P(R,D,3),NewValue=$P(R,D,4),DateMod=$P(R,D,5),User=$P(R,D,7),OldValueTxt=$P(R,D,9),NewValueTxt=$P(R,D,10)
 . . Set R=KLNr_D_KLNaam_D_DateMod_D_Rubriek_D_OldValue_D_OldValueTxt_D_NewValue_D_NewValueTxt_D_User
 . . Set ^HULP(%J,"S",KLKey_Date)=R
 Quit
 ;