cQUP318 ;Update cQ ;cQUP318; [ 08/24/01  9:19 AM ]
 ;
1 ;Updated routines
 ;cQ*
 ;New Routines
 ;cQ*
 ;
2 ;Update
 W !!,"Update voor  ",$ZV,"  release  ",$P($T(ZZ),"-r",2),! R K:2
 D SWNS^cQ13,VERS^cQ7,LOGOUT^cQ7
 ;
 S REL=$P($T(ZZ),"-r",2),RELDP=$TR(REL,".")
 F K="cQINT","cQUP" D
 . S (I,J)=K
 . F  S I=$O(^$R(I)) Q:$E(I,1,$L(J))'=J  S K=$P(I,J,2) I K?.N,K'=RELDP X "ZR  ZS @I"
 ;
 S CN=$ZU(5),SN="%SYS"
 ;
3 ;Save routines in namespace %SYS
 D RS("cCHARWIN\%CHARWIN",CN,SN)
 D RS("cX364\%X364",CN,SN)
 D RS("cQQ\cQQ",CN,SN)
 D RS("cQZSTART\%ZSTART",CN,SN)
 D RS("cQZSTOP\%ZSTOP",CN,SN)
 ;
4 ;Save routines in current namespace
 D RS("cQIINT\IINT",CN,CN)
 D RS("cQTTSC\TTSC",CN,CN)
 ;
5 ;Delete routines in namescpace %SYS
 D RD("cQMSMQ",CN,SN)
 D RD("%ZSTU",CN,SN)
 D RD("%ZHALT",CN,SN)
 ;
6 ;Delete routines in current namespace 
 D RD("cQCACHE",CN,CN)
 D RD("cQINST9",CN,CN)
 D RD("cQDUMMY",CN,CN)
 D RD("cQZHALT",CN,CN)
 D RD("cQZSTU",CN,CN)
 D RD("cQALERT",CN,CN)
 ;
7 ;Adjust logbook Backup
 S TYPE=$G(^cLOG(cs,"BACKUP","TYPE"),4)
 I '$D(^cLOG(cs,"BACKUP","LOGBOEK",TYPE)) D
 . K ^xxxx
 . M ^xxxx(cs,"BACKUP","LOGBOEK",TYPE)=^cLOG(cs,"BACKUP","LOGBOEK")
 . K ^cLOG(cs,"BACKUP","LOGBOEK")
 . M ^cLOG(cs,"BACKUP","LOGBOEK",TYPE)=^xxxx(cs,"BACKUP","LOGBOEK",TYPE)
 . K ^xxxx
 ;
8 ;Change references to routines cQMSM... to cQ...
 K N D NSPC^cQ21(.N,1) S N=""
 F  S N=$O(N(N)) Q:N=""  D
 . F G="^DAMBA","^cDAMBA","^EABA" S GS=G_"(""MENU"")",I1="" D
 .. F  S I1=$O(@GS@(I1)) Q:I1=""  S I2="" D
 ... F  S I2=$O(@GS@(I1,I2)) Q:I2=""  S A=^(I2) I A["cQMSM" D  S ^(I2)=A
 .... F  S A=$P(A,"cQMSM",1)_"cQ"_$P(A,"cQMSM",2,$L(A,"cQMSM")) Q:A'["cQMSM"
 ;
9 W !!
 ;
YZ Q
 ;
RS(R,From,To)       ; Save routine R in namespace To
 S R=$G(R),From=$G(From),To=$G(To)
 Q:'$L(R)  Q:'$L($P(R,"\"))  Q:'$D(^$R($P(R,"\")))  Q:'$L($P(R,"\",2))  Q:'$L(From)  Q:'$L(To)
 W !,"Saving ",$P(R,"\")," as ",$P(R,"\",2)," in namespace ",To
 X "ZL "_$P(R,"\")_" ZN To ZS "_$P(R,"\",2)_" ZN From"
 Q
 ;
RD(R,From,To)       ; Delete routine R in namespace To
 S R=$G(R),From=$G(From),To=$G(To)
 Q:'$L(R)  Q:'$L($P(R,"\"))  Q:'$L(From)  Q:'$L(To)
 W !,"Removing ",$P(R,"\")," in namespace ",To
 X "ZN To ZR  ZS "_$P(R,"\")_" ZN From"
 Q
 ;
XL(R,From,To)       ; Xecute R in namespace To
 S R=$G(R),From=$G(From),To=$G(To)
 Q:'$L(R)  Q:'$L($P(R,"\"))  Q:'$L(From)  Q:'$L(To)
 W !,"Xecuting ",$P(R,"\")," in namespace ",To
 X "ZN To "_$P(R,"\")_" ZN From"
 Q
 ;
ZZ ; 24.08.01 -  9 u 19 * Cache-r3.1.8