cABVB04	;Aanmaken standaard tab;  cABVB04
	;
	G YZ
	;
T0	;Aanmaken standaard tab;
T1	;Usertab ";Standaardtab ";" bestaat niet.;
T2	;Standaardtab ";" kon niet worden ;aangemaakt.;gewijzigd.;
T3	;Standaardkolom ";" kon niet worden ;aangemaakt.;gewijzigd.;
T4	;Omschrijving ;Nederlands;Engels;Frans;Duits;
T5	;Aanmaken ;Wijzigen ;standaardtab ;op basis van usertab ;
T6	;Standaardtab ; aangemaakt.; gewijzigd.;Kolommen ; succesvol;
	;
MKSTAND(GRID,INI,TABNR,OVERWR)	; Standaard tab maken van een doorgegeven usertab
	; Input: GRID: naam grid van de te kopiëren user-tab(s)
	; 	INI: initialen te kopiëren user-tab(s)
	; 	TABNR: nummer van de te kopiëren user-tab
	; 	OVERWR: "": Usertab wordt volgende standaardtab
	; 		1: Usertab overschrijft de originele tab
	S $ZT="TRAP^cAN000"
	N OK,USERTAB,UI1TAB,TAB,i,K,VP
	S OK=1,K=""
	;
	D P^cA612(2,1,20,80,1,0,0,0,$P($T(@("T0"_QT)),U,2),0,0,7,1,1)
	;
MKSTAND1	; Doorgegeven parameters checken: bestaat de usertab?
	S USERTAB=$G(GRID)_" "_$G(INI)_" "_$G(TABNR)	
	I '$D(^VBN(0,"USER.GRID.TAB",USERTAB)) S K=$P($T(@("T1"_QT)),U,2)_USERTAB_$P($T(@("T1"_QT)),U,4) D F1 G MKSTANDY
	;
	;
MKSTAND2	; Volgende standaardtab bepalen
	S ORITAB=$$DATA^cAFVBO01("VBN",0,"USER.GRID.TAB",USERTAB,111)	; Originele tab
	S STTABNR=$O(^VBN(0,"GRID.TAB",GRID_"   ~"),-1)
	S STTABNR=$P(STTABNR," ",4)
	I $G(OVERWR) S UI1TAB=ORITAB G MKSTAND3
	S STTABNR=STTABNR+1
	S UI1TAB=GRID_"   "_STTABNR
	;
MKSTAND3	; Standaardtab aanmaken
	W /CUP(2,3),$P($T(@("T5"_QT)),U,2+$G(OVERWR)),$P($T(@("T5"_QT)),U,4),/CUP(2,25),UI1TAB
	W /CUP(3,3),$P($T(@("T5"_QT)),U,5),/CUP(3,25),USERTAB
	;
	K TAB,WTAB
	S UTAB(1)=^VBN(0,"USER.GRID.TAB",USERTAB,0)
	S TAB(1)=^VBN(0,"GRID.TAB",ORITAB,0),TAB(2)=^(1)
	S $P(TAB(1),D,3)=STTABNR			; Tabnummer
	S $P(TAB(1),D,9)=$P(UTAB(1),D,9)		; Data-level
	S $P(TAB(1),D,10)=STTABNR			; Positie
	F i=28:1:30 S $P(TAB(1),D,i)=""		; Tool-velden
	;
	S (CAPTIONE,CAPTIOND,CAPTIONF,CAPTIONG)=""
	;
OM1	; Omschrijving Engels
	S CAPTIONE=$P(UTAB(1),D,5)
	S R="CAPTIONE\22\3\"_$P($T(@("T4"_QT)),U,2)_$P($T(@("T4"_QT)),U,4)_"\\30\\$L(K)\\\\\1" D R0 G:K="-" MKSTANDY 
	W /CUP(5,3),$P($T(@("T4"_QT)),U,2)_$P($T(@("T4"_QT)),U,4)_":",/CUP(5,30),CAPTIONE
	;
OM2	; Omschrijving Nederlands
	S CAPTIOND=$P(UTAB(1),D,6)
	S R="CAPTIOND\22\3\"_$P($T(@("T4"_QT)),U,2)_$P($T(@("T4"_QT)),U,3)_"\\30\\$L(K)\\\\\1" D R0 G:K="-" OM1
	W /CUP(6,3),$P($T(@("T4"_QT)),U,2)_$P($T(@("T4"_QT)),U,3)_":",/CUP(6,30),CAPTIOND
	;
OM3	; Omschrijving Frans
	S CAPTIONF=$P(UTAB(1),D,7)
	S R="CAPTIONF\22\3\"_$P($T(@("T4"_QT)),U,2)_$P($T(@("T4"_QT)),U,5)_"\\30\\$L(K)\\\\\1" D R0 G:K="-" OM2
	W /CUP(7,3),$P($T(@("T4"_QT)),U,2)_$P($T(@("T4"_QT)),U,5)_":",/CUP(7,30),CAPTIONF
	;
OM4	; Omschrijving Duits
	S CAPTIONG=$P(UTAB(1),D,8)
	S R="CAPTIONG\22\3\"_$P($T(@("T4"_QT)),U,2)_$P($T(@("T4"_QT)),U,6)_"\\30\\$L(K)\\\\\1" D R0 G:K="-" OM3
	W /CUP(8,3),$P($T(@("T4"_QT)),U,2)_$P($T(@("T4"_QT)),U,6)_":",/CUP(8,30),CAPTIONG
	;
	S $P(TAB(1),D,5)=CAPTIONE
	S $P(TAB(1),D,6)=CAPTIOND
	S $P(TAB(1),D,7)=CAPTIONF
	S $P(TAB(1),D,8)=CAPTIONG
	;	
	; Tab openen	
	I '$G(OVERWR) D P^cAN220("GRIDN.TAB","VB",UI1TAB,"TAB","") 
	; Tab wijzigen
	I $G(OVERWR) D 
	. F i=5:1:9 S WTAB(i+100)=$P(TAB(1),D,i)
	. D B^cAN220("GRIDN.TAB","VB",UI1TAB,"WTAB")
	;
	I $L(K) S K=$P($T(@("T2"_QT)),U,2)_UI1TAB_$P($T(@("T2"_QT)),U,3)_$P($T(@("T2"_QT)),U,4+$G(OVERWR)) D F1 G MKSTANDY
	W /CUP(10,3),$P($T(@("T6"_QT)),U,2)_UI1TAB_$P($T(@("T6"_QT)),U,3+$G(OVERWR))
	;
MKSTAND4	; Standaardkolommen aanmaken
	W /CUP(12,3),$P($T(@("T6"_QT)),U,5),"  "
	K VP
	S COLUI1=ORITAB_" " F  S COLUI1=$O(^VBN(0,"GRID.TAB.COL",COLUI1)) Q:$P(COLUI1," ",1,4)'=ORITAB  D  G:'OK MKSTANDY
	. K UCOL,COL,WCOL
	. S COL(1)=^(COLUI1,0),COL(2)=^(1),COL(3)=^(2)
	. S UCOL(1)=^VBN(0,"USER.GRID.TAB.COL",USERTAB_" "_$P(COL(1),D,4),0)
	. S $P(COL(1),D,3)=STTABNR					; Tabnummer
	. F i=11,12,14,15,17,18 S $P(COL(1),D,i)=$P(UCOL(1),D,i)	; Specifieke rubrieken overnemen
	. I $P(UCOL(1),D,38)=1,'$P(UCOL(1),D,15) S $P(COL(2),D,2)=0	; Indien beheerbaar en op niet zichtbaar gezet: niet in select
	. S UI1COL=COLUI1,$P(UI1COL," ",4)=$P(UI1TAB," ",4)
	. ; Kolom openen
	. I '$G(OVERWR) D P^cAN220("GRIDN.TAB.COL","VB",UI1COL,"COL","") S VP($P(UCOL(1),D,11))=UI1COL
	. ; Kolom wijzigen
	. I $G(OVERWR) D 
	.. F i=11,12,14,15,17,18 S WCOL(i+100)=$P(COL(1),D,i)
	.. D B^cAN220("GRIDN.TAB.COL","VB",UI1COL,"WCOL") 
	. I $L(K) S K=$P($T(@("T3"_QT)),U,2)_UI1COL_$P($T(@("T3"_QT)),U,3)_$P($T(@("T3"_QT)),U,4+$G(OVERWR)) D F1 S OK=0 Q
	. W $P(UI1COL," ",5)_"  "
	W $P($T(@("T6"_QT)),U,3+$G(OVERWR))
	;
	; Visuele posities juist zetten
	I '$G(OVERWR) D
	. S i="" F  S i=$O(VP(i)) Q:'$L(i)  D
	.. S UI1COL=VP(i)
	.. D W^cAN220("GRIDN.TAB.COL","VB",UI1COL,111,i)
	;
	S K=$P($T(@("T6"_QT)),U,2)_UI1TAB_$P($T(@("T6"_QT)),U,6)_$P($T(@("T6"_QT)),U,3+$G(OVERWR)) D F1
	;
MKSTANDY	D C^cA612 
	;
MKSTANDZ	Q 
	;
YZ	Q
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
	;
F1	S R=250
F2	D TXT^cAFA1(R)
FZ	K R Q
	;
ZZ	; 29.08.07 - 10 u 22 * V8.09