#Include BL.Derde.Kennis
 
RPLPR5 ;RAADPLEGEN PRODUCTEN (KennisAnker) ;RPLPR;
 ;
 ; Tonen van alle ankers
ALL(PRNr)
 New PopUp
 Set PopUp("Buttons")="OK;NIEUW;WIJZIG"
 Quit $$Read(PRNr,,,,1,.PopUp)
 ;
 ; Tonen van alle ongelezen ankers
ALLUnRead(PRNr)
 New PopUp
 Set PopUp("Buttons")="GELEZEN;ANNULEER;NIEUW;WIJZIG"
 Quit $$Read(PRNr,,,,,.PopUp)
 ;
 ; Tonen van alle ongelezen ankers voor klant Van Hoecke
VHUnRead(PRNr)
 New PopUp
 Set PopUp("Buttons")="GELEZEN;ANNULEER;NIEUW;WIJZIG"
 Quit $$Read(PRNr,,,4682,,.PopUp)
 ;
 ; Tonen van de ongelezen ankers volgens selectie
Read(PRNr,GebruikersGroep,ActieDomein,KLNr,BypassAutoShow,PopUp)
 New Input
 Set GebruikersGroep=$G(GebruikersGroep),ActieDomein=$G(ActieDomein)
 If GebruikersGroep'="",'$$IsGroep^vhUSER(,GebruikersGroep)
 Else  Do  ; Indien geen GebruikersGroep gedefinieerd of de gebruiker behoord tot de GebruikersGroep
 . Set PopUp("PRNr")=PRNr,PopUp("List")=1,PopUp("Criteria",3)=$P(^KPR(PRNr,0),D)
 . Set PopUp("Criteria",2)=$P(^KPR(PRNr,2),D,25)_" ("_PRNr_$S($P($G(^KPR(PRNr,"G")),D,13):"/"_$P(^KPR(PRNr,"G"),D,13),1:"")_")"
 . Set Input=##class(CHUI.Derde.Kennis.Kennis).PopUp($G(KLNr),ActieDomein,$LB(PRNr),$G(CUserId,$G(QU(1))),,,,,+$G(BypassAutoShow),.PopUp)
 Quit $G(Input)
 ;
 ; Ophalen aantal ankers
GetAantal(PRNr)
 Quit ##class(BL.Derde.Kennis.Kennis).GetAnkerCountViaProduct(PRNr)
 ;
 ; Initialisatie ankers
Init
 New Aantal,lbIDs,varErrStr
 Do:$G(KennisAnker("PRNr"))'=PRNr
 . Kill KennisAnker
 . Set KennisAnker("PRNr")=PRNr
 . Set KennisAnker("IsOV")=$$IsGroep^vhUSER(,"ORDVW")
 . Set Aantal=$$GetAantal(PRNr)
 . Do:Aantal
 . . Set KennisAnker("Aantal")=Aantal
 . . Set lbIDs=##class(BL.Derde.Kennis.Kennis).GetIDsToPopup(,.varErrStr,"",$LB(PRNr),$G(CUserId,$G(QU(1))))
 . . Set KennisAnker("NotRead")=$LL(lbIDs)_D_lbIDs
 Quit
 ;