cAB100	;Beheer ^DMA ;%AB10 ; [ 03/29/01  9:18 AM ]
	;
T1	;Nummer element;
T2	; [] = autom. nummer   .x[] = pagina x   P[] = beheer positionering;
T3	;B[] = buitenduwen      Y[] = kopiëren   V[] = verwijderen rubriek;
	;
	; Window & Titel
1	D O^cA612(2,1,20,80,0,0,0,0) ; algemene gegevens verbergen
11	I '$D(^DMA(UQA,USA,0,"WIN")) S ^("WIN")="2\1\20\80\1\1\1\1"
13	S I=$G(^("WIN")) F J=1:1:8 S $P(I,D,J)=+$P(I,D,J)
15	S ^("WIN")=I,J=I,UTIT=$G(^("TIT"))
17	S I=$NA(^DMA(UQA,USA),2)_" ["""_$ZU($ZV'["MSM"*5)_"""]"
19	D P^cA612($P(J,D),$P(J,D,2),$P(J,D,3),$P(J,D,4),$P(J,D,5),0,0,1,I,$P(UTIT,D,2),$P(UTIT,D,3),$P(UTIT,D,4),0,0)
	;
	; Pagina tonen
2	I SW4<1 S SW4=1
21	S SW5=1 K C D S1^cAN000(SW2)
23	S U1=0 F  S U1=$O(C(U1)) Q:U1=""  D S2^cAN000(U1),S3,S3^cAN000(K) I 'U2(22) W /CUP(U2(2),U2(6)),/SGR(1),U1,/SGR(0)
	;
	; Nummer element
3	S R="U1\22\3\"_$P($T(T1),U,2)_"\S1\3\\\\\1\\\1" D R0
31	I RK=25 S:SW2=1 K="-" S:SW2>1 (K,U1)="."_(SW2-1) G 37
33	I RK=26 S (K,U1)="."_(SW2+1) G 37
35	I RK'=28 G 3
37	G YZ:K="-"!(K=",")
	;
	; Welke module
4	I $E(K)="." S K=+$E(K,2,9) G 3:K-1>SW4!'K S SW2=K G 2   ; andere pagina
41	I K="B" D ^cAB105 G 2                                   ; buitenduwen
43	I K="Y" D ^cAB106 G 2                                   ; kopiëren
45	I K="V" D ^cAB104 G 2                                   ; verwijderen
47	I K="P" D ^cAB103 G 2                                   ; positionering
49	I K="" D ^cAB101 G 2                                    ; openen
	;
	; Wijzigen rubriek
5	S U1=+U1 I '$D(C(U1)) G 3
51	D M^cAN000(U1),^cAB102
53	I K'="V" F I=2:1:50 I $G(U2(I))="" K U2(I)
55	K ^DMA(UQA,USA,SW2,C(U1)) M ^DMA(UQA,USA,SW2,C(U1))=U2 G 2
	;
YZ	D C^cA612,C^cA612 G 6^cAB10
	;
	; commentaar
S1	W !?2,$P($T(T2),U,2),!?2,$P($T(T3),U,2)
S1Z	Q
	;
	; opzetten "data"
S3	S (K,U2(8))="" I U2(9) S $P(K,".",U2(9))="."
S3A	I U2(13)>U2(9) F  Q:$L(K)=U2(13)  S K=K_"*"
S3Z	Q
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
	;
ZZ	; 18.05.01 - 11 u 18 * V7.86