cI98	;Conversie veld 'Rappel' bij de klanten; cI98
	;
T0	;Conversie veld 'Rappel';
T1	;Klanten voor Q-waarde ; zijn in gebruik;
	;
YZ	Q
	;
DMA	N I1,I2,I3
	S $ZT="TRAP^cAN000"
	; Converteren veld 'Rappel' in ^DMA
	S I1=""
	F  S I1=$O(^DMA(I1)) Q:I1=""  D
	. I '$D(^DMA(I1,"KL")) Q
	. ; Opzetten veld 'Datum rappel'
	. S ^DMA(I1,"KL",2,99,1)="Datum herinnering\Date rappel\Datum rappel\Date reminder"
	. S ^DMA(I1,"KL",2,99,2)=3
	. S ^DMA(I1,"KL",2,99,3)=41
	. S ^DMA(I1,"KL",2,99,6)=62
	. S ^DMA(I1,"KL",2,99,9)=8
	. S ^DMA(I1,"KL",2,99,13)=8
	. S ^DMA(I1,"KL",2,99,15)="'$G(EXTWIJZ)"
	. S ^DMA(I1,"KL",2,99,16)=317
	. S ^DMA(I1,"KL",2,99,19)="S K=$S(RK=31:""-"",1:"""")"
	. S ^DMA(I1,"KL",2,99,22)=0
	. S ^DMA(I1,"KL",2,99,23)=0
	. ; Opzoeken veld 'Rappel'
	. S I2=0
	. F  S I2=$O(^DMA(I1,"KL",I2)) Q:I2=""  D
	.. S I3=0
	.. F  S I3=$O(^DMA(I1,"KL",I2,I3)) Q:I3=""  D
	... I $G(^DMA(I1,"KL",I2,I3,16))'=110 Q
	... S ^DMA(I1,"KL",I2,I3,8)="S U3=$$JN^cAFO1(K)"
	... S ^DMA(I1,"KL",I2,I3,10)="[] = neen   1[] = ja\[] = non   1[] = oui\[] = nein   1[] = ja\[] = no   1[] = yes"
DMAZ	Q
	;
CONV	N Q,UQC,USC,UREF,I1,RAP,REF
	S $ZT="TRAP^cAN000"
	; Converteren veld 'Rappel bij de klant'
	S Q=0
	F  S Q=$O(^DMS(Q)) Q:(Q="")  D
	. I '$D(^DMS(Q,"KL")) Q
	. D DMS^cAN000("UQC","USC","KL")
	. S UREF=^DMC(UQC,USC,"DATA","REF")
	. S REF=$P(UREF,"(UI1")_""")"
	. L +@REF:2 E  W !,$P($T(@("T1"_QT)),U,2)_Q_" : "_REF_$P($T(@("T1"_QT)),U,3) Q
	. S UI1=0
	. F  S UI1=$O(@UREF) Q:UI1=""  D
	.. I $D(^TEMPC($T(+0),$NA(@UREF))) Q
	.. W !,$P(@UREF@(0),D,2)
	.. S RAP=$P(^(0),D,10)
	.. S RAP='RAP
	.. I RAP=0 S RAP=""
	.. D W^cAN220("KL","",UI1,110,RAP)
	.. I K="-" X "STOP"
	.. S ^TEMPC($T(+0),$NA(@UREF))=""
	. L -@REF
CONVZ	Q
	;
ZZ	; 24.02.06 -  9 u 54 * V8.06