KSPROD ;KS Produkt [ 01/08/2001  10:20 AM ]
KSPAK(PRNr,NoSa) ; Verpakking staffeling voor KS produkten
 New J,Rec,KSDB,KSKV,KSGV
 If "N"[$G(NoSa) Set NoSa=""
 Set J=$O(^KPR(PRNr,"J")) Quit:$E(J)'="J" ""
 Set Rec=^KPR(PRNr,J)
 Set KSDB=$P(Rec,D,10)
 Set KSKV=$P(Rec,D,11)
 Set KSGV=$P(Rec,D,12)
 If NoSa="S" Set Rec=^KPR(PRNr,2) Set:$P(Rec,D,10) KSDB=$P(Rec,D,10)
 Quit:'KSDB!'KSKV!'KSGV ""
 Quit KSGV_D_KSKV_D_1
 
 ; KS-produkt
ISKS(PRNr,NoSa) 
 Quit $$KSPAK(PRNr,$G(NoSa))'=""
 
KSPRIJS(PRNr,KLNr,NoSa,RtnLoc,Munt,PrijsKL,IsHandel,IsBruto) 
 ;PRNr : Verplicht
 ;KLNr : Niet verplicht, default=""
 ;NoSa : Niet verplicht, default="N"
 ;RtnLoc : De versch. prijzen worden per verpakking doorgeg. via de .RtnLoc. Voor een KS produkt zijn er dan drie records met PROD^KSPRIJS geg.
 Set NoSa=$G(NoSa,"N")
 If $G(KLNr) Do
 .New KLId
 .Set KLId=^KK1(KLNr)
 .If $G(PrijsKL)="" Do
 ..Set PrijsKL=$P(^KKL(KLId,2),D,3)
 ..If NoSa="S",$L($P(^KKL(KLId,2),D,25)) Set PrijsKL=$P(^KKL(KLId,2),D,25)
 .Set IsBruto=$G(IsBruto,$P(^KKL(KLId,2),D,5))
 .Set IsHandel=$G(IsHandel,$$IsHandel^KLANT5(KLNr))
 .Set:$G(Munt)="" Munt=$P(^KKL(KLId,0),D,11)
 Else  Do 
 .Set:$G(PrijsKL)="" PrijsKL="P"
 .Set IsBruto=$G(IsBruto)
 .Set IsHandel=$G(IsHandel)
 .Set:$G(Munt)="" Munt=$$FADEF^vhRtn1()
 Set KSPak=$$KSPAK(PRNr,NoSa)
 Set:'$L(KSPak)!(PrijsKL'="P") KSPak=0
 Kill RtnLoc
 If 'KSPak Do
 .Set RtnLoc(0)=$$PROD^KPRIJS(PRNr,PrijsKL,"",Munt,IsBruto,IsHandel,NoSa)
 Else  For I=1:1:3 Do
 .Set RtnLoc($P(KSPak,D,I))=$$PROD^KPRIJS(PRNr,$E("LKE",I),"",Munt,IsBruto,IsHandel,NoSa)
 Quit