cTN0092	;Controle BH: diverse checks ;cTN009 ; [ 12/10/01  5:49 PM ]
	;
T1	;Saldo (;) verschilt van totaal openstaande documenten (;
T2	;Openstaande documenten;Beginsaldi;Saldi via samengestelde cumul;
T3	;Som beginsaldi ; verschilt van ;
T4	;Saldo via gecombineerde cumul (;) verschilt van saldo rekening (;
T5	;Beginsaldo via gecombineerde cumul (;) verschilt van beginsaldo rekening (;
	;
T1F	;
	;
T1E	;
	;
YZ	Q
	;
	; 
DIV(VBM,TBM)	; Controle BH: diverse checks
	; Input: VBM: Van boekingsmaand
	;        TBM: Tot boekingsmaand
	;        
	S $ZT="TRAP^cAN000"
	N @$$INIT^cTN009("VBM,TBM")
	;
	; Controle parameters
DIV1	F i="VBM","TBM" S @i=$G(@i)
	I '$L(VBM) G DIVZ
	I '$L(TBM) S TBM=$$JBM^cTN003(.Q)
	;
	; Definities ophalen
DIV2	G:'$L(UREFDB) DIVZ G:'$L(IREFDB) DIVZ
	G:'$L(UREFREG) DIVZ G:'$L(IREFREG) DIVZ
	;
	; Totaal openstaand afchecken
DIV3	W !,!,$P($T(@("T2")),U,2),!
	S R=$$OPEN("KL.A")
	S R=$$OPEN("LE.A")
	;
	; Beginsaldi
DIV4	W !,!,$P($T(@("T2")),U,3),!
	S BBJ=$$BJ^cTN003(.Q,VBM)
	S EBJ=$$BJ^cTN003(.Q,TBM)
	F JR=BBJ:1:EBJ W JR_" " D BS(JR,"AR.A"),BS(JR,"KL.A"),BS(JR,"LE.A")
	;
	; Saldo grootboekrek. in evenwicht via gecombineerde cumuls
DIV5	W !,!,$P($T(@("T2")),U,4),!
	D SALAR(Q,VBM,TBM)
	;
DIVY	;
DIVZ	Q
	;
	;
SALAR(Q,VBM,TBM) ; Controle saldo AR.A via gecombineerde cumul
	; Input: Q:   Vennootschap
	;        VBM: Van boekingsmaand
	;        TBM: Tot boekingsmaand
	S $ZT="TRAP^cAN000"
	N @$$INIT^cTN009("VBM,TBM")
	;
	; Q(49) ophalen
SALAR1	D Q1^cAFA10("AR.A")
	;
	; Controle parameters + definities ophalen
SALAR2	S R=1 I '$L($G(VBM)) G SALARY
	I '$$PAR^cTN001(Q,501) G SALARY ; Geen analytische BH
	S REF=$$REF^cAFA10(.Q,"AR.A",101),UREF=$P(REF,D),IREF=$P(REF,D,3)
	I '$L(UREF)!'$L(IREF) G SALARY
	S STJR=$$PAR^cTN001(Q,515),STMT="" I $L(STJR) S STMT=$$BM^cTN003(Q,STJR)
	I $L(STMT),(VBM<STMT) S VBM=STMT
	S BBJ=$$BJ^cTN003(Q,VBM)
	S:'$L(TBM) TBM=$$JBM^cTN003(Q) S EBJ=$$BJ^cTN003(Q,TBM)
	;
	; Rekeningen doorlopen
SALAR3	S I1=""
SALAR31	S I1=$O(@IREF@(I1)),I2="" I '$L(I1) G SALARY
SALAR32	S I2=$O(@IREF@(I1,I2)) I '$L(I2) G SALAR31
	S UI1=$P(^(I2),D),BM=VBM-.01,JR=BBJ-1
	;
	; Maanden aflopen 
SALAR4	S BM=BM+.01  I $L($G(BM)),BM>TBM G SALAR5
	I $P(BM,".",2)>12 S BM=BM+.88
	S BM=$E(BM_"0",1,7)
	; Saldo's bepalen
	S SAL1=$$SALDO^cTN004(Q,UI1,BM,"AR.A",2) ; Saldo via CUM.AR
	S SAL2=$$SALDO^cTN004(Q,UI1,BM,"C2",2)	 ; Saldo via CUM
	; Resultaat verwerken
	I SAL1=SAL2 G SALAR49
	S ERR=$P($T(@("T4")),U,2)_SAL2_$P($T(@("T4")),U,3)_SAL1_"): "_(SAL2-SAL1)
	D ERR^cTN009("5",UI1,BM,"",ERR) S R=0
SALAR49	G SALAR4
	;
	; Jaren aflopen
SALAR5	S JR=JR+1 I JR>EBJ G SALAR9
	; Saldo's bepalen
	S SAL1=$$SALDO^cTN004(Q,UI1,JR,"AR.A",3) ; Beginsaldo via CUM.AR
	S SAL2=$$SALDO^cTN004(Q,UI1,JR,"C2",3)	 ; Beginsaldo via CUM
	; Resultaat verwerken
	I SAL1=SAL2 G SALAR7
	S ERR=$P($T(@("T5")),U,2)_SAL2_$P($T(@("T5")),U,3)_SAL1_"): "_(SAL2-SAL1)
	D ERR^cTN009("5",UI1,JR,"",ERR) S R=0
SALAR7	G SALAR5
	;
SALAR9	G SALAR32
	;
	; Oorspronkelijke Q(49) terugzetten
SALARY	D Q2^cAFA10
	;
SALARZ	Q R
	;
BS(BJR,TYPE)	; Controle op beginsaldi
	; Input: BJR: Boekjaar
	;        TYPE: Type rekening
	;              AR.A: Grootboekrekening
	;              KL.A: Klant
	;              LE.A: Leverancier
	S $ZT="TRAP^cAN000"
	N @$$INIT^cTN009("BJR,TYPE")
	;
	; Controle parameters
BS1	S R=1 I '$L($G(BJR))!'$L($G(TYPE)) G BSZ
	S DMS="BEG."_$P(TYPE,".")
	;
	; Definities
BS2	S UREF=$P($$REF^cAFA10(.Q,DMS),D)
	I '$L(UREF) G BSZ
	;
	; Totaal beginsaldi bepalen
BS3	S CHK=($$Q^cAFA10_" "_BJR),UI1=CHK_" ",TOT=0
BS31	S UI1=$O(@UREF) I $P(UI1," ",1,2)'=CHK G BS4
	S TOT=TOT+$P(^(UI1,0),D,3)
BS37	G BS31
	;
	; Correcte totaal bepalen
BS4	I TYPE="AR.A" S CHKTOT=0 G BS45
	I TYPE="KL.A" S CHKTOT=$$SALDO^cTN004(Q,$$SIG^cAFA1("Q",Q,401),BJR,"AR.A",5)  G BS45
	I TYPE="LE.A" S CHKTOT=$$SALDO^cTN004(Q,$$SIG^cAFA1("Q",Q,402),BJR,"AR.A",5) G BS45
	G BSZ
	;	
BS45	I TOT=CHKTOT G BSZ
	S ERR=$P($T(@("T3")),U,2)_"("_TOT_")"_$P($T(@("T3")),U,3)_CHKTOT_": "_(CHKTOT-TOT),R=0
	D ERR^cTN009("4",TYPE,BJR,"",ERR)
	;
BSZ	Q R
	;
OPEN(TYPE)	; Controle openstaande documenten <-> basisrekeningen KL/LE
	; Input: TYPE: KL.A = Klanten
	;              LE.A = Leveranciers
	;
	S $ZT="TRAP^cAN000"
	N @$$INIT^cTN009("TYPE")
	;
	; Baisrekeningen ophalen
OPEN1	W $G(TYPE)_" "
	S R=1,TYPE=$S($G(TYPE)="KL.A":1,$G(TYPE)="LE.A":2,1:"") I '$L(TYPE) G OPENZ
	S BREK=$$SIGN^cAFA1("Q",Q,3) ; Basisrekeningen
	S KZREK=$P(BREK,D,TYPE) ; Basisrekening KL/LE
	S S1=1 I TYPE=2 S S1=-1 ; Teken afhankelijk van KL/LE
	S QKZ=$$Q49^cAFVBA03(Q,"DB")
	;
	; Definities
OPEN2	G:'$L(UREFDB) OPENZ G:'$L(IREFDB) OPENZ
	;
	; Openstaand saldo bepalen
OPEN3	S (KZ,OKL)="",MULT="M"_(1+TYPE)
OPEN31	S KZ=$O(@IREFDB@(MULT,QKZ,KZ)),EDOC="" G:KZ=" " OPEN31 G:'$L(KZ) OPEN4
OPEN33	S EDOC=$O(@IREFDB@(MULT,QKZ,KZ,1,EDOC)),IDOC="" I '$L(EDOC) G OPEN31
OPEN35	S IDOC=$O(@IREFDB@(MULT,QKZ,KZ,1,EDOC,IDOC)) I '$L(IDOC) G OPEN33
	S UI1=$P(^(IDOC),D),N=@UREFDB@(0)
	S OKL=OKL+($P(N,D,18)*S1)
OPEN39	G OPEN35
	;
	; Openstaand saldo vergelijken met saldo grootboekrekening
OPEN4	S SKZ=$$SALDO^cTN004(Q,KZREK,,"AR.A",1)
	I +SKZ=+OKL G OPENZ
	S ERR=$P($T(@("T1")),U,2)_+SKZ_$P($T(@("T1")),U,3)_OKL_"): "_(SKZ-OKL)
	D ERR^cTN009("3","AR.A",KZREK,"",ERR)
	S R="0\"_ERR
	;
OPENZ	Q R
	;
ZZ	; 29.08.07 - 10 u 22 * V8.09