RPLPROF ;Raadplegen proforma [ 02/01/2001   9:03 AM ]
 d ^cA604
RPLF2 Set PROFNr=$$ASK^vhINP("Geef faktuur nummer",6,"400013")
 Quit:PROFNr="-"!(PROFNr=".")
 Set:$L(PROFNr)<6 PROFNr=400000+PROFNr
 Goto RPLF2:'$D(^KFAP("F",PROFNr))
 Do LIJST(PROFNr)
 Goto RPLF2
 
LIJST(PROFNr,BeginPos) ; Fakturen detail
 New KLNr,CC,FAD,R,Input,DL,Bruto
 For  Do  Quit:"()"'[Input
 .Do INIT
 .Do WL^PROC 
 .Do SL^PROC
 .If R="COM" Do MENU^RPLKL4
 .If R="SPEC" Do SPEC^RPLKL4
 .Set Input=R
 .If Input="(" Set R=$$NEXT(KLNr,PROFNr,-1) Set:R PROFNr=R
 .If Input=")" Set R=$$NEXT(KLNr,PROFNr,1) Set:R PROFNr=R
 .If Input="PZ"!(Input="PRINT") Do PRINT(PROFNr) Set Input=""
 .If Input="ENTER" Set Input=","
 Quit Input
 
SHOW(PROFNr,BeginPos) 
 New KLNr,CC,FAD,R,Input,DL,Bruto
 Do INIT
 Do WL^PROC
 Do SL^PROC
 If R="ENTER" Set R=","
 Quit R
 
NEXT(KLNr,PROFNr,Dir) 
 New Dat
 Set Dat=$P(^KFAP("F",PROFNr,0,0),D,6)
 Set Dat=-$$INTDATE^vhLib.DataTypes(Dat)
 Set PROFNr=$O(^KFAP1("F",KLNr,Dat,PROFNr),Dir)
 Set:PROFNr="" Dat=$O(^KFAP1("F",KLNr,Dat),Dir)
 Set:PROFNr=""&(Dat'="") PROFNr=$O(^KFAP1("F",KLNr,Dat,PROFNr),Dir)
 Quit PROFNr
 
INIT New VNR,ULNr
 Set KLNr=+^KFAP("F",PROFNr,0,0)
 Kill ^HULP($J,"K"_KLNr,"FD")
 Set CC=$P(^KFAP("F",PROFNr,0,3),D,23)
 Set Bruto=$P(^KFAP("F",PROFNr,0,3),D,27)
 Set (FAD(9),VNR)=0
 Set ULNr="U"
 For  Set ULNr=$O(^KFAP("F",PROFNr,ULNr)) Quit:ULNr=""  Do
 .Set:VNR VNR=VNR+1,^HULP($J,"K"_KLNr,"FD",VNR)=""
 .Set VNR=VNR+1,^HULP($J,"K"_KLNr,"FD",VNR)="U"_D_$E(ULNr,2,99)_D_^KFAP("F",PROFNr,ULNr,1)
 .Set:CC $P(^HULP($J,"K"_KLNr,"FD",VNR),D,9)="CC #cash&carry"
 .Set:+^KFAP("F",PROFNr,ULNr,3) VNR=VNR+1,^HULP($J,"K"_KLNr,"FD",VNR)=^KFAP("F",PROFNr,ULNr,3)
 .Set ULL=100
 .For  Set ULL=$O(^KFAP("F",PROFNr,ULNr,ULL)) Quit:ULL=""  Do
 ..Set VNR=VNR+1,^HULP($J,"K"_KLNr,"FD",VNR)=^KFAP("F",PROFNr,ULNr,ULL)
 Quit:'VNR
 Do INIT^PROC("RPLFAKTPR","FAD")
 Set FAD(2,1)=^LD("L","RPLFAKTTXT")
 Set FAD(9)=VNR
 Set R=^KFAP("F",PROFNr,0,0)
 Set FAD(8)="Proforma : "_$E(PROFNr,1,3)_"."_$E(PROFNr,4,6)_" van "_$P(R,D,6)_" bedrag goederen "_$$EXTNUM^vhLib.DataTypes($P(R,D,7),0,",",2)_" "_$S($P(R,D,5)="":$$FADEF^vhRtn1(),1:$P(R,D,5))
 Set:$P($P(R,D,17),"#",2) FAD(8)=FAD(8)_" port "_$$EXTNUM^vhLib.DataTypes($P($P(R,D,17),"#",2),0,",",2)_" "_$S($P(R,D,5)="":$$FADEF^vhRtn1(),1:$P(R,D,5))
 Set FAD(3)=$S($D(BeginPos):BeginPos,1:8)
 Set FAD(4)=""
 
 Quit
 
CB(Nr,Ref) ; Callback
 If $P(Ref,D,17)="KF6" Quit ""
 If $P($P(Ref,D,17),"#")="KF1925" Quit ""
 If Ref="" Set FL(3,2)="      |" Quit 1
 If $P(Ref,D,17)="KF5" Set FL(3,2)="Order | "_$E($P(Ref,D,5),1,3)_"."_$E($P(Ref,D,5),4,999) Quit 1
 If $P($P(Ref,D,17),"#")="KF11" Set FL(3,2)="      | "_$P(Ref,D,5) Quit 1
 If $P(Ref,D,1)="U" Set FL(3,2)=$S(CC:"Order | ",1:"Bon   | ")_$E($P(Ref,D,2),1,3)_"."_$E($P(Ref,D,2),4,6)_" van "_$P(Ref,D,4)_" "_$$LOCASE^vhRtn1($P($P(Ref,D,9),"#",2)) Quit 1
 Set FL(3,2)="Adres | "_$$INITCAP^vhRtn1($P(Ref,D,2)_" - "_$P(Ref,D,7)_" - "_$P(Ref,D,5)) Quit 1
 
PRINT(PROFNr) 
 Do EXTERN^DCPRINT("V",PROFNr,0,1,1)
 Quit