cTN1114	; Aankoop : Inschrijven aankoopdocumenten: link met gecontroleerde levering; cTN1114;
	;
T1	;Factuur is reeds ingeboekt onder nummer ;
	;
T1F	;Facture est déjà inscrite sous le numéro ;
	;
T1E	;Voucher is already registered with number ;
	;
T1D	;Rechnung ist schon gebucht mit Nummer ;
	;
YZ	Q
	;
	;
BTMPGL(GRIDID,LE)	; Opbouwen mtemp99 voor de openstaande gecontroleerde leveringen
	; Input: GRIDID: Gridid van mtemp99 met registraties (indien "": nieuw gridid ophalen)
	;        LE: UI1 van de leverancier
	; Output: GRIDID
	;         of 
	;         0\Foutboodschap
	S $ZT="ERR^cAFVBF01"
	N @$$INITVAR^cAFVBA01("GRIDID,LE")
	;
	; Controle parameters
BTMPGL1	F i="GRIDID","LE" S @i=$G(@i)
	S OK="" I '$L(LE) G BTMPGLZ
	I '$L(GRIDID) S GRIDID=$$GRIDID^cAFVBF01()
	S LENR=$$SIG^cAFA1("LE.A",LE,101) I '$L(LENR) G BTMPGLZ
	K ^mtemp99(GRIDID,"COMMON")
	;
	; Opslag 
BTMPGL2	S QAK=$$QAK($$Q^cAFA10()) ; Q-waarde aankoop
	S REF="^"_QAK_"TOA(LENR)" I '$D(@REF) G BTMPGLZ
	;
	; Mtemp99 opbouwen
	S LREF=""
BTMPGL3	S LREF=$O(@REF@(LREF)) I '$L(LREF) G BTMPGLY
	S FNR=$P(@REF@(LREF),D),(UR,NODE0,NODE3)="" K BON 
	; Alle gecontroleerde leveringen doorlopen met hetzelfde factuurnummer leverancier
BTMPGL4	S UR=$O(@REF@(LREF,UR)) I UR="" S BDT="" G BTMPGL6
BTMPGL5	S RQ=^(UR),US=$P(RQ,D),RQ=$P(RQ,D,2) S:RQ="" RQ=QAK G BTMPGL4:'$D(@("^"_RQ_"TOL(LENR,US,UR,1)")) 
	S OMS=$P(^(1),D,3)                              ; Referte bon
	S BONDT=$P(^(1),D,2) S DBONDT=$$DC^cAFD1(BONDT) ; Datum bon 
	S $P(BON(DBONDT,UR),D)=FNR             ; Leveranciersnummer
	S $P(BON(DBONDT,UR),D,2)=$P(^(1),D,3)  ; Referte bon
	S $P(BON(DBONDT,UR),D,3)=UR            ; Bonnummer
	S $P(BON(DBONDT,UR),D,4)=BONDT         ; Datum bon
	G BTMPGL4
	; 
	; Bonnen 		
BTMPGL6	S BDT=$O(BON(BDT),-1) I '$L(BDT) G BTMPGL9
	S VNR=""
BTMPGL7	S VNR=$O(BON(BDT,VNR),-1) I '$L(VNR) G BTMPGL6
	I $L($P(NODE0,D)) G BTMPGL8
	S $P(NODE0,D)=$P(BON(BDT,VNR),D)
	S $P(NODE0,D,2)=$P(BON(BDT,VNR),D,2)
	S $P(NODE0,D,3)=$P(BON(BDT,VNR),D,3)
	S $P(NODE3,D)=$P(BON(BDT,VNR),D,4)
	G BTMPGL7
BTMPGL8	I $L($P(NODE0,D,4),",")'<5 S $P(NODE0,D,4)=$P(NODE0,D,4)_",..." G BTMPGL9
	S $P(NODE0,D,4)=$P(NODE0,D,4)_$S($L($P(NODE0,D,4)):", ",1:"")
	S $P(NODE0,D,4)=$P(NODE0,D,4)_$P(BON(BDT,VNR),D,3)_" ("_$P(BON(BDT,VNR),D,4)_")"
	G BTMPGL7	
BTMPGL9	S ^mtemp99(GRIDID,"COMMON",LREF,0)=NODE0,^(3)=NODE3
	G BTMPGL3
	; ...
BTMPGLY	S OK=GRIDID 
BTMPGLZ	Q OK
	;
BEDR(GRIDID,LE,LREF,MNT,MPAR)	; Opmaken van hoofding + registraties aan de hand van gecontroleerde levering
	; Input: GRIDID: GridId
	;        LE:     Leverancier (ID ^DLE)
	;        LREF:   Factuurnummer leverancier
	;        MNT:    Munt aankoopdocument
	;        MPAR:   Pariteit (1 EUR= xxx.xx MNT)
	; Output: 0: Geen gecontroleerde levering gevonden
	;         1: Wel geonctroleerde levering(en) gevonden
	;            Wordt opgezet in:
	;              - Hoofding:     ^mtemp99(GRIDID,"DB","GL")
	;              - Registraties: ^mtemp99(GRIDID,"REG")
	;
	N @$$INITVAR^cAFVBA01("GRIDID,LE,LREF,MNT,MPAR")
	S $ZT="^dmERROR"
	;
	; Check parameters
BEDR1	S R=0 F i="GRIDID","LE","LREF","MNT","MPAR" S @i=$G(@i)
	I '$L(GRIDID) G BEDRZ
	I '$L(LE) G BEDRZ
	S LENR=$$SIG^cAFA1("LE.A",LE,101) I '$L(LENR) G BEDRZ  ; Leveranciersnummer
	S SWBTW=$P(^(0),D,15)                                  ; BTW-aanrekenen?
	I '$L(MNT) S MNT=$P(^(0),D,11)                         ; Munt leverancier
	I '$L(LREF) G BEDRZ
	S LREF=$$DI^cAN000(LREF,"")                            ; Factuurnummer leverancier
	S (NETG,NETD,NETI,NETA,AFBTW,TTB,MST)=0                ; Bedragen initialiseren
	S BHM=$$SIG^cAFA1("Q",$$Q^cAFA10,202)                  ; Munt boekhouding
	S QQ=$$Q^cAFA10	D                                      ; Tabel met BTW-percentages ophalen
	. N Q
	. S Q=QQ D S1^cA305 
	;
	; Gegevens uit TOA ophalen	
BEDR2	S QAK=$$QAK($$Q^cAFA10())                              ; Q-waarde aankoop
	S REF="^"_QAK_"TOA(LENR)" I '$D(@REF) G BEDRZ
BEDR21	S (UR,OMS,OMDT)=""
	; Alle gecontroleerde leveringen doorlopen met hetzelfde factuurnummer leverancier
BEDR23	S UR=$O(@("^"_QAK_"TOA(LENR,LREF,UR)")) I UR="" G BEDR3
BEDR25	S RQ=^(UR),US=$P(RQ,D),UZ=100,RQ=$P(RQ,D,2) S:RQ="" RQ=QAK G BEDR23:'$D(@("^"_RQ_"TOL(LENR,US,UR,1)")) 
	S VM=$P(^(1),D,18) I '$L(VM) S VM=BHM           ; Munt bon
	S BONDT=$P(^(1),D,2) S DBONDT=$$DC^cAFD1(BONDT) ; Datum bon
	I BONDT'<OMDT S OMS=$P(^(1),D,3),OMDT=BONDT     ; Referte bon
BEDR27	S UZ=$O(@("^"_RQ_"TOL(LENR,US,UR,UZ)")) I UZ="" G BEDR23
	S BE=$P(^(UZ),D,9),BTWC=$P(^(UZ),D,8),BTWB=$P(^(UZ),D,10)
	S BE=$$OMREK^cTN001(.Q,BE,VM,MNT,"","",MPAR)        ; Bedrag (omrekenen naar munt document)
	S BTWB=$$OMREK^cTN001(.Q,BTWB,VM,MNT,"","",MPAR)    ; Maatstaf (omrekenen naar munt document)
	S MST=MST+BTWB,AFBTW=AFBTW+($G(PBTW(+BTWC))*BTWB/100)
	I $G(PBTW(+BTWC))="Z.B." S MST=MST-BTWB,NETA=NETA+BE G BEDR29
	S BR=$P(^(UZ),D),AR=$P(^(UZ),D,44)          ; K-code - A-code
	I $L(BR) S BR=$$UI1OP^cAFA1("AR.A","M1","",$$Q^cAFA10,BR),BRNR=$$SIG^cAFA1("AR.A",BR,101)
	I $G(AR) S AR=$$UI1OP^cAFA1("ARA.A","M1","",$$Q^cAFA10,AR)
	I '$L(BR) G BEDR29
	; Uitsplitsing G/D/I/A
	I $E(BRNR,1,2)=60 S NETG=NETG+BE G BEDR28     ; Klasse 60 = goederen
	I $E(BRNR)=2 S NETI=NETI+BE G BEDR28          ; Klasse 2  = investeringen
	S NETD=NETD+BE                                ; Rest      = diensten
BEDR28	S REG(BR_"~"_AR)=$G(REG(BR_"~"_AR))+BE
	; ATL ??
BEDR29	G BEDR27
	;
	; Bedragen formateren 
BEDR3	S NETG=$J(NETG,0,QD),NETD=$J(NETD,0,QD),NETI=$J(NETI,0,QD),NETA=$J(NETA,0,QD),MST=$J(MST,0,QD),AFBTW=$J(AFBTW,0,QD)
	S FC="F",TTB=$J(NETG+NETD+NETI+NETA,0,QD) I SWBTW S TTB=$J(TTB+AFBTW,0,QD) ;,AFBTW=""
	I 'SWBTW S AFBTW=""
BEDR39	;I TTB'<0 G BEDR4
	; Creditnota
	;S FC="C",TTB=-TTB,NETG=-NETG,NETD=-NETD,NETI=-NETI,NETA=-NETA,MST=-MST,AFBTW=-AFBTW
	;S i="" F  S i=$O(REG(i)) Q:'$L(i)  S:REG(i) REG(i)=-REG(i)
	;
	; Hoofding: bedragen + omschrijving opslaan
BEDR4	K ^mtemp99(GRIDID,"DB","GL")
	S $P(^mtemp99(GRIDID,"DB","GL",0),D,19)=TTB,$P(^(0),D,13)=OMS
	S ^(4)=NETG_D_NETD_D_NETI_D_NETA_D_MST,$P(^(4),D,10)=AFBTW
	;
	; Registraties: bedragen opslaan
BEDR5	K ^mtemp99(GRIDID,"REG")
	S i="" 
BEDR51	S i=$O(REG(i)) I '$L(i) G BEDRY 
	S UI1=$$REGUI1^cTN1113(GRIDID)
	S $P(^mtemp99(GRIDID,"REG",UI1,0),D,8,9)=$P(i,"~")_D_$P(i,"~",2)
	S $P(^(2),D)=REG(i)
	D SREG^cTN1113(GRIDID_"||"_UI1,MNT,MPAR,1)
BEDR59	G BEDR51
	;
BEDRY	S R=1
BEDRZ	Q R
	;
DEL(GRIDID)	; Verwijder mtemp99 met de defaults van de gecontroleerde levering
	N OK
	S $ZT="^dmERROR"
	;
DEL1	S OK=1 I '$L($G(GRIDID)) G DELZ
	K ^mtemp99(GRIDID,"DB","GL")
	;
DELZ	Q OK
	;
LEFNR(LEFNR,LE)	; Check of documentnummer leverancier al is ingeboekt
	; Input: LEFNR: Documentnummer leverancier
	;        LE:  Leverancier (ID ^DLE)
	; Output: 1: alles OK
	;         -1\Waarschuwing
	N @$$INITVAR^cAFVBA01("LEFNR,LE")
	S $ZT="^dmERROR"
	;
	; Controle parameters
LEFNR1	S OK=1 I '$L($G(LEFNR)) G LEFNRZ
	I '$L($G(LE)) G LEFNRZ
	;
	; Check of document reeds is ingeboekt
LEFNR2	S DB=$$UI1OP^cAFA1("DB","M5","",$$Q^cAFA10,"A",LE,LEFNR) I '$L(DB) G LEFNRZ
	S FNR=$$SIG^cAFA1("DB",DB,103)
	S OK=-1_D_$P($T(@("T1"_QT)),U,2)_FNR_"." ; Document is reeds ingeboekt
	;
LEFNRZ	Q OK
	;
LINK(LREF,LE,FNR)	; Link verbreken met aankoop + documentnr invullen bij aankoop
	; Input: LREF: Documentnummer leverancier
	;        LE:   Leverancier
	;        FNR:  Documentnummer boekhouding	
	N LENR,LENR,UR,QAK,US,RQ
	S $ZT="TRAP^cAN000"
	;
	; Controle parameters	
LINK1	I '$L($G(LREF)) G LINKZ
	I '$L($G(LE)) G LINKZ
	I '$L($G(FNR)) G LINKZ
	;
	; Alle bonnen doorlopen
LINK2	S LREF=$$DI^cAN000(LREF,"")
	S LENR=$$SIG^cAFA1("LE.A",LE,101) I '$L(LENR) G LINKZ
	S UR="",QAK=$$QAK^cTN1114($$Q^cAFA10)
LINK3	S UR=$O(@("^"_QAK_"TOA(LENR,LREF,UR)")) G LINKY:'$L(UR) S US=$P(^(UR),D),RQ=$P(^(UR),D,2) I RQ="" S RQ=QAK
LINK5	G LINK3:'$D(@("^"_RQ_"TOL(LENR,US,UR,1)")) 
	; Documentnr BH invullen + status aanduiden als verwerkt
LINK7	S $P(@("^"_RQ_"TOL(LENR,US,UR,1)"),D,45)=FNR,$P(^(1),D,50)=1
	       ; ^DATA(,"TOL."_US ook aanpassen
	I $P($G(@("^"_RQ_"TOL(LENR,US,UR,3)")),D,24) D
	. N USA,UQA,TAB,Q
	. S Q=RQ
	. D DMS^cAN000("UQA","USA","TOL."_US,1) I '$L(UQA)!'$L(USA) Q
	. I $L($G(^DMS(Q,"TOL."_US,"DMA","W"))) S UQA=$P(^("W"),D),USA=$P(^("W"),D,2)
	. S TAB(145)=FNR,TAB(150)=1 D B^cFNA000(Q,USA,UQA,UR,"TAB")
	; Link verbreken (bon-niveau)
	K @("^"_QAK_"TOA(LENR,LREF,UR)")
	G LINK3
	; Link verbreken (factuurnummer leverancier-niveau)
LINKY	I $O(^(UR))="" K @("^"_QAK_"TOA(LENR,LREF)")
LINKZ	Q
	;
VALGL(GRIDID,GL,SGL)	; Validatie van ingegeven gecontroleerde levering
	; Input: GRIDID: GridId van mtemp99 met gecontroleerde leveringen
	;        GL: Ingegeven gecontroleerde levering
	;        SGL: Geselecteerde gecontroleerde levering vanuit de grid
	N R,i,N,GLID,C,ID
	S $ZT="^dmERROR"
	;
VALGL1	I $L($G(SGL)) S ID=SGL,GLID=$P(ID,"||",2) G VALGL41
	S D="\",GL=$TR($$UC^cAFA1($G(GL))," ","")
	;
	; Check parameters
VALGL2	S R=0 I '$L($G(GRIDID))!'$L(GL) G VALGLZ
	;
VALGL3	S (i,C)="" F  S i=$O(^mtemp99(GRIDID,"COMMON",i)) Q:'$L(i)  D  Q:R!(C>1)
	. S N=^(i,0) I $P(N,D,30)=2 Q
	. S NR=$TR($$UC^cAFA1($P(N,D))," ","") I NR=GL S R=1,GLID=i Q
	. I $E(NR,1,$L(GL))=GL S C=C+1,GLID=i
	;
	; Eén gecontroleerde levering gevonden
VALGL4	I '(R!(C=1)) G VALGL5
	S ID=GRIDID_"||"_GLID
VALGL41	S R="1\"_GLID_"\Select T1.TempId, T1.Text01 From TECH.TEMP T1 "
	S R=R_"where T1.ID = '"_ID_"'"
	G VALGLZ
	;
	; Meerdere gecontroleerde leveringen gevonden
VALGL5	I C>1 S R=2_D_GL_D_2 G VALGLZ
	;
	; Geen gecontroleerde leveringen gevonden
VALGL6	S R=0 G VALGLZ
	;
VALGLZ	Q R
	;
QAK(Q)	; Bepalen Q-waarde aankoop
	N QAK
	S $ZT="TRAP^cAN000"
	;
	S QAK=Q ; Q-waarde aankoop (voorlopig) = Q-waarde BH
	;
QAKZ	Q QAK
	;
ZZ	; 29.08.07 - 10 u 22 * V8.09