KPBI ;KLANT-PRODUKT BESTELIMPULS ;KPBI; Do naar PROC [ 06/13/2002  8:54 AM ]
 G BEGIN
 ;
T1 ;KLANT;4;2;;4;15;;$P(K," ",2)_" "_$P(^KKL(K,0),D,2);6;;;;28;;;
T2 ;IDENTNUMMER;5;2;;5;15;;;11;;;;;;;2
T3 ;KORTTEKST;6;2;;6;15;;K_$P("*",D,$P(^KPR(PR,1),D,20));30;;$L(K);;;;;1
T4 ;BESTELIMUPLS;4;52;;4;65;;;6;;;;;;;3
T5 ;MIN. AFNAME;5;52;;5;65;;;6;;;;;;;4
T6 ;RAAMORDER;6;52;;6;65;;$S(K:"JA",1:"");6;;;;;;;5
 ;
T10 ;0;C;L;1;;\2;C;L;25;;\7;C;L;1;;| \4;N;R;13;;| \5;N;R;13;;| \6;C;R;9;;;;$S(X:"Ja",1:"")
T11 ; Korttekst                 | Bestelimpuls |  Min. afname | Raamorder
T12 ;VERWIJDEREN PRODUKT : 
T13 ;V = verwijderen   , = hernemen
T14 ;  [] = ok 
T15 ; Dit produkt is reeds opgenomen   W = wijzigen 
T16 ; Dit is een STOCK-produkt 
T17 ;*** I'm thinking ***
T18 ;
T19 ;KLANT PROD IMPULS;OVERZICHT
 ;
O1 S K=$P($T(T15),U,2) G OY
O2 S K=$P($T(T16),U,2) G OY
OY S FP=2403 W @F,@F1,@FMTI,K,$P($T(T14),U,2),@FMTi,@F0 K IK D IK^PROC1
OZ Q
 ;
 ;Schermaanduiding
SA S FP=255 W @F,@FMTB,$J($P($T(T18),U,$F("I",U4)),25),@FMTb
 Q
 ;
SA1 S FP=255 W @F,$J("",5),@FMTK,$P($T(T17),U,2),@FMTk
 Q
 ;
 ; Help
HLP D SA
 S HLP(1)=$P($T(T19),U,2),HLP(2)=$P($T(T19),U,3),HLP(3)=10,HLP(6)="" D HLP^HELP
 Q
 ;
 ; Initialisatie
IN S K=$P($T(+1),U,2)_QN_" ",FP=203+$L(K) W @F61,@F11,@F1,@F,@F5 S FP=202 W @F,@F4,K,@F5
 F I=1:1 S U2=$P($T(@("T"_I)),U,2,999) Q:U2=""  D RUB
 S PRKL(1)="^HULP($J",PRKL(2)=$P($T(T10),U,2,999),PRKL(3)=8,PRKL(4)=12,PRKL(8)=$P($T(T11),U,2)
 S KCX=""
 Q
 ;
 ; Lock
LCK S LCK=1 L ^KPBI("D",KC,PR):2 E  X ^cTXT(0,"N",163) K IK D IK^PROC1 S LCK=0
 Q
 ;
 ; Opzetten rubrieken
RUB S FP=$P(U2,U,5)*100+$P(U2,U,6) W @F,@F9,":"
 S FP=$P(U2,U,2)*100+$P(U2,U,3) W @F,@F6,$P(U2,U,1),@F9
 Q
 ;
 ; Display gegevens
DISPL S K=$P(B,D,$P(U2,U,16)+1) I $L($P(U2,U,8)) X "S K="_$P(U2,U,8)
 S FP=$P(U2,U,5)*100+$P(U2,U,6)+3 W @F,$J("",$P(U2,U,9)),$J("",$P(U2,U,13)),@F,K
 Q
 ;
 ; Ophalen produkten klant
REN K ^HULP($J),DL S DL(1)="PRKL",(PR,VNR)=0 D SA1
 F  S PR=$N(^KPBI("D",KC,PR)) Q:PR=-1  D
 .S REF=^(PR) S:$L(REF,D)=1 REF=REF_D S:$L(REF,D)=2 REF=REF_D
 .I '$D(^KPR(PR,0)) S K=REF D KIL Q
 .S PC=$P(^(0),D,1),STNST=$P(^(1),D,20),PID=$P(^(2),D,25)
 .S K=" \ \ " I $E($N(^("I")))="I" S K=^($N(^("I")))
 .S HG=$P(K,D,1)_" ",GR=$P(K,D,2)_" ",SG=$P(K,D,3)_" "
 .S ^HULP($J,HG,GR,SG,$$COMPR^PRODUKT(PR))=PR_D_PC_D_PID_D_REF_D_$P("*",D,STNST)
 S HG="" F  S HG=$O(^HULP($J,HG)) Q:HG=""  D
 .S GR="" F  S GR=$O(^HULP($J,HG,GR)) Q:GR=""  D
 ..S SG="" F  S SG=$O(^HULP($J,HG,GR,SG)) Q:SG=""  D
 ...S PC="" F  S PC=$O(^HULP($J,HG,GR,SG,PC)) Q:PC=""  D
 ....S K=^(PC) k ^(PC) S VNR=VNR+1,^HULP($J,VNR)=K
 I $D(U4),U4="V" S:PRKL(6)>1&'$D(^HULP($J,PRKL(6))) PRKL(6)=PRKL(6)-1 G REN1
 S PRKL(6)=1 F I=1:1 Q:'$D(^(I))  S R=+^(I) I R=BPR S PRKL(6)=I Q
REN1 I $D(PRKL(4)) S PRKL(7)=PRKL(6)-PRKL(4)+1 S:PRKL(7)<1 PRKL(7)=1
 D WL^PROC
 Q
 ;
 ; Show produkt
SPR G SPR3:'$D(^HULP($J)) S B=^($J,PRKL(6)) G SPR3:PR=+B
SPR1 S (BPR,PR)=+B F I=2,3 S U2=$P($T(@("T"_I)),U,2,999) Q:U2=""  D DISPL
SPR2 F I=4:1 S U2=$P($T(@("T"_I)),U,2,999) Q:U2=""  D DISPL
SPR3 Q
 ;
 ; Clear produkt
CLR F I=2:1 S U2=$P($T(@("T"_I)),U,2,999) Q:U2=""  S FP=$P(U2,U,5)*100+$P(U2,U,6)+3 W @F,$J("",$P(U2,U,9)),$J("",$P(U2,U,13))
 Q
 ;
 ; Kill indien '$D(^KPR(PR)) of verwijder
KIL K ^KPBI("D",KC,PR)
 Q
 ;
 ; Selekteer bestaande
SEL S WNR=$N(^HULP($J,0)),WNR=0
SEL1 S WNR=$N(^(WNR)) I WNR'=-1 G SEL1:K'=+^(WNR)
 I WNR<PRKL(7)!((WNR-PRKL(7)+1)>PRKL(4)) S (PRKL(6),PRKL(7))=WNR D WL^PROC G SEL2
 D DL^PROC S PRKL(6)=WNR D EL^PROC
SEL2 Q
 ;
 ; Nieuw
NEW 
 N %SC,Impuls,MinAfn,RaamOrd
 D CLR S BPR=""
NEW1 I VNR'=PRKL(6) S DL(2)="EN" D ML^PROC K DL(2)
NEW2 S R="K\2100\P" D ^SELPR I K="-" D CLR G NEW4
 I $D(^KPBI("D",KC,K)) D SEL,O1 G NEW1:R'="W",WZN
 S PR=K,B=PR_D_$P(^KPR(PR,0),D,1)_D_$P(^(2),D,25)_D_D_D_D_$P("*",D,$P(^(1),D,20)) D SPR1
 ;I $P(^KPR(PR,1),D,20) D O2 G NEW2
 D NIEUW^vhScherm("KPBI","","",$J("",80),"","",3)
 I '%SC D CLR G NEW2
 S $P(B,D,4,6)=$P(^KPBI("D",KC,PR),D,1,3)
 D SPR2,C23
 I VNR'>PRKL(4),$D(^HULP($J,PRKL(6))) D DL^PROC
 S VNR=VNR+1,^HULP($J,VNR)=B
 S PRKL(6)=VNR I VNR'>PRKL(4) D EL^PROC
NEW4 I K'="-",VNR>PRKL(4) S PRKL(6)=VNR-1,DL(2)="DO" D ML^PROC K DL(2)
 Q
 ;
 ;
 ; Verwijderen
VRW G VRW3:'$D(^HULP($J)) I $D(B),B=^($J,PRKL(6)) G VRW1
 D SPR
VRW1 D LCK G VRW2:'LCK
 S FP=2303 W @F,$P($T(T12),U,2),$P(B,D,2),$P(B,D,6)
 W !?2,$P($T(T13),U,2) K IK D IK^PROC1
 I R="V" D CLR S PR=+B,K=$P(B,D,4) K B D KIL S R="V"
VRW2 D C23
VRW3 Q
 ;
 ; Wijzigen
WZN 
 N %SC,Impuls,MinAfn,RaamOrd
 G WZN2:'$D(^HULP($J)) S B=^($J,PRKL(6)),PR=+B I PR'=BPR D SPR1
 D LCK I 'LCK D C23 G WZN2
 D EDIT^vhScherm("KPBI","","",$J("",80),"","",3)
 I %SC D
 .S $P(B,D,4,6)=$P(^KPBI("D",KC,PR),D,1,3),^HULP($J,PRKL(6))=B
 .D SPR2,EL^PROC
 E  D C23
WZN2 Q
 ;
 ; Clear vanaf lijn 23
C23 S FP=2301 W @F,@F1
 Q
 ;
BEGIN D IN
 ;
KLANT S U2=$P($T(T1),U,2,999),KC=$$SELECT^KLANT6() G END:'KC
 S (K,B)=^KK1(KC),FP=2001 W @F,@F1
 I KC=KCX G 11:DL(1)="PRKL" S DL(1)="PRKL" D WL^PROC G 11
 D DISPL,CLR S BPR="",U4="?"
 ;
1 S KCX=KC D REN
10 S U4="?" D SA
11 L  S DL(3)=3 D SL^PROC
13 L
 I R="-" D WIJZ^LOG("BI",KC) G END
 I R="K" D WIJZ^LOG("BI",KC) G KLANT
 S U4=R I U4="" S U4="ENTER"
 I U4="ENTER" D SPR G 11
 I U4="N" D NEW G 13:K=",",11
 I U4="R" G 1
 I U4="V" D VRW G 1:R="V",13
 I U4="W" D WZN G 11
 I U4'="?",U4'="HELP" G 11
 D HLP G 13:"\-\K\"[(D_R_D) K DL S DL(1)="PRKL",U4=R D WL^PROC S R=U4 G 13:R="I",11
 ;
BuildIndex
 New PRNr,KLNr
 ; Via .Local
 Kill ^KPBI("IP")
 Set (PRNr,KLNr)=""  
 For  Set KLNr=$O(^KPBI("D",KLNr)) Quit:KLNr=""  Do
 . For  Set PRNr=$O(^KPBI("D",KLNr,PRNr)) Quit:PRNr=""  Do
 . . Set ^KPBI("IP",PRNr,KLNr)=""
 Quit
 
END 
 K ^HULP($J) 
 Do BuildIndex
 Q
 
 ;
MINVERP(PRNr) 
 New R
 Set R="J",R=$O(^KPR(PRNr,R)) Set:$E(R)="J" R=^(R)
 Set R=$S($P(R,D,14):$P(R,D,14),$P(R,D,15):$P(R,D,15),1:$P(R,D,16))
 Quit R
 ;