ORGAWWWSHOWROOM ;Opbouw van het javascript met de orgalux showrooms [ 12/15/2003  8:35 AM ]
 New
 Set Q="K"
 Do ^cA604,INIT^vhTERMINA
 Set L="#"
 Set KLKey=0 
 For  Set KLKey=$O(^KKL(KLKey)) Quit:KLKey=""  Do 
 . Quit:$P(KLKey," ",2)=1000
 . Set rec=$G(^KKL(KLKey,8))
 . Quit:$P(rec,D,12)'=1 ;Orgalux vermelding op het web moet ingevuld z.
 . set OpenDeur=$P(rec,D,9)
 . set BeginDtm=$P(rec,D,10)
 . set EindDtm=$P(rec,D,11)
 . if BeginDtm,EindDtm  Do 
 .. if ($h'>EindDtm)&($h'<$$CALCDATE^vhLib.DataTypes(BeginDtm,"M","-1"))  Do 
 ... set BeginDtm=$$EXTDATE^vhLib.DataTypes(BeginDtm,"DK4")
 ... set EindDtm=$$EXTDATE^vhLib.DataTypes(EindDtm,"DK4")
 .. Else  Do
 ... set BeginDtm=""
 ... set EindDtm=""         
 . set TelNr=$P(rec,D,8)
 . set KLNm=$P(rec,D,1)
 . set rec=^KKL(KLKey,0)
 . Set:KLNm="" KLNm=$P(rec,D,2) 
 . Set:'TelNr TelNr=$S($P(^KKL(KLKey,8),D,8)'="":$P(^KKL(KLKey,8),D,8),1:$P(rec,D,13))
 . Set URL=$P(^KKL(KLKey,7),D,2)
 . Set Straat=$P(rec,D,5)
 . If ($$UPTRIMAN^vhRtn1(Straat)["POSTBUS")  Do
 .. Set tKey=$O(^KKL(KLKey,"L"))
 .. Set:$E(tKey)="L" rec=^KKL(KLKey,tKey)
 . Set Straat=$$INITCAP^vhRtn1($P(rec,D,5))
 . Set PostNr=$P(rec,D,6)
 . Set Gemeente=$$INITCAP^vhRtn1($P(rec,D,7))
 . Set Land=$P(rec,D,8)
 . Set Land=$S(Land=1019:1,Land=1147:2,1:3)
 . Set Data(Land_PostNr_KLNm)=KLNm_L_PostNr_L_Gemeente_L_Straat_L_TelNr_L_URL_L_Land_L_OpenDeur_L_BeginDtm_L_EindDtm
 
 Set Dir="\\NOTES01\c$\"
 Set FileNm="adresData.js"
 Set Dev=0
 Set Dev=$$OPEN^vhDEV(Dir,FileNm,"W","M")
 Use:0'[Dev Dev
 set index=""
 set Cnt=0
 
 Write "var data=new Array();"_$c(13,10,13,10) 
 
 For  Set index=$O(Data(index)) Quit:index=""  Do 
 . Write "data["_Cnt_"]="""_Data(index)_""";",! 
 . Set Cnt=Cnt+1
 
 Close:0'[Dev Dev
 
 
 ; versturen naar TESTWWW
 set err=$$SendFile^FTP(Dir_FileNm,"testWWW/Orgalux/",FileNm,"192.168.100.2","Tineke","T!neKe")
 If $L(err) Do  Quit
 . Set Status=$$SendMiniMail^vhLib("CACHE01@VANHOECKE.BE",$LB("PV@VANHOECKE.BE"),$ZN_" : ftp mistlukt naar test WWW, ftp naar WWW niet uitgevoerd","Fout : "_err)
 
 ; versturen naar WWW
 Set err=$$SendFile^FTP(Dir_FileNm,"WWW/Orgalux/",FileNm,"192.168.100.2","Tineke","T!neKe")
 Set:$L(err) Status=$$SendMiniMail^vhLib("CACHE01@VANHOECKE.BE",$LB("PV@VANHOECKE.BE"),$ZN_" : ftp mistlukt naar WWW","Fout : "_err)
 
 Quit