cTN102	; Cumuls + omzet ; cTN102
	;
YZ	Q
	;
CUM(TREK,REK,BP,SW,BEDR,BEDRVM)	; Cumuls rekening aanpassen
	; Input: TREK: Type rekening
	;              AR:  Grootboekrekening
	;              ARA: Analytische rekening
	;              EC1: Extra-compt. rekening 1
	;              EC2: Extra-compt. rekening 2
	;              EC3: Extra-compt. rekening 3
	;              KL:  Klantenrekening
	;              LE:  Leveranciersrekening
	;        REK: UI1 rekening
	;        BP: Boekingsmaand
	;        SW: Switch bedrag
	;            D = Debet
	;            C = Credit
	;            O = Omzet (enkel klanten/leveranciers)
	;        BEDR: Bedrag in munt BH
	;        BEDRVM: Bedrag in vreemde munt
	N UI1,i,UREF,UQC,USC,CUM,CUMN,K,DMS
	S $ZT="TRAP^cAN000"
	;
	; Controle parameters
CUM1	F i="TREK","REK","BP","SW","BEDR","BEDRVM"  S @i=$G(@i)
	I '$L(TREK)!'$L(REK)!'$L(BP)!'$L(SW)!'$L(BEDR) G CUMZ
	I +BEDR=0,(+BEDRVM=0) G CUMZ
	;
	; Ophalen definities
CUM2	S Q(49)=$$Q49^cAFVBA03(Q,"REG"),TREK=$P(TREK,".") 
	S UI1=$$Q^cAFA10_" "_$TR(BP,".","")_" "_REK,DMS="CUM."_TREK
	D DMS^cAN000("UQC","USC",DMS,1) I (UQC="")!(USC="") G CUMZ
	S UREF=$G(^DMC(UQC,USC,"DATA","REF")) I '$L(UREF) G CUMZ
	;
	; Locken (zonder time-out)
CUM3	L +@UREF
	;
	; Cumuls opzetten
CUM4	I $D(@UREF) G CUM5
	S $P(CUM(1),D,2)=BP                        ; 2.  Boekingsmaand
	S $P(CUM(1),D,3)=REK                       ; 3.  Rekening
	;
	; Firmamunt
CUM41	S $P(CUM(1),D,11)=$S(SW="D":BEDR,1:"")     ; 11. Cumulbedrag debet in firmamunt 
	S $P(CUM(1),D,12)=$S(SW="C":BEDR,1:"")     ; 12. Cumulbedrag credit in firmamunt 
	;
	; Vreemde munt
	I TREK'="AR" G CUM45
CUM43	S $P(CUM(1),D,13)=$S(SW="D":BEDRVM,1:"")   ; 13. Cumulbedrag debet in vreemde munt
	S $P(CUM(1),D,14)=$S(SW="C":BEDRVM,1:"")   ; 14. Cumulbedrag credit in vreemde munt
	;
	; Omzet
CUM45	I SW'="O" G CUM49
	S $P(CUM(1),D,10)=BEDR                     ; 10. Omzet (enkel voor klant/leverancier)
	;
CUM49	D P^cAN220(DMS,"",UI1,"CUM","") I $L(K) X "STOP"
	G CUMY
	;	
	; Cumuls aanpassen
CUM5	S CUMN=@UREF@(0)
	I SW="D" S CUM(111)=$P(CUMN,D,11)+BEDR I TREK="AR" S CUM(113)=$P(CUMN,D,13)+BEDRVM ; Debet
	I SW="C" S CUM(112)=$P(CUMN,D,12)+BEDR I TREK="AR" S CUM(114)=$P(CUMN,D,14)+BEDRVM ; Credit
	I SW="O" S CUM(110)=$P(CUMN,D,10)+BEDR ; Omzet
	;
	D B^cAN220(DMS,"",UI1,"CUM") I $L(K) X "STOP"
	;
	; Unlocken
CUMY	L -@UREF
	;
CUMZ	Q
	;
CUMS(AR,ARA,IAS,BP,BPE,SW,BEDR) ; Samengestelde cumul aanpassen
	; Input: REK: UI1 rekening
	;        BP: Boekingsmaand
	;        SW: Switch bedrag
	;            D = Debet
	;            C = Credit
	;        BEDR: Bedrag in munt BH
	N UI1,i,UREF,UQC,USC,CUM,CUMN,K,DMS,STJR
	S $ZT="TRAP^cAN000"
	;
	; Controle parameters
CUMS1	F i="AR","ARA","IAS","BP","BPE","SW","BEDR"  S @i=$G(@i)
	I '$$PAR^cTN001(Q,501) G CUMSZ ; Geen analytische BH
	I '$L(AR)!'$L(BP)!'$L(SW)!'$L(BEDR) G CUMSZ
	S STJR=$$PAR^cTN001(Q,515) I $L(STJR),STJR>$$BJ^cTN003(Q,BP) G CUMSZ ; Pas vanaf startjaar 
	I +BEDR=0 G CUMSZ
	;
	; Ophalen definities
CUMS2	S Q(49)=$$Q49^cAFVBA03(Q,"REG"),DMS="CUM"
	S UI1=$$Q^cAFA10_" "_$TR(BP,".","")_" "_AR_" "_ARA_" "_IAS_" "_$TR(BPE,".","")
	S UREF=$P($$REF^cAFA10(.Q,DMS),D) I '$L(UREF) G CUMSZ
	;
	; Locken (zonder time-out)
CUMS3	L +@UREF
	;
	; Cumuls opzetten
CUMS4	I $D(@UREF) G CUMS5
	S $P(CUM(1),D,2)=BP                        ; 2.  Boekingsmaand
	S $P(CUM(1),D,3)=AR                        ; 3.  Grootboekrekening
	S $P(CUM(1),D,4)=ARA                       ; 4.  Analytische rekening
	S $P(CUM(1),D,5)=IAS                       ; 5.  IAS rekening
	S $P(CUM(1),D,6)=BPE                       ; 6.  Leveringsmaand (boekingsperiode)
	; 
	; Debet/Credit
CUMS41	S $P(CUM(1),D,11)=$S(SW="D":BEDR,1:"")     ; 11. Cumulbedrag debet in firmamunt 
	S $P(CUM(1),D,12)=$S(SW="C":BEDR,1:"")     ; 12. Cumulbedrag credit in firmamunt 
	;
CUMS49	D P^cAN220(DMS,"",UI1,DMS,"") I $L(K) X "STOP"
	G CUMSY
	;	
	; Cumuls aanpassen
CUMS5	S CUMN=@UREF@(0)
	I SW="D" S CUM(111)=$P(CUMN,D,11)+BEDR
	I SW="C" S CUM(112)=$P(CUMN,D,12)+BEDR
	;
	D B^cAN220(DMS,"",UI1,DMS) I $L(K) X "STOP"
	;
	; Unlocken
CUMSY	L -@UREF
	;
CUMSZ	Q
	;
OMZ(TREK,REK,KJ,BEDR)	; Omzet rekening aanpassen
	; Input: TREK: Type rekening
	;              KL:  Klantenrekening
	;              LE:  Leveranciersrekening
	;        REK: UI1 rekening
	;        KJ: Boekingsmaand of kalenderjaar
	;        BEDR: Bedrag in munt BH
	N UI1,i,UREF,UQC,USC,OMZ,OMZN,K,DMS,NUI1
	S $ZT="TRAP^cAN000"
	;
	; Controle parameters
OMZ1	F i="TREK","REK","KJ","BEDR"  S @i=$G(@i)
	I '$L(TREK)!'$L(REK)!'$L(KJ)!'$L(BEDR) G OMZZ
	I '((TREK="KL")!(TREK="LE")) G OMZZ
	S KJ=$P(KJ,".")
	;	
	; Ophalen definities
OMZ2	S DMS="OMZ."_TREK
	S Q(49)=$$Q49^cAFVBA03(Q,DMS) 
	S UI1=$$Q^cAFA10()_" "_KJ_" "_REK
	D DMS^cAN000("UQC","USC",DMS,1) I (UQC="")!(USC="") G OMZZ
	S UREF=$G(^DMC(UQC,USC,"DATA","REF")) I '$L(UREF) G OMZZ
	;
	; Locken (zonder time-out)
OMZ3	L +@UREF
	;
	; Omzet opzetten
OMZ4	I $D(@UREF) G OMZ5
	S $P(OMZ(1),D)=KJ                          ; 1.  Kalenderjaar
	S $P(OMZ(1),D,2)=REK                       ; 2.  Rekening
	S $P(OMZ(1),D,3)=BEDR                      ; 3.  Omzet in munt BH
	D P^cAN220(DMS,"",UI1,"OMZ","") I $L(K) X "STOP"
	G OMZY
	;	
	; Omzet aanpassen
OMZ5	S OMZN=@UREF@(0),BEDR=BEDR+$P(OMZN,D,3)
	D W^cAN220(DMS,"",UI1,103,BEDR) I $L(K) X "STOP"
	;
	; Unlocken
OMZY	L -@UREF	
	;
OMZZ	Q
	;
ZZ	; 29.08.07 - 10 u 22 * V8.09