MBNOHLUX ;NEW PROGRAM [ 04/03/2003  1:19 PM ]
 
 ;INIT 
 Set KlantKey=0               
 Set Dev=0
 Set NooitH=1
 
 ;CALCDATE voor 6 maand terug 
 Set HB=$$EXTDATE^vhLib.DataTypes($$CALCDATE^vhLib.DataTypes($H,"M",-6),"DKP")
 
 Set Dev=$$OPEN^vhDEV(,"NoHaluxForSixMonth.txt","W")
 
 Write !,"Start..."
 Use:0'[Dev Dev
 
 ;WRITE HEADER
 Write "KLANTNAAM",$C(9),"KLANTNUMMER",$C(9),"STRAAT",$C(9),"WOONPLAATS",$C(9),"POSTNUMMER",$C(9),"TELEFOON1",$C(9),"TELEFOON2",$C(9),"GSM",$C(9),"KLANT VAN",$C(9),"FASE",$C(9),"BEZCODE",$C(9),"PRIJSKLASSE",$C(9),"KODE COMM.AKT.",$C(9),"OPMERKING1",$C(9),"OPMERKING2",$C(9),"OPMERKING3",$C(9),"OMZET",$C(9),"REGIO",$C(9),"KONTAKTPERS",$C(9),"NOOIT HALUX",!
 
 ;FETCH DATA
 For  Set KlantKey=$O(^KKL(KlantKey)) Quit:KlantKey=""  Do
 . Set rec=^KKL(KlantKey,0) 
 . Quit:'$D(^KK1($P(rec,D)))
 . Set Regio=$P(rec,D,20)
 . ;If '((Regio<30)&(Regio>-1)) Quit     ;moet in regio 20 tem 29 zijn
 . Set KlantNm=$P(rec,D,2) 
 . Set KlantNr=$P(rec,D,1)
 . Quit:$$YesHalux(KlantNr) 
 . Set Kontakt=$G(^PERS("K",KlantNr,1),"")
 . Set:Kontakt'="" Kontakt=$P(Kontakt,D,4)_" "_$P(Kontakt,D,3)_" "_$P(Kontakt,D,2) 
 . Set tRec=rec
 . Set StrtNrBs=$P(rec,D,5)
 . ;Indien postbus leveranciersadres gebruiken
 . If ($$UPTRIMAN^vhRtn1(StrtNrBs)["POSTBUS")  Do
 .. Set tKey=$O(^KKL(KlantKey,"L"))
 .. Set:$E(tKey)="L" tRec=^KKL(KlantKey,tKey)
 . Set StrtNrBs=$P(tRec,D,5)
 . Set PostNr=$P(tRec,D,6) 
 . Set WoonPlts=$P(tRec,D,7)
 . Set Tel1=$P(tRec,D,13)
 . Set Tel2=$P(rec,D,14)
 . Set rec=^KKL(KlantKey,1) 
 . Set Fase=$P(rec,D,4)
 . Set BezCode=$P(rec,D,8)
 . Set KlantVan=$P(rec,D,10)
 . Set rec=^KKL(KlantKey,2)
 . Set PrsKls=$$KODEX^KLANT(KlantNr)
 . Set KodeComm=$S($P(rec,D,10):"NON",1:"AKT")
 . Set GSMNr=$P(rec,D,20)         ;kijken naar ^PERS ?
 . Set rec=^KKL(KlantKey,4)
 . Set Opmerk1=$P(rec,D,1)
 . Set Opmerk2=$P(rec,D,2)
 . Set Opmerk3=$P(rec,D,3)
 . Set Omzet=$P($G(^KKAAP(KlantNr,0,0,0,0),0),D,1)
 . ;WRITE DATA
 . Write KlantNm,$C(9),KlantNr,$C(9),StrtNrBs,$C(9),WoonPlts,$C(9),PostNr,$C(9),Tel1,$C(9),Tel2,$C(9),GSMNr,$C(9),KlantVan,$C(9),Fase,$C(9),BezCode,$C(9),PrsKls,$C(9),KodeComm,$C(9),Opmerk1,$C(9),Opmerk2,$C(9),Opmerk3,$C(9),$C(9),$J(Omzet,0,0),$C(9),Regio,$C(9),Kontakt,$C(9),NooitH,! 
 close:0'[Dev Dev
 Write !,"Einde."
 Quit
 
 ;KIJK WELKE KLANTEN WEL HALUX KOCHTEN 
YesHalux(KLNr)  
 Set retval=0
 Set NooitH=1
 Set PRNr="" 
 For  Set PRNr=$O(^KSTKL(KLNr,PRNr)) Quit:PRNr=""  Do
 . Quit:'$$ISHALUX^PRODUKT2(PRNr)
 . Set LaatsteA=$P(^KSTKL(KLNr,PRNr,0),D,1)
 . Set:LaatsteA NooitH=0
 . Quit:'LaatsteA
 . Set:$$COMPDATE^vhLib.DataTypes(LaatsteA,">","DKP",HB) retval=1 
 . Set:retval PRNr=""
 Quit retval