KSCHADV ;VERWIJDEREN SCHADUWGEGEVENS ;KSCHADV; [ 08/06/2002   8:43 AM ]
 ;
 Set K=$P($T(+1),U,2)_QN_" ",FP=203+$L(K)
 Write @F61,@F11,@F1,@F,@F5
 Set FP=202
 Write @F,@F4,K,@F5
 Set FP=301
 Write @F,$C(13),!?2,"AANDACHT !!!",!!?2,"BESTAND UITZONDERINGEN PRIJSKLASSE:"
 Write !?2,"ALLE schaduw uitzonderingen prijsklasse verdwijnen."
 Write !!?2,"MUNTPARITEITTBESTAND:"
 Write !?2,"ALLE schaduw muntpariteiten verdwijnen."
 Write !!?2,"KLANTENBESTAND:",!?2,"Voor die klanten welke de schaduwprijsklasse is ingevuld:"
 Write !?2,"De schaduwprijsklasse verdwijnt."
 Write !!?2,"PRODUKTENBESTAND:",!?2,"Voor die produkten welke schadwgegevens bevatten:"
 Write !?2,"Alle schaduwgegevens verdwijnen."
 Set R="K\23\3\V[] = VERWIJDEREN SCHADUWGEGEVENS   -[] = hernemen\\1\\""-V""[K&$L(K)"
 Do R0 Do:K'="-"
 . Set R="K\24\3\V[] = DEFINITIEF VERWIJDEREN SCHADUWGEGEVENS   -[] = hernemen\\1\\""-V""[K&$L(K)"
 . Do R0
 . Quit:K="-"
 . Set FP=301
 . Write @F,@F1
 . Set FP=1903 W @F,"VERWIJDEREN SCHADUW UITZONDERINGEN PRIJSKLASSE KLANTEN"
 . Kill ^KLPUTZ("S"),^KLPUTZ("IS"),^KLPUTZ("AS")
 . Hang 1
 . Set FP=301
 . Write @F,@F1
 . Set FP=1903
 . Write @F,"VERWIJDEREN SCHADUW MUNTPARITEIT"
 . Set X=$G(^KBA("S",11))
 . Kill ^KBA("S",11)
 . Set:$L(X) ^KBA("S",11)=X
 . Hang 1
 . Set FP=1903
 . Write @F,@F1,"VERWIJDEREN SCHADUWPRIJSKLASSE KLANTEN"
 . Set FP=2103
 . Write @F,@F1,"KLANT :"
 . Set KlKey=0
 . For  Set KlKey=$O(^KKL(KlKey)) Quit:KlKey=""  Do ONECUST($P(KlKey," ",2))
 . Set FP=1903
 . Write @F,@F1,"VERWIJDEREN SCHADUWGEGEVENS PRODUKTEN"
 . Set FP=2103
 . Write @F,"PRODUKT     :"
 . Set PRNr=0
 . For  Set PRNr=$O(^KPR(PRNr)) Quit:PRNr=""  D ONEPROD(PRNr)
 Quit
 ;
GRORDE 
 New R,KKey
 Set KKey=""
 For  Set KKey=$O(^KLAS("K",KKey)) Quit:KKey=""  Do
 .Set R=^KLAS("K",KKey)
 .Quit:$P(R,D,15)=""
 .Set $P(R,D,15)="",^KLAS("K",KKey)=R
 Quit
 ;
ONECUST(KLNr)
 New R,%TC,KlKey,KlNaam,SchPrijsKl,SchPrijsKlOrgalux
 Set KlKey=^KK1(KLNr),R=^KKL(KlKey,2),SchPrijsKlOrgalux=$P(R,D,24),SchPrijsKl=$P(R,D,25)
 If SchPrijsKl="",SchPrijsKlOrgalux=""
 Else  Do
 . Set KlNaam=$P(^KKL(KlKey,0),D,2),FP=2111
 . Write @F,@F2,KlNaam
 . For  Do ADD^vhLock("^KKL(KlKey)") Quit:%TC  Do LDISP^vhLock("^KKL(KlKey)","Klant")
 . Do:SchPrijsKlOrgalux'="" MODFIELD^KLANT(KLNr,324,"")
 . Do:SchPrijsKl'="" MODFIELD^KLANT(KLNr,325,"")
 . Do REMOVE^vhLock("^KKL(KlKey)")
 Quit
 ;
ONEPROD(PRNr)
 New R,%TC,KortTxt,SchPPL,SchKortP,SchCifP,SchDBP,SchVorkP,SchMunt,SchKatPr,SchKatPrHand,SchGrOrde
 Set R=^KPR(PRNr,1),SchMunt=$P(R,D,3),SchGrOrde=$P(R,D,14),SchKatPrHand=$P(R,D,15),SchKatPr=$P(R,D,16)
 Set R=^KPR(PRNr,2),SchPPL=$P(R,D,3),SchKortP=$P(R,D,4),SchVorkP=$P(R,D,5),SchDBP=$P(R,D,6),SchCifP=$P(R,D,7)
 If SchMunt="",SchGrOrde="",SchKatPrHand="",SchKatPr="",SchPPL="",SchKortP="",SchVorkP="",SchDBP="",SchCifP=""
 Else  Do
 . Set KortTxt=$P(^KPR(PRNr,0),D),FP=2117
 . Write @F,@F2,KortTxt
 . For  Do ADD^vhLock("^KPR(PRNr)") Quit:%TC  Do LDISP^vhLock("^KPR(PRNr)","Product")
 . Do:SchMunt'="" MODFIELD^PRODUKT(PRNr,203,"")
 . Do:SchGrOrde'="" MODFIELD^PRODUKT(PRNr,214,"")
 . Do:SchKatPrHand'="" MODFIELD^PRODUKT(PRNr,215,"")
 . Do:SchKatPr'="" MODFIELD^PRODUKT(PRNr,216,"")
 . Do:SchPPL'="" MODFIELD^PRODUKT(PRNr,303,"")
 . Do:SchKortP'="" MODFIELD^PRODUKT(PRNr,304,"")
 . Do:SchVorkP'="" MODFIELD^PRODUKT(PRNr,305,"")
 . Do:SchDBP'="" MODFIELD^PRODUKT(PRNr,306,"")
 . Do:SchCifP'="" MODFIELD^PRODUKT(PRNr,307,"")
 . Do REMOVE^vhLock("^KPR(PRNr)")
 Quit
 ;
R0 S R7=1 S:$P(R,D,8)'="" R7=R7_"&("_$P(R,D,8)_")" S:$P(R,D,7)'="" R7=R7_"&("_$P($T(@$P(R,D,7))," ",2,99)_")"
R0A S R2=$P(R,D,2),R3=$P(R,D,3),R4=$P(R,D,4),R5=$P(R,D,5),R6=$P(R,D,6)
R0B S R0=$L(R4)+R3+3 S FP=R2*100+R3+F60 W @F W:R3<4 @F1 W @F2,R4," : " I R5'="" W:R5["""" !,?2,@R5 D:R5'["""" @R5
R0C S FP=R2*100+R0+F60 W @F,@F2,$E("........................................",1,R6),@F,@F0
R0D R K W @F2 I $L(K)'>R6,K'[D&(K'?.E1C.E),@R7 S @$P(R,D,1)=K
R0E E  G R0C
R0F S FP=$P(R,D,9)*100+($P(R,D,10)*1) I FP W @F,$J("",R6),@F,K
R0Z K R,R0,R2,R3,R4,R5,R6,R7 Q  ;V5 02.01.86
 ;