cTN810	; BTW-eenheid ; cTN8010;  [ 17/11/09  11:27:47 ]
	;
T1	;Geen BTW toegelaten binnen de BTW - eenheid
T2	;Er werd BTW aangerekend binnen de BTW - eenheid\".[] = doorgaan"
	;
T1F	;TVA n'est pas permis dans l'unité TVA
T2F	;Vous voulez inscrire de la TVA dans l'unité TVA\".[] = continuer"
	;
T1E	;No VAT allowed in the VAT unit
T2E	;VAT has been registered in the VAT unit\".[] = continue"
	;
YZ	Q
	;
BTWEH(Q,BTWNR,BP)	; herkenningsfunctie BTW - eenheid
	; 
	; input 
	; Q     = Q - waarde vennootschap waarin huidige factuur gemaakt wordt
	; BTWNR = BTW - nummer van de betrokken klant of leverancier
	; BP    = boekingsmaand waarin de betrokken factuur gemaakt wordt
	; 
	; output = 0 : niet in BTW - eenheid (geen verdere actie)
	;          1 : wel in BTW - eenheid  (BTW forceren op 0)
	; 
	N BTWEH,EEN,IND,KUBTWEH,KUBP,IREF2
	S $ZT="TRAP^cAN000"
	S BTWEH=0
	; factuur aan vennootschap zelf -> geen BTW-eenheid - FB - 01.02.08
	I $$SIG^cAFA1("Q",Q,207)=BTWNR G BTWEHZ
	; vennootschap niet in BTW-eenheid
	S EEN=$$SIGN^cAFA1("Q",Q,1)
	S KUBTWEH=$P(EEN,D,24) I '$L(KUBTWEH) G BTWEHZ
	S KUBP=$P(EEN,D,25)
	S IREF2=$P($$REF^cAFA10(Q,"Q"),D,3)
	I '$L(IREF2) G BTWEHZ
	;
	; maand toetreding niet ingevuld of boekingsmaand kleiner dan maand toetreding BTW - eenheid
	I '$L(KUBP)!(BP<KUBP) G BTWEHZ
	;
	; maand uittreding niet ingevuld of boekingsmaand groter dan maand uittreding BTW - eenheid
	I '$L(KUBP)!(BP<KUBP) G BTWEHZ
	;
	; BTW - nummer niet gevonden in multiple-index
	S BTWNR=$$DP^cAFA1(BTWNR)
	I '$L(BTWNR) G BTWEHZ
	I '$D(@IREF2@("M1",KUBTWEH,BTWNR)) G BTWEHZ
	;
	S BTWEH=1  ; alle testen voldaan -> BTW - eenheid op "ja"
	;
BTWEHZ	Q BTWEH
	;
BTWAOK(Q,BP,KC)	; controle bij inschrijven aankoopfactuur  - FB - 26.11.07
	N OK,BTWNR
	S $ZT="TRAP^cAN000"
	S OK=1
	S BTWNR=$$SG^cAFA1("LE",KC,116)
	I '$L(BTWNR) G BTWAOKZ   ; geen BTW - nummer bij leverancier ingevuld
	I '$$BTWEH^cTN810(Q,BTWNR,BP) G BTWAOKZ            ; geen BTW - eenheid - situatie
	;
	; check of er BTW bedragen zijn
	I '$G(AFBTW),'$G(NAFBTW),'$G(BTWIC),'$G(BTWMC),'$G(BTWOH),'$G(BTWVL) G BTWAOKZ  ; geen BTW - bedragen
	;
	; boekingsperiode '= eerste maand in de BTW - eenheid
	I BP'=$$SIG^cAFA1("Q",Q,225) S K=$P($T(@("T1"_QT)),U,2) D TXT^cAFA1(250) S OK=0 G BTWAOKZ
	;
	; boekingsperiode wel eerste maand in de BTW - eenheid
	S R="K\22\3\"_$P($T(@("T2"_QT)),U,2)_"\1\\""-,.""[K&$L(K)" D R0 I K'="." S OK=0
	;
BTWAOKZ	Q OK
	;
BTWAK(Q,BP,LE,AFBTW,NAFBTW,BTWT) ; Controle bij inschrijven aankoopfactuur  - GM - 25.02.08 - GRAFISCH
	; Input: Q:      Vennootschap
	;        BP:     Boekingsmaand
	;        LE      Leverancier (LE.A)
	;        AFBTW:  Aftrekbare BTW
	;        NAFBTW: Niet-aftrekbare BTW
	;        BTWT:   BTW-bedrag type (MC,IC,...)
	;        
	; Output: 1: Alles OK
	;         0\Foutboodschap
	;         -1\Waarschuwing
	N OK,BTWNR,R
	S $ZT="TRAP^cAN000"
	;
	; BTW-eenheid?
BTWAK1	S R=1,BTWNR=$$SIG^cAFA1("LE.A",LE,116) I '$L(BTWNR) G BTWAKZ   ; Geen BTW-nummer bij leverancier ingevuld
	I '$$BTWEH^cTN810(Q,BTWNR,BP) G BTWAKZ ; Geen BTW-eenheid situatie
	;
	; Check of er BTW bedragen zijn
BTWAK2	I '$G(AFBTW),'$G(NAFBTW),'$G(BTWT) G BTWAKZ ; Geen BTW-bedragen
	;
	; Boekingsperiode '= eerste maand in de BTW-eenheid
BTWAK3	I BP'=$$SIG^cAFA1("Q",Q,225) S R=0_D_$P($T(@("T1"_QT)),U,2)_"." G BTWAKZ
	;
	; boekingsperiode wel eerste maand in de BTW-eenheid
BTWAK4	S R=-1_D_$P($P($T(@("T2"_QT)),U,2),"\")_"."
	;
BTWAKZ	Q R
	;
R0	S $P(R,D,12)=$T(+0),$P(R,D,13)=1 D ^cAN1000 Q  ; v12 23.01.95
	;
BTW00(Q)	; zoeken naar BTW code 00%	;
	N CODE,I2
	S $ZT="TRAP^cAN000"
	S CODE=""
	S I2="" F  S I2=$O(@("^"_Q_"BA(18,I2)")) Q:I2=""!(I2>9)  I $P(^(I2),D)="00%" S CODE=I2 Q
BTW00Z	Q CODE
	;
BTWMT	; rubriek BTW - code in MMM - facturatie - FB - 21.11.07
	N DTC,BP,BTW00
	S $ZT="TRAP^cAN000"
	I '$D(WZ),K="-" G BTWMTZ
	S BTW00=$$BTW00(Q)
	; in geval van wijzigen en BTW-code = 00% => code niet wijzigbaar
	I $D(WZ),$P(B(1),D,8)=BTW00 G BTWMTZ
	;
	; in geval van wijzigen en BTW-code '= 00% => code vragen
	I $D(WZ) S RBTW=$P(B(1),D,8) D ^cA305 G BTWMTZ
	;
	; in geval van registratie
	S K=$S(UM="M"&'KB:0,$$BTWC^BCFN69(PR,Q,KC)'=BTWZB&'KB:0,1:$$BTWC^BCFN69(PR,Q,KC))
	I K=BTWZB G BTWMTZ	; Z.B. wordt niet op 00% geforceerd
	;
	S DTC=$$DC^cAFD1(DT)
	S BP=$E(DTC,1,4)_"."_$E(DTC,5,6)
	I $$BTWEH(Q,$$SG^cAFA1("KL",KC,116),BP) S K=BTW00
BTWMTZ	Q
	;
BP(DAT)	; bepalen boekingsperiode adhv datum
	N BP,DATC
	S $ZT="TRAP^cAN000"
	S DATC=$$DC^cAFD1(DAT)
	S BP=$E(DATC,1,4)_"."_$E(DATC,5,6)
BPZ	Q BP
	;
ZZ	; 16.10.08 - 14 u 11 * V9.04