cI44	;Conversie ivm grootboekrek. en anal. rek. naar .NET; cI44
	;
YZ	Q
	;
AR(Q,SWTEST)	; Conversie velden in ^_Q_AR voor overgang naar ^DAR
	N I1,INH,INH1,I,DMAW,TAB
	S $ZT="TRAP^cAN000"
	; Opzetten DMA AR voor wijzigen velden 120,117 en 118
	K ^DMA("CONV","AR")
	S DMAW=$G(^DMS(Q,"AR","DMA","W"))
	M ^DMA("CONV","AR",0)=^DMA($P(DMAW,D),$P(DMAW,D,2),0)
	S ^DMA("CONV","AR",1,6,1)="V/W-rekening\Compte perte/prof.\V/G-rechnung\L/P-account"
	S ^DMA("CONV","AR",1,6,2)="7"
	S ^DMA("CONV","AR",1,6,3)="2"
	S ^DMA("CONV","AR",1,6,6)="25"
	S ^DMA("CONV","AR",1,6,9)="1"
	S ^DMA("CONV","AR",1,6,13)="4"
	S ^DMA("CONV","AR",1,6,16)="120"
	S ^DMA("CONV","AR",1,6,22)="1"
	S ^DMA("CONV","AR",1,6,23)="1"
	S ^DMA("CONV","AR",1,11,1)="BTW-rekening\Compte de TVA\MWST-Rechnung\VAT-account"
	S ^DMA("CONV","AR",1,11,2)="12"
	S ^DMA("CONV","AR",1,11,3)="2"
	S ^DMA("CONV","AR",1,11,6)="25"
	S ^DMA("CONV","AR",1,11,9)="1"
	S ^DMA("CONV","AR",1,11,13)="16"
	S ^DMA("CONV","AR",1,11,16)="118"
	S ^DMA("CONV","AR",1,11,22)="1"
	S ^DMA("CONV","AR",1,11,23)="1"
	S ^DMA("CONV","AR",1,12,1)="Wisselrekening\Compte traite\Wechselrechnung\Bill of exch. acc."
	S ^DMA("CONV","AR",1,12,2)="13"
	S ^DMA("CONV","AR",1,12,3)="2"
	S ^DMA("CONV","AR",1,12,6)="25"
	S ^DMA("CONV","AR",1,12,9)="1"
	S ^DMA("CONV","AR",1,12,13)="4"
	S ^DMA("CONV","AR",1,12,16)="117"
	S ^DMA("CONV","AR",1,12,22)="1"
	S ^DMA("CONV","AR",1,12,23)="1"
	S ^DMA("CONV","AR",1,99,1)="Omschrijving F.\Description F.\Omschrijving F.\Omschrijving F."
	S ^DMA("CONV","AR",1,99,2)="14"
	S ^DMA("CONV","AR",1,99,3)="2"
	S ^DMA("CONV","AR",1,99,6)="25"
	S ^DMA("CONV","AR",1,99,9)="1"
	S ^DMA("CONV","AR",1,99,13)="4"
	S ^DMA("CONV","AR",1,99,16)="207"
	S ^DMA("CONV","AR",1,99,22)="1"
	S ^DMA("CONV","AR",1,99,23)="1"
	S I1=0
ARB	S I1=$O(@("^"_Q_"AR(I1)"))
	I I1="" G ARY
	S INH=^(I1,0)
	S INH1=$G(^(1))
	I '$P(INH,D,6)!($P(INH,D,6)="#") S $P(INH,D,6)="0#"
	I $P(INH,D,6)=1 S $P(INH,D,6)="1#"
	; Conversie velden omschrijving
ARC	I '$L($P(INH1,D,5)),'$L($P(INH1,D,7)),'$L($P(INH1,D,9)),'$L($P(INH1,D,11)) F I=5,7,9,11 S $P(INH1,D,I)=$P(INH,D,2)
	; Leeg maken veld opmerking
	S $P(INH,D,31)=""
	I $P(INH,D,20)="" S $P(INH,D,20)=0
	I $P(INH,D,17)="" S $P(INH,D,17)=0
	S @("^"_Q_"AR(I1,0)")=INH
	S ^(1)=INH1
	I $P(INH,D,13)'=1 G ARD
	I $P(INH,D,20)=0,($P(INH,D,17)=0),($P(INH,D,18)="") G ARD
	K TAB
	S TAB(120)=0,TAB(117)=0,TAB(118)=""
	D B^cAN220("AR","CONV",I1,"TAB")
	;
	; Test op tekstrekeningen
ARD	I $P(INH,D,13)=1 D  G ARB
	. I (($P(INH,D,20)'=0)!($P(INH,D,17)'=0)!($P(INH,D,18)'="")) D
	.. I $G(SWTEST) W !,$P(INH,D)_" "
	.. I $P(INH,D,20)'=0 W:$G(SWTEST) "20:"_$P(INH,D,20)_"->0"
	.. I $P(INH,D,18)'="" W:$G(SWTEST) " 18:"_$P(INH,D,18)_"->"""""
	.. I $P(INH,D,17)'=0 W:$G(SWTEST) "17:"_$P(INH,D,17)_"->0"
	; Testen op rekeningen van 0-5: nooit VW-rek., BTW mag niet = 3
	I $E($P(INH,D))<6,($P(INH,D,20)'=0!($P(INH,D,18)=3)) D
	. I $G(SWTEST) W !,$P(INH,D)_" "
	. I $P(INH,D,20)'=0 W:$G(SWTEST) "20:"_$P(INH,D,20)_"->0"
	. I $P(INH,D,18)=3 W:$G(SWTEST) " 18:3->"""""
	; Testen op rekeningen van 6-9: steeds VW-rek, nooit wisselrek., indien BTW'= 3 moet het 0 zijn
	I $E($P(INH,D))>5 D
	. I $P(INH,D,20)'=1 W:$G(SWTEST) !,$P(INH,D)_" 20:"_$P(INH,D,20)_"->1"
	. I $P(INH,D,18)'=3,($P(INH,D,18)'="") W:$G(SWTEST) !,$P(INH,D)_" 18:"_$P(INH,D,18)_"->"""""
	. I $P(INH,D,17)'=0 W:$G(SWTEST) !,$P(INH,D)_" 17:"_$P(INH,D,17)_"->0"
	G ARB
ARY	K ^DMA("CONV","AR")
	W !,"Einde conversie ^_Q_AR voor overgang naar ^DAR"
ARZ	Q
	;
ARA(Q)	; Conversie velden in ^_Q_ARA voor overgang naar ^DARA
	N I1,INH,INH1,I
	S $ZT="TRAP^cAN000"
	S I1=0
ARAA	S I1=$O(@("^"_Q_"ARA(I1)"))
	I I1="" G ARAY
	S INH=^(I1,0)
	S INH1=$G(^(1))
	; Conversie velden omschrijving
ARAB	I '$L($P(INH1,D,5)),'$L($P(INH1,D,7)),'$L($P(INH1,D,9)),'$L($P(INH1,D,11)) F I=5,7,9,11 S $P(INH1,D,I)=$P(INH,D,2)
	; Leeg maken veld opmerking
	S $P(INH,D,31)=""
	S @("^"_Q_"ARA(I1,0)")=INH
	S ^(1)=INH1
	G ARAA
ARAY	W !,"Einde conversie ^_Q_ARA voor overgang naa ^DARA"
ARAZ	Q
	;
AK(Q)	; Conversie bestand AK naar ARA.CURV
	N I1,INH,TAB,I2,UI1H,UI1,BEST,I
	S $ZT="TRAP^cAN000"
	S I1=0
AKA	F  S I1=$O(@("^"_Q_"AK(I1)")) Q:I1=""  D
	. S INH=^(I1,0)
	. K TAB
	. S TAB(1)=$P(INH,D)
	. F I=2,12,22,32 S $P(TAB(1),D,I)=$P(INH,D,2)
	. S $P(TAB(1),D,49)=Q
	. D P^cAN220("ARA.CURV","","","TAB","") I K="-" X "STOP"
	. S UI1H=NUI1
	. S BEST($P(I1," ",2))=UI1H
	. S I2=0
	. F  S I2=$O(@("^"_Q_"AK(I1,I2)")) Q:I2=""  D
	.. S INH=^(I2)
	.. K TAB
	.. S TAB(1)=UI1H_D_I2_D_$$SIG^cAFA1("ARA",$P(INH,D),148)_D_$P(INH,D,2)
	.. S $P(TAB(1),D,49)=Q
	.. S UI1=UI1H_" "_(1000+I2)
	.. D P^cAN220("ARA.CURV.DET","",UI1,"TAB","") I K="-" X "STOP"
	; Aflopen van de grootboekrekeningen en omvormen bestand AK
AKB	S I1=0
	F  S I1=$O(@("^"_Q_"AR(I1)")) Q:I1=""  D
	. S INH=$P(^(I1,0),D,6)
	. I $P(INH,"#")'="K" Q
	. S INH="K#"_$P(BEST($P(INH,"#",2)),D)
	. S $P(@("^"_Q_"AR(I1,0)"),D,6)=INH
	W !,"Einde conversie analytische curves"
AKZ	Q
	;
ZZ	; 29.08.07 - 10 u 22 * V8.09