cABVBP1	;Functies End Definition ; cABVBP1
	;
T1	;Initieel opzetten;Aanpassen;Aanpassen + verwijderen
T2	;Klasse aanmaken; en compileren
T3	;DMA aanmaken;DMA aanpassen
T4	;Niet controleren;Uitlijsten;Aanpassen
T5	;Grids en forms: verschillen ;uitlijsten;aanpassen
T6	;Klasse;Groep;Interne naam;
T8	;Taal;
T10	;Klasse is verwijderd;
T11	;Enkel intern;Enkel extern;Intern + extern
	;
T1E	;First time;Modify;Modify + delete
T2E	;Creating class; and compiling
T3E	;Creating DMA;Modifying DMA
T4E	;Don't check;List out;Modify
T5E	;Grids and forms: changes ;list out;modify
T6E	;Class;Group;Internal name;
T8E	;Language;
T10E	;Class has been deleted;
T11E	;Intern only;Extern only;Intern + extern
	;
YZ	Q
	;
	;DP.Taal : mtemp opbouwen
BTEMP(GRIDID,DPID)	
	; GRIDID: volgnr van de grid : indien '' : volgnummer ophalen
	; DPID : intern nr van ^DDP(0,"KLASSE" waaruit data moet opgehaald worden
	S $ZT="ERR^cAFVBF01"
	N @$$INITVAR^cAFVBA01("GRIDID,DPID")	
	;
	F i="GRIDID","DPID" S @i=$G(@i)
	I '$L(GRIDID) S GRIDID=$$GRIDID^cAFVBF01()
	K ^mtemp99(GRIDID,"COMMON") S OK=GRIDID
	;
	D DMS^cAN000("UQC","USC","DP.TAAL",1) I '$L(UQC)!'$L(USC) G BTEMPZ
	S UREF=^DMC(UQC,USC,"DATA","REF")
	S TKI1=""
	F  S TKI1=$O(^DTEXT(0,"TEXT.9000",TKI1)) Q:TKI1=""  D     ; aflopen taalcodes
	. S TKB=^(TKI1,0)
	. I $P(TKB,D,30) Q  ; BG of verwijderd
	. S TK=TKI1 ;$P(TKB,D)
	. S UI1=DPID_" "_TK
	. S B(1)=$G(@UREF@(0))
	. S B=$S($L(B(1)):UI1,1:"")_D_TK    ; key (ingevuld als rec. bestaat)_D_taalcode
	. S $P(B,D,3)=$P(B(1),D,3) 	      ; Groep
	. S $P(B,D,4)=$P(B(1),D,4)    	      ; Externe naam
	. S $P(B,D,5)=$P(B(1),D,5)    	      ; Omschrijving 
	. S $P(B,D,6)=$P(B(1),D,6)    	      ; SQLTabel
	. S UI1T=$P(B,D) I '$L(UI1T) S UI1T=" "_TK
	. S ^mtemp99(GRIDID,"COMMON",UI1T,0)=B
BTEMPZ	Q OK
	;	;
HDRDP(NR,GROEP,INTNAAM)	; header End definition: Class
	N HNR,HGROEP,HINTNAAM
	S $ZT="^dmERROR"
	S U=";"
	D QT^cAFVBO01
	I '$L(NR),('$L(GROEP)),('$L(INTNAAM)) D  G HDRDPA
	. S HNR=..DPId,HINTNAAM=..B101
	. S HGROEP="" I $L(..B103) S HGROEP=..B103.B101
	S HNR=NR,HGROEP=GROEP,HINTNAAM=INTNAAM
HDRDPA	S OUT="\\\"_$P($T(@("T6"_QT)),U,2)_";"_HNR_" "_HGROEP_" "_HINTNAAM_"; \\\"
HDRDPZ	Q OUT
	;
HDRDPL()	; header End definition Class-DefPerTaal-logging
	N OUT
	S $ZT="^dmERROR"
	S OUT=$$HDRDP(..B101.DPId,..B101.B103,..B101.B101)
	S OUT=OUT_"\"_$P($T(@("T8"_QT)),";",2)_";"
	X "S R=..B102."_$P("OmschrijvingNederlands#OmschrijvingFrans#OmschrijvingEngels#OmschrijvingDuits","#",QTU)
	S OUT=OUT_R_";"
HDRDPLZ 	Q OUT
	;
BTEMPSEL(GRIDID,DPIDS)	
	; Input: GRIDID
	; 	DPIDS: Geselecteerde klasseids gescheiden door "\"
	S $ZT="ERR^cAFVBF01"
	N @$$INITVAR^cAFVBA01("GRIDID,DPIDS")
	D QT^cAFVBO01
	;
	F i="GRIDID","DPIDS" S @i=$G(@i)
	I '$L(GRIDID) S GRIDID=$$GRIDID^cAFVBF01()
	K ^mtemp99(GRIDID,"COMMON") S OK=GRIDID
	;
	D DMS^cAN000("UQC","USC","DP",1) I '$L(UQC)!'$L(USC) G BTEMPSELZ
	S UREF=^DMC(UQC,USC,"DATA","REF")
	;
	F PC=1:1:$L(DPIDS,D) D
	. S UI1=$P(DPIDS,D,PC) I '$L(UI1) Q
	. S N=$G(@UREF@(0)) I '$L(N) Q
	. I $P(N,D,30)=2 Q
	. S $P(N,D,3)=$$DATA^cAFVBO01("DKODE",0,"CODE.9022",$P(N,D,3),101) ;Klassegroep
	. S ^mtemp99(GRIDID,"COMMON",UI1,0)=$P(N,D,1,3)
	. S ^mtemp99(GRIDID,"COMMON",UI1,1)=0 ; Record al verwerkt (=nee)
	. S $P(^mtemp99(GRIDID,"COMMON",UI1,0),D,5)=$$BG^cAFVBO01(0,QT)
	;
BTEMPSELZ	Q OK
	;
BUILD(GRIDID,QQ,SWKLA,SWKLC,SWDMA,DMATYPE,UQA,USA,SWUPD,TAAL)	
	; Input: GRIDID: Gridid van de geselecteerde klassen
	; 	QQ: Q-waarde
	; 	SWKLA: Klasse aanmaken? 1=ja,0=neen
	; 	SWKLC: Klasse compileren? 1=ja,0=neen
	; 	SWDMA: DMA aanmaken? 1=ja,0=neen
	; 	DMATYPE: Hoe DMA aanmaken (0,1 of 2)
	; 	UQA: Specifieke UQA
	; 	USA: Specifieke USA
	; 	SWUPD: Update grids en forms 0=neen,1=test,2=ja
	; 	TAAL : zie beschrijving in BUILD^cABVBP3
	; 	
	S $ZT="^dmERROR"
	N @$$INITVAR^cAFVBA01("GRIDID,QQ,SWKLA,SWKLC,SWDMA,DMATYPE,UQA,USA,SWUPD,TAAL")
	D QT^cAFVBO01
	;
	S OK=1
	F i="GRIDID","QQ","SWKLA","SWKLC","SWDMA","DMATYPE","UQA","USA","SWUPD" S @i=$G(@i)
	I '$L(GRIDID) G BUILDZ
	;
	D DMS^cAN000("UQC","USC","DP",1) I '$L(UQC)!'$L(USC) G BUILDZ
	S UREF=^DMC(UQC,USC,"DATA","REF")
	S MTEMP="^mtemp99(GRIDID,""COMMON"",DPID)"
	;
	S DPID="" F  S DPID=$O(^mtemp99(GRIDID,"COMMON",DPID)) Q:'$L(DPID)  D
	. I $G(^(DPID,1)) Q          ; Record is reeds verwerkt
	. S UI1=DPID,N=$G(@UREF@(0)) 
	. I ('$L(N))!$P(N,D,30)=2 S $P(@MTEMP@(0),D,4)=$P($T(@("T10"_QT)),U,2),OK=0 Q ; Record is verwijderd
	. ; KLasse aanmaken en compileren
	. I SWKLA D  I 'OK Q 
	.. S MSG=$P($T(@("T2"_QT)),U,2) I SWKLC S MSG=MSG_$P($T(@("T2"_QT)),U,3)
	.. W !,MSG 
	.. S RES=$$BUILD^cABVBP3(QQ,DPID,SWKLC,$G(TAAL))
	.. I 'RES S $P(@MTEMP@(0),D,4)=$P(RES,D,2),OK=0
	. ; DMA opzetten
	. I SWDMA D  I 'OK Q
	.. S MSG=$P($T(@("T3"_QT)),U,2) I DMATYPE S MSG=$P($T(@("T3"_QT)),U,3)
	.. W !,MSG 
	.. S RES=$$BUILD^cABVBP4(QQ,DPID,DMATYPE,UQA,USA)
	.. I 'RES S $P(@MTEMP@(0),D,4)=$P(RES,D,2),OK=0
	. ; Update grids en forms
	. I SWUPD D  I 'OK Q
	.. S MSG=$P($T(@("T5"_QT)),U,2)_$P($T(@("T5"_QT)),U,2+SWUPD)
	.. W !,MSG 
	.. S RES=$$DDP^cABVBP5(DPID,$S(SWUPD=1:1,1:""))
	.. I 'RES S $P(@MTEMP@(0),D,4)=$P(RES,D,2),OK=0
	. S $P(@MTEMP@(1),D)=1,$P(@MTEMP@(0),D,5)=$$BG^cAFVBO01(1,QT) ; Record aanduiden als verwerkt
	. S $P(@MTEMP@(0),D,4)="" ; Eventuele vorige fout verwijderen
	;
BUILDZ	Q OK
	;
	;Verschillende mogelijkheden voor een combobbox teruggeven
COMBO(TYPE)	
	; TYPE: "" of 0: type DMA
	;       1: Verschillen
	;       2: Type klasse
	S $ZT="^dmERROR"
	N R,U,D,NR
	S U=";",D="\"
	D QT^cAFVBO01
	;
	S NR=1
	I $G(TYPE)=1 S NR=4
	I $G(TYPE)=2 S NR=11
	S R=$TR($P($T(@("T"_NR_QT)),U,2,99),U,D)
	;
COMBOZ	Q R
	;
OMS(ID,QTD,DCSW)	; Omschrijvingen
OMSZ	Q $$DATA^cAFVBO01($S($G(DCSW):"DDC",1:"DDP"),0,"KLASSE.TAAL",$G(ID)_" "_$S($L($G(QTD,"E")):$G(QTD,"E"),1:"N"),104)
	;
UPDI	F I1="DP","DP.TAAL","DP.PROP","DP.PROP.TAAL","DP.IND","DP.METH","DP.APPL","DP.APPL.TAAL" D S1^cAN002(0,I1,24)
UPDIZ	Q
	;
ZZ	; 29.08.07 - 10 u 22 * V8.09