cA700	;OPBOUW RECORD MS-DOS ;%A700; [ 01/04/01  2:37 PM ]
	;
T0	;Opbouw record ms-dos ;
T1	;Het formaat;
T2	;volgend formaat;
	;
T0F	;Création record ms-dos ;
T1F	;Format;
T2F	;format suivant;
	;
T0E	;Building record ms-dos ;
T1E	;The file type;
T2E	;next file type;
	;
1	N UREF
	S UREF="^HULP(""TR"",Q,TNR)"
11	S S2="" F S1=1:1:RT S S3=$G(RT(S1)) D S2
	I $G(PTS)=4!$G(SWSET),$E(S2,$L(S2))=VS S S2=$E(S2,1,$L(S2)-1)  ; indien print to file via Reflection laatste sep. eraf halen
19	S S2=S2_RS D S1
	;
YZ	K S1,S2,S3,RT Q      
	;
	; schrijven van 1 record
S1	I $G(PTS)=4 D  G S1Z    ; print to file via Reflection
	. ; MSM
	. I $ZV["MSM" W $$D2NT^cQCV(S2) Q
	. ; Caché
	. W S2
	S TVG=TVG+1,@UREF@(TVG)=S2
S1A	I '$G(SWSET) S S0=^(0),$P(S0,D,4)=$P(S0,D,4)+1,$P(S0,D,9)=$P(S0,D,9)+$L(S2),^(0)=S0 I $G(RO) S FP=RO W @F,$J($P(S0,D,4),8)
S1Z	K S0 Q
	;
	; opbouw 1 record
S2	I VL,$G(RL(S1)) D S3
	I $G(VQ),'$G(RN(S1)) S S3=$C(34)_$$QUOTE(S3)_$C(34)  ; data tussen quotes
S2A	; I $G(PTS)'=4,$L(S2)+$L(S3)+$L(VS)+$L(RS)>255 D S1 S S2=""
	; KU : 18.04.06  : in Caché niet meer op lengte testen
	I $ZV["MSM",$G(PTS)'=4,$L(S2)+$L(S3)+$L(VS)+$L(RS)>255 D S1 S S2=""
S2Z	S S2=S2_S3_VS Q
	;
S3	I $G(RN(S1)),$L(S3)<RL(S1) S S3=0_S3 G S3
S3Z	S S3=$E(S3_$J("",RL(S1)),1,RL(S1)) Q
	;
QUOTE(R)	; indien in R een Quote zit : quote verdubbelen
	I R'["""" G QUOTEZ
	N I,J
	S I=0
	F  S J=$F(R,"""",I) Q:'J  S R=$E(R,1,J-1)_""""_$E(R,J,$L(R)),I=J+1
QUOTEZ	Q R
	;
SET(UREF,TXT,VNR,VL,VS,RS,VQ)	
	; UREF = bestand waarin de data moet terecht komen : bv "^TEMP(boot,$j+.01,1)"
	; TXT wordt doorgegeven als referentie : dus d SET(.TXT,...)
	; TXT(n) = inhoud kolom n _D_ lengte kolom n
	; VNR = VNR in bestand -> komrt terecht in var. TVG
	; VL = vaste veldlengte            |
	; VS = veldseparator               | -> zie ook doc. van formaten
	; RS = Recordseparator             | 
	; VQ = data tss quotes : 1 = ja    | 
	N I,RT,RL,S1,S2,S3,SWSET
	S $ZT="TRAP^cAN000"
	S I="",RT=0,SWSET=1 S:'$L($G(VNR)) VNR=9 S TVG=VNR
	F  S I=$O(TXT(I)) Q:I=""  S RT=RT+1,RT(RT)=$P(TXT(I),D),RL(RT)=$P(TXT(I),D,2)
	I '$L($G(UREF)) S UREF="^HULP(""TR"",Q,TNR)"
	D 11
SETZ	Q
	;
FO	S R="O;FORM;FORM1;"_$P($T(@("T1"_QT)),U,2)_U_$P($T(@("T2"_QT)),U,2) G O^cA200
FW	S R="W;FORM;FORM1;"_$P($T(@("T1"_QT)),U,2) G W^cA200
FR	S R="R;FORM;FORM1;"_$P($T(@("T1"_QT)),U,2) G R^cA200
FV	S R="V;FORM;FORM1;"_$P($T(@("T1"_QT)),U,2) G V^cA200
FL	S R="L;FORM;FORM1;"_$P($T(@("T1"_QT)),U,2) G L^cA200
	;
Z	X ^cZ Q
ZZ	; 25.04.06 - 15 u 44 * V8.07