cI94	;Hernummeren van de vertegenwoordigers (enkel boekhouding); %I94 [ 08/20/2002  12:26 PM ]
	;
	G 1
	;
T0	;Hernummeren van de vertegenwoordigers (enkel boekhouding!);
T1	;Q-waarde;
T2	;Hernummeren vanaf\"xxxxxx = huidig vertegenwoordigersnummer +/- xxxxxx";
T3	;Nieuw vertegenwoordigersnummer = vertegenwoordigersnummer ;
T4	;Bevestiging\".[] = ok";
T5	;Einde hernummering vertegenwoordigers.;
T6	;Keuze\"[] = bijtellen   1[] = aftrekken";
	;
1	D P^cA612(2,1,20,80,1,0,1,1,$P($T(@("T0"_QT)),U,2),0,0,7,1,1)
11	N QQ,NNR,BEV,UI1,NUI1,VTNR,NVTNR,NAAM,I1,USA,UQA
13	S $ZT="TRAP^cAN000"
	;  Vraagstelling voor welke Q-waarde
15	S R="QQ\22\3\"_$P($T(@("T1"_QT)),U,2)_"\C1\3\\$L(K)&(""-""[K!($$QWRD^cI93(K)))\\\1\\1" D R0
16	I QQ="-" G YZ
17	W /CUP(2,2),@F6,$P($T(@("T1"_QT)),U,2),@F9," : ",QQ
	; Vraagstelling naar de hernummering
19	S R="NNR\22\3\"_$P($T(@("T2"_QT)),U,2)_"\7\\$L(K)&(""-""[K!(K?.N))\\\\\1" D R0
	;
2	I NNR="-" G 15
21	S R="TEKEN\22\3\"_$P($T(@("T6"_QT)),U,2)_"\1\\K=""1""!(K=""-"")!(K="""")\\\\\1" D R0
23	I TEKEN="-" G 19
25	W /CUP(4,3),$P($T(@("T3"_QT)),U,2),$S(TEKEN="":"+ ",1:"- "),NNR
27	S R="BEV\22\3\"_$P($T(@("T4"_QT)),U,2)_"\1\\$L(K)&(K="".""!(K=""-""))" D R0
28	I BEV="-" G 21
29	I TEKEN=1 S NNR="-"_NNR
	;
	;  Hernummeren van de vertegenwoordigers
3	K ^TEMPC($T(+0),QQ) 
	;  Aflopen van het vertegenwoordigersbestand
31	S UI1=0
33	F  S UI1=$O(@("^"_QQ_"VT(UI1)")) Q:UI1=""  D
	. S VTNR=$P(^(UI1,0),D)
	. W /CUP(17,2),@F2,VTNR
	. S NAAM=$P(^(0),D,2)
	. S NVTNR=VTNR+NNR
	. I $D(^TEMPC($T(+0),QQ,"VT",VTNR)) Q
	. S $P(@("^"_QQ_"VT(UI1,0)"),D)=NVTNR
	. S NUI1=$$DI^cAN000(NAAM,NVTNR)
	. M @("^"_QQ_"VT(NUI1)")=@("^"_QQ_"VT(UI1)")
	. S ^TEMPC($T(+0),QQ,"VT",NVTNR)=VTNR_D_NVTNR
	. K @("^"_QQ_"VT(UI1)")
	. S @("^"_QQ_"VT1(NVTNR)")=NUI1
	. K @("^"_QQ_"VT1(VTNR)")
	. ; Hernummeren logging
	. M ^DLOG(QQ,"VT",NVTNR)=^DLOG(QQ,"VT",VTNR)
	. K ^DLOG(QQ,"VT",VTNR)
	. ; Hernummeren TXT
	. M ^DTXT(QQ,"VT",NVTNR)=^DTXT(QQ,"VT",VTNR)
	. K ^DTXT(QQ,"VT",VTNR)
	; Hernummeren ^DIN
35	S ^DIN(QQ,"VT")=$G(^DIN(QQ,"VT"))+NNR
	;  Controle indexen vertegenwoordigers
37	N Q S Q=QQ
38	D DMS^cAN000("UQC","USC","VT")
39	D S1^cAN002(UQC,USC,17,0)
	;
	;  Hernummeren klanten
4	S UQA=$P($G(^DMS(QQ,"KL","DMA","W")),D),USA=$P($G(^("W")),D,2)
41	I UQA=""!USA="" G 5
43	S I1=0
45	F  S I1=$O(@("^"_QQ_"KL(I1)")) Q:I1=""  D
	. W /CUP(17,2),@F2,I1
	. I '$L($P(^(I1,0),D,21)) Q
	. S NVTNR=$P(^(0),D,21)+NNR
	. D W^cAN220(USA,UQA,I1,121,NVTNR)
	;
5	S K=$P($T(@("T5"_QT)),U,2) D TXT^cAFA1(250)
	;
YZ	D C^cA612 Q
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q
	;
C1	W !?2,$TR(^cLOG(boot,"Q","TST,"_boot),"\"," ") Q
	;
QWRD(K)	;  Inputcontrole op geldige Q-waarde
	N R,qq
	S $ZT="TRAP^cAN000"
	I '$L(K) S R=0 G QWRDZ
	S R=1
	S qq=^cLOG(boot,"Q","TST,"_boot)
	S qq=U_$TR(qq,"\",U)_U
	I qq'[(U_K_U) S R=0
QWRDZ	Q R
	;
ZZ	; 29.10.02 - 11 u 38 * V7.93