cTN8200	; BTW-codes; cTN8200;;     [ 19/11/09  17:32:45 ]
	;
T1	;Het koppelen van teksten is enkel mogelijk indien de BTW-code aangeduid is als: BTW niet aanrekenen EU, BTW niet aanrekenen andere of BTW-eenheid.;
	;
T1F	;La liaison de textes est seulement possible si le code TVA a été indiqué comme "TVA UE à ne pas calculer", "TVA autre à ne pas calculer" ou "Unité de TVA".;
	;
T1E	;Linking texts is only possible if the VAT-code is indicated as "EU VAT Not To Calculate", "VAT Other Not To Calculate" or "VAT Unit".;
	;
YZ	Q
	;
	;
CHKDEF(UI1,B)	; Controleren default bij BTW-type.
	; Input: UI1: intern nummer van de BTW-code
	; 
	; Output: 1
	;         0\Fout
	;
	; - Er kan maar één BTW-code per type, per land als default worden ingesteld. 
	;   Indien er al een andere BTW-code was ingesteld, default daar afgevinkt.
	; 
	; Controle + opzetten definitie's
CHKDEF1	S $ZT="TRAP^cAN000"
	N R,DMS,REF,IREF,UREF,DEFBTWA,DEFBTWNIC,DEFBTWN,LAND,I2,I3,TAB
	F i="UI1","B","DEFBTWA","DEFBTWNIC","DEFBTWN" S @i=$G(@i)
	S R=1,DMS="CODE.9011"
	I '$L(UI1) G CHKDEFZ
	S REF=$$REF^cAFA10(Q,DMS),IREF=$P(REF,D,3),UREF=$P(REF,D) I '$L(REF) G CHKDEFZ
	S UREF=$$REPL^cAFA10(UREF,"UI1","UI1CODE")
	;
CHKDEF15	S LAND=$P(B(1),D,3)                      ; Land van de BTW-code
	I $P(B(1),D,5) S DEFBTWA=1               ; BTW aanrekenen default aangevinkt
	I $P(B(1),D,7) S DEFBTWNIC=1             ; BTW niet aanrekenen IC default aangevinkt
	I $P(B(1),D,9) S DEFBTWN=1               ; BTW niet aanrekenen andere default aangevinkt
	;
	; Alle BTW-codes van het land doorlopen en controleren of er een default moet worden afgevinkt
CHKDEF2	S I2=""
CHKDEF21	S I2=$O(@IREF@("M1",LAND,I2)),I3="" I '$L(I2) G CHKDEFZ
CHKDEF22	S I3=$O(@IREF@("M1",LAND,I2,I3)) I '$L(I3) G CHKDEF21
	S UI1CODE=$P($G(^(I3)),D),NODE0=$G(@UREF@(0)) I '$L(UI1CODE) G CHKDEF22
	I UI1CODE=UI1 G CHKDEF22                  ; Indien het de doorgegeven BTW-code is, volgende controleren
	K TAB
	; Controleren 'BTW aanrekenen default'
CHKDEF23	I '+DEFBTWA G CHKDEF24
	I $P(NODE0,D,5) S TAB(105)=0              ; Indien default aangevinkt stond bij 'BTW aanrekenen default' nu afvinken
	;
	; Controleren 'BTW niet aanrekenen IC default'
CHKDEF24	I '+DEFBTWNIC G CHKDEF25
	I $P(NODE0,D,7) S TAB(107)=0              ; Indien default aangevinkt stond bij 'BTW niet aanrekenen IC default' nu afvinken
	;
	; Controleren 'BTW niet aanrekenen andere'
CHKDEF25	I '+DEFBTWN G CHKDEF28
	I $P(NODE0,D,9) S TAB(109)=0              ; Indien default aangevinkt stond bij 'BTW niet aanrekenen andere' nu afvinken	
	;
CHKDEF28	I $D(TAB) D B^cAN220(DMS,"",UI1CODE,"TAB") I K'="" X "STOP"
CHKDEF29	G CHKDEF22
	;
CHKDEFZ	Q R
	;
	;
CHKTEK(UI1,PAR)	; Controleren of teksten mogen gekoppeld worden aan doorgegeven BTW-code
	; Input: UI1: intern nummer van de BTW-code
	;        PAR: BTW niet aanrekenen IC\BTW niet aanrekenen andere\BTW-eenheid
	; 
	; Output: 1
	;         0\Fout
	;
	; Koppelen van teksten enkel mogelijk bij: BTW niet aanrekenen IC, BTW niet aanrekenen andere of BTW-eenheid.
	;
	; Controle + opzetten definitie's
CHKTEK1	S $ZT="TRAP^cAN000"
	N R
	F i="UI1","PAR" S @i=$G(@i)
	S R=0
	I '$L(UI1) G CHKTEKZ
	;
CHKTEK2	I $L(PAR) G CHKTEK3
	; Geen parameters doorgeven, dus opgestart via grid
	S NODE0=$$SIGN^cAFA1("CODE.9011",UI1,0)
	I $P(NODE0,D,6)!$P(NODE0,D,8)!$P(NODE0,D,10) S R=1
	G CHKTEKY
	;
	; Parameters doorgeven, dus opgestart via form
CHKTEK3	I PAR[1 S R=1
	G CHKTEKY
	;
CHKTEKY	I 'R S R=0_D_$P($T(@("T1"_QT)),U,2)
CHKTEKZ	Q R
	;
	;
NASAVE	; Uit te voeren vanuit DMA nadat er werd gesaved
	S $ZT="TRAP^cAN000"
	;
	; Indien er een default op staat bij de BTW-code
NASAVE1	I $P(B(1),D,5)!$P(B(1),D,7)!$P(B(1),D,9) D CHKDEF(UI1,.B)
	; 
NASAVEZ	Q
	;
	;
ZZ	; 05.11.09