cAFVBA03	; algemene functies VB ;cAFVBA03
	;
YZ	Q
	;
DATACB(CLASS,B1,B2,QTD,QVAL)	; ophalen data combobox
	S $ZT="^dmERROR"
	N QT,QTU,OUT,PB1,PB2
	S OUT=""
	I '$L($TR(B1,"#")) G DATACBZ  ; er moet minstens een zoeksleutel 1 zijn
	S QT=QTD
	D QT^cAFVBO01
	S PB1=$P(B1,"#",QTU) S:'$L(PB1) PB1=$P(B1,"#")
	S PB2=$P(B2,"#",QTU) S:'$L(PB2) PB2=$P(B2,"#") 
	S OUT="Select ID, "_PB1
	I $L(PB2) S OUT=OUT_", "_PB2
	S OUT=OUT_" FROM "_$$TABLE^dmSQL(CLASS)_" T1"
	S OUT=OUT_" WHERE T1.LevelUsage=0"
DATACBZ	Q OUT
	;
Q49(Q,DMS,SQLPROP)	; bepalen Q-waarde en filter van een bestand binnen entiteit QENT
	N D,U,R
	S D="\",U=";",R=""
	S R=$$DMQ49^cAFA10($G(Q),$G(DMS)) I '$L(R) G Q49Z
Q49A	I $P(R,D)?1A.A S R=$P(R,D) G Q49Y       ; vaste Q-waarde
	I $P(R,D) S R=Q G Q49Y                  ; Q-waarde
	S R=""                                  ; geen Q49
Q49Y	I $L(R),$L($G(SQLPROP)) S R=R_D_"(%ALPHAUP(T1."_SQLPROP_") = %ALPHAUP('"_R_"'))"
Q49Z	Q R
	;
DMQ49(CLASS)	;  Staat Q49-parameter op bij de doorgegeven klasse?
	S $ZT="^dmERROR"
	N OK,dmQ49
	I '$L($G(CLASS)) G DMQ49Z
	;	
	s dmQ49=##class(%Dictionary.CompiledParameter).%OpenId(CLASS_"||dmQ49",0)
	I $L(dmQ49) S OK=dmQ49.Default D dmQ49.%Close() S dmQ49=""
	;
DMQ49Z	Q +$G(OK)
	;
SAVE(TXT)	; saven van een object
	S $zt="^dmERROR"
	N sc,OK,err
	S OK=1 
	S sc=..%Save()
	I 'sc S OK=$$ERR^cABVBP3(sc,$G(TXT))
SAVEZ	Q OK
	;
ZZ	; 29.08.07 - 10 u 22 * V8.09