VERSLAGC ;Verslagen [ 12/23/97  3:17 PM ]
 Quit
 ;
CONVERT 
 Kill
 Do INIT^vhTERMINA
 Set VerslId="",Count=0
 For  Set VerslId=$O(^VERSLAG("D",VerslId)) Quit:VerslId=""  Do
 .Set Count=Count+1
 .Write:'(Count#100) "."
 .Set R=^VERSLAG("D",VerslId,0)
 .Set Date=$P(R,D),FTime=$P(R,D,2),TTime=$P(R,D,3),RefType=$P(R,D,5),RefNr=$P(R,D,6)
 .Set BeginKm=$P(R,D,10),EindKm=$P(R,D,11),DagKm=$P(R,D,12),DateMod=$P(R,D,13),Auteur=$P(R,D,14)
 .Set IntPers=$G(^VERSLAG("D",VerslId,"I")),ExtPers=$G(^VERSLAG("D",VerslId,"C"))
 .Set Adres=$G(^VERSLAG("D",VerslId,"A")),MailRef=$G(^VERSLAG("D",VerslId,"P"))
 .Kill Tekst
 .For I=1:1 Quit:'$D(^VERSLAG("D",VerslId,"T",I))  Set Tekst(I)=^VERSLAG("D",VerslId,"T",I)
 .Set It=I-1 Set:It<1 It=1 Set Tekst(It)=$G(Tekst(It))
 .For I=1:1 Quit:'$D(^VERSLAG("D",VerslId,"M",I))  Do
 ..Set Motiv=^VERSLAG("D",VerslId,"M",I)
 ..If $L(Tekst(It))+$L(Motiv)>510 Set It=It+1,Tekst(It)=""
 ..Set:$L(Tekst(It)) Tekst(It)=Tekst(It)_"~"
 ..Set Tekst(It)=Tekst(It)_Motiv
 .For I=1:1 Quit:'$D(^VERSLAG("D",VerslId,"E",I))  Do
 ..Set Evaluat=^VERSLAG("D",VerslId,"E",I)
 ..If $L(Tekst(It))+$L(Evaluat)>510 Set It=It+1,Tekst(It)=""
 ..Set:$L(Tekst(It)) Tekst(It)=Tekst(It)_"~"
 ..Set Tekst(It)=Tekst(It)_Evaluat
 .Do DELOBJ(VerslId)
 .Do SAVE(VerslId,Date,FTime,TTime,DateMod,RefType,RefNr,"","","",BeginKm,EindKm,DagKm,Auteur,IntPers,ExtPers,.MotEva,.TeDoen,.Tekst,Adres,MailRef)
 Quit
 ;
 ; Verwijderen van een verslag (Oude versie)
DELOBJ(VerslId) 
 New I,R,Date,RefType,RefNr,IntPers,MailId
 Set R=^VERSLAG("D",VerslId,0),Date=$P(R,D),RefType=$P(R,D,5),RefNr=$P(R,D,6)
 Set IntPers=$G(^VERSLAG("D",VerslId,"I"))
 For I=1:1:$L(IntPers,D) Kill:$L($P(IntPers,D,I)) ^VERSLAG("II",$P(IntPers,D,I),+Date,VerslId)
 If RefType="LE",RefNr Kill ^VERSLAG("IL",RefNr,+Date,VerslId)
 If RefType="KL",RefNr Kill ^VERSLAG("IK",RefNr,+Date,VerslId)
 If RefType="PP" Do
 .Set R=$$UPCASE^vhRtn1($P($G(^VERSLAG("D",VerslId,"A")),D))
 .If $L(R) Kill ^VERSLAG("IP",R,+Date,VerslId)
 Set MailId=$P($G(^VERSLAG("D",VerslId,"P")),D)
 Do:MailId DELOBJ^vhMAIL(MailId)
 Kill ^VERSLAG("D",VerslId)
 Quit
 ;
 ; Wegschrijven van een verslag (Nieuwe versie)
SAVE(VerslId,Date,FTime,TTime,DateMod,RefType,RefNr,BezSoort,Bestel,Geldig,BeginKm,EindKm,DagKm,Auteur,IntPers,ExtPers,MotEva,TeDoen,Tekst,Adres,MailRef) 
 New I,R
 Set MailRef=$G(MailRef)
 If RefType="PP" Set ^VERSLAG("D",VerslId,"A")=RefNr,RefNr=""
 Set R=Date_D_FTime_D_TTime_D_""_D_RefType_D_RefNr_D_BezSoort_D_Bestel
 Set R=R_D_Geldig_D_BeginKm_D_EindKm_D_DagKm_D_DateMod_D_Auteur
 Set ^VERSLAG("D",VerslId,0)=R
 For I=1:1 Quit:'$D(Tekst(I))  Set ^VERSLAG("D",VerslId,"T",I)=Tekst(I)
 For I=1:1 Quit:'$D(MotEva(I))  Set ^VERSLAG("D",VerslId,"EM",I)=MotEva(I)
 Set TeDoen=""
 For I=1:1 Quit:'$D(TeDoen(I))  Set TeDoen=TeDoen_D_TeDoen(I)
 Set $E(TeDoen)="" Set:$L(TeDoen) ^VERSLAG("D",VerslId,"TD")=TeDoen
 Set:$L(IntPers) ^VERSLAG("D",VerslId,"I")=IntPers Set:$L(ExtPers) ^VERSLAG("D",VerslId,"C")=ExtPers
 Set:$L(Adres) ^VERSLAG("D",VerslId,"A")=Adres
 Set:$L(MailRef) ^VERSLAG("D",VerslId,"P")=MailRef
 Do BLDIND(VerslId)
 Quit
 ;
 ; Opbouwen van de indexen van een verslag
BLDIND(VerslId) 
 New I,R,Date,RefType,RefNr,IntPers
 Set R=^VERSLAG("D",VerslId,0),Date=$P(R,D),RefType=$P(R,D,5),RefNr=$P(R,D,6)
 Set IntPers=$G(^VERSLAG("D",VerslId,"I"))
 If $L(IntPers) Do
 .For I=1:1:$L(IntPers,D) Do
 ..Quit:'$P(IntPers,D,I)
 ..Quit:'$D(^vhUSER("D",$P(IntPers,D,I)))
 ..Set ^VERSLAG("II",$P(IntPers,D,I),+Date,VerslId)=I
 If RefType="LE",RefNr Set ^VERSLAG("IL",RefNr,+Date,VerslId)=""
 If RefType="KL",RefNr Set ^VERSLAG("IK",RefNr,+Date,VerslId)=""
 If RefType="PP" Do
 .Set R=$$UPCASE^vhRtn1($P($G(^VERSLAG("D",VerslId,"A")),D))
 .If $L(R) Set ^VERSLAG("IP",R,+Date,VerslId)=""
 Set ^VERSLAG("ID",+Date,VerslId)=""
 Set:$P($ZU(5),",")="VTW" ^VERSLAG("UPD",VerslId)=""
 Quit
 ;