cAN227	;Codebestanden ;%AN227 ; [ 11/13/01  2:29 PM ]
	G YZ
	;
T0	;Codebestanden ;
T1	;U kan maximaal ; bestanden definiëren ;
T2	;Beheer codebestanden;
T3	;Controlelijst codebestanden;
T4	;Vrije velden codebestanden;
	;
T0F	;Fichiers-codes ;
T1F	;Vous ne pouvez définier que 99 fichiers ;
T2F	;Gestion des codes;
T3F	;Liste de contrôle des codes;
T4F	;Champs libres des codes;
	;
T0E	;Codefiles;
T1E	;You can only define up to 99 files ;
T2E	;Administration codefiles;
T3E	;Checklist codefiles;
T4E	;Free fields codefiles;
	;
	; oproepen synoniemen vanuit vrije velden
SYN(DMS)	S K=$$^cANSYN(DMS,"",K,$$SIG^cAFA1("CODE.VV",$P(DMS,".",2),105))
SYNZ	Q
	;
MAX	S K=$P($T(T1),U,2)_((BEHEER*1000)+999)_$P($T(T1),U,3) D:'$G(SWVB) TXT^cAFA1(250)
MAXZ	Q
	;
	; Stap 1: controle op nummer bestand
STAP1	S $P(B(1),D)=UI1,OK=2
	I UI1>((BEHEER*1000)+999) D MAX S OK=0 G YZ
	G YZ
	;
	; Stap 2: kopiëren standaard definitie + éénmalige wijzigingen + Stap 3
STAP2	M ^DMA(0,"CODE."_UI1)=^DMA(0,"CODE.0")
	S ^DMA(0,"CODE."_UI1,0,"DMS")="CODE."_UI1
	;
	M ^DMC(0,"CODE."_UI1)=^DMC(0,"CODE.0")
	S I=^DMC(0,"CODE."_UI1,"DATA","INDEX")  D VERVANG S ^("INDEX")=I
	S I=^DMC(0,"CODE."_UI1,"DATA","INDEX2") D VERVANG S ^("INDEX2")=I
	S I=^DMC(0,"CODE."_UI1,"DATA","REF")    D VERVANG S ^("REF")=I
	S I=^DMC(0,"CODE."_UI1,"DIN")           D VERVANG S ^("DIN")=I
	S I=^DMC(0,"CODE."_UI1,"LOGGING")       D VERVANG S ^("LOGGING")=I
	S I=^DMC(0,"CODE."_UI1,"LOGGING","TOP") D VERVANG S ^("TOP")=I
	S I=^DMC(0,"CODE."_UI1,"SYN",0,0,2,0)   D VERVANG S ^(0)=I
	;
	M ^DMS(0,"CODE."_UI1)=^DMS(0,"CODE.0")
	S $P(^DMS(0,"CODE."_UI1),D,2)="CODE."_UI1
	S $P(^DMS(0,"CODE."_UI1,0),D,4)="CODE."_UI1
	S $P(^DMS(0,"CODE."_UI1,"DMA","O"),D,2)="CODE."_UI1
	S $P(^DMS(0,"CODE."_UI1,"DMA","W"),D,2)="CODE."_UI1
	S $P(^DMS(0,"CODE."_UI1,"DMA","L"),D,2)="CODE."_UI1
	;
	S ^DMQ(0,"CODE."_UI1,0)=0
	;
	G STAP3
	;
	; Stap 3: wijzigingen overnemen uit definitie
STAP3	S ^DMA(0,"CODE."_UI1,1,1,9)=$P(B(1),D,3)          ; code
	S ^DMA(0,"CODE."_UI1,1,1,11)="$L(K)"_$S($P(B(1),D,6):"&$$UNIEK^cAFA1(""CODE."_UI1_""",101,K)",1:"")
	S ^DMA(0,"CODE."_UI1,1,2,9)=$P(B(1),D,4)          ; omschrijving
	S ^DMA(0,"CODE."_UI1,1,3,9)=$P(B(1),D,4)
	S ^DMA(0,"CODE."_UI1,1,4,9)=$P(B(1),D,4)
	S ^DMA(0,"CODE."_UI1,1,5,9)=$P(B(1),D,4)
	;
	S $P(^DMC(0,"CODE."_UI1,"TAAL","N"),D,2)=$$LC^cAFA1($P(B(1),D,2))
	S $P(^DMC(0,"CODE."_UI1,"TAAL","F"),D,2)=$$LC^cAFA1($P(B(1),D,12))
	S $P(^DMC(0,"CODE."_UI1,"TAAL","D"),D,2)=$$LC^cAFA1($P(B(1),D,22))
	S $P(^DMC(0,"CODE."_UI1,"TAAL","E"),D,2)=$$LC^cAFA1($P(B(1),D,32))
	;
	S $P(^DMS(0,"CODE."_UI1,0),D)=$$OMS^cAFA1("CODE."_UI1,"N",2,1)
	S $P(^DMS(0,"CODE."_UI1,0),D,11)=$$OMS^cAFA1("CODE."_UI1,"F",2,1)
	S $P(^DMS(0,"CODE."_UI1,0),D,21)=$$OMS^cAFA1("CODE."_UI1,"D",2,1)
	S $P(^DMS(0,"CODE."_UI1,0),D,31)=$$OMS^cAFA1("CODE."_UI1,"E",2,1)
	D
	. N Q S Q=0 D S1^cAN002("DAM","DMS",0,0)          ; controle indexen
	;
	G YZ
	;
	; Definiëren vanuit 7.11.1
D	S BEHEER=1
	S FILTER="I $P($G(^DKODE(0,""CODE.VV"",UI1,0)),D,7)=1"
	D W^cAN200("CODE.VV","","","","S UI1=$$^cANSYN(""CODE.VV"","""","""","""","""","""",FILTER)")
	G YZ
	;
	; Definiëren vanuit ^cABI1
DDATAM	S BEHEER=$$BEHEER()
	D W^cAN200("CODE.VV","","","")
	G YZ
	;
NR(SRT,BEHEER,SWVB)	; ophalen volgende vrij nummer
	N D,U
	S D="\",U=";"
	S R=$G(^DIN(0,SRT_".VV",BEHEER)) 
	I R<(BEHEER*1000) S R=BEHEER*1000
	I R>((BEHEER*1000)+999) D MAX^cAN227 S R="-" S:$G(SWVB) R=0_D_K                                              
NRZ	Q R
	;
BEHEER()	Q $S($ZU(5)="PETC1":9,1:2)
	;
	; Beheer
W	D P^cA612(2,1,20,80,1,0,0,0,$P($T(@("T2"_QT)),U,2),0,0,7,1,1)
	S K=$$^cANSYN("CODE.VV")
	I K D W^cAN200("CODE."_K,"","","")
	G Y
	;
	; Controlelijst
L	D P^cA612(2,1,20,80,1,0,0,0,$P($T(@("T3"_QT)),U,2),0,0,7,1,1)
	S K=$$^cANSYN("CODE.VV")
	I K D L^cAN200("CODE."_K,"","","")
	G Y
	;
	; Vrije velden
VV	D P^cA612(2,1,20,80,1,0,0,0,$P($T(@("T4"_QT)),U,2),0,0,7,1,1)
	S K=$$^cANSYN("CODE.VV")
	I K D ^cAN222("CODE."_K,"","")
	G Y
	;
Y	D C^cA612
YZ	Q
	;
VERVANG	I I["CODE.0" S I=$P(I,"CODE.0")_"CODE."_UI1_$P(I,"CODE.0",2,99) G VERVANG
	Q
	;
ZZ	; 19.03.07 - 15 u 31 * V8.08