cQ13	;Functions ;cQ13;
	Q
	;
date	;date
	N %H,%J,%R S %H=1+$H,%J=%H\1461,%R=%H#1461,DJ=%J*4+1841+(%R\365),DD=%R#365,DM=1 I %R=1460 S DD=365,DJ=DJ-1
	F %J=31,(%R>1154)+28,31,30,31,30,31,31,30,31,30 Q:%J'<DD  S DM=DM+1,DD=DD-%J
	S:'DD DJ=DJ-1,DM=12,DD=31 S:DD<10 DD=0_DD S:DM<10 DM=0_DM S DT=DD_"."_DM_"."_$E(DJ,3,4)
datez	Q
time	;time
	N %J,%R S QT=$G(QT),%R=$P($H,",",2)\60,%J=%R\60
	S TD=$J(%J,2)_$P(" u ; h ; h ",";",$S(QT="F":2,QT="E":3,1:1))_(%R#60\10)_(%R#10)
timez	Q
doubleq(X)	;Double quotes in string
	N Y S Y=0 F  S Y=$F(X,"""",Y) Q:'Y  S X=$E(X,0,Y-1)_""""_$E(X,Y,$L(X)),Y=Y+1
doubleqz	K Y Q X
	;
SWNS	D SWNS^cQZSTART Q
	;
TL(R,S,L)	;GET first line of routine R in namespace S optional line L
	N I,K
	S R=$G(R),S=$G(S),QT=$G(QT),L=$G(L),K="Routine not found!"
	I $L(R) D
	. S SO=$ZU(5) S:$E(R)="%" S="" I $L(S) ZN S
	. I $D(^$|S|ROUTINE(R)) D
	.. S K="" S L=$P($TR(L,":()[]","|||||"),"|")
	.. I $L(L) X "ZL @R S K=$P($T("_L_"),"";"",2)" I $L(K)>5 Q
	.. X "ZL @R S K=$P($T(@(""T0""_QT)),"";"",2) S:$L(K)<5 K=$P($T(+1),"";"",2) S:$L(K)<5 K=$P($T(+1),"";"",3)"
	.. S:K["[" K=$P(K,"[") S K=$ZSTRIP(K,"<W")
	. I SO'=$ZU(5) ZN SO
TLZ	Q K
	;
CVER	K %v
	S %v(3)=($P($P($ZV,")",2),"(",1)[" 3."),%v(30)=($P($P($ZV,")",2),"(",1)[" 3.0"),%v(32)=($P($P($ZV,")",2),"(",1)[" 3.2")
	S %v(4)=($P($P($ZV,")",2),"(",1)[" 4."),%v(40)=($P($P($ZV,")",2),"(",1)[" 4.0"),%v(404)=($P($P($ZV,")",2),"(",1)[" 4.0.4")
	S %v(5)=($P($P($ZV,")",2),"(",1)[" 5."),%v(50)=($P($P($ZV,")",2),"(",1)[" 5.0"),%v(2008)=($P($P($ZV,")",2),"(",1)[" 2008")
	S %v(2010)=($P($P($ZV,")",2),"(",1)[" 2010")
CVERZ	Q
	;
WX	I $G(^cLOG($ZU(5),"ZWINTERM",0))=1 D W^cA612 Q   ; activeren ZWINTERM
	E  D X^cA612                                 ; activeren ANSI
WXZ	Q
	;
BX	I $G(^cLOG($ZU(5),"ZWINTERM",0))=1 D B^cA612 Q   ; starten ZWINTERM
	E  D X^cA612                                 ; activeren ANSI
BXZ	Q
	;
STUSSD(X)	;Add entry to ^cLOG(boot,"STUSSD")
	N LOG,Q,QU
	S Q("X")=$G(X,"???"),QU="SYS",$ZT="ERR^"_$T(+0) I '($D(Q)#10) D QQM^cQ6,MASTER^cQ5
	S X=Q("X"),LOG="^cLOG("""_$ZCVT($ZU(110),"U")_""",""STUSSD"")"
	D date,time,CLEAN(LOG,45)
	S @LOG@($P($H,","),$P($H,",",2))=X_"\"_DD_"."_DM_"."_DJ_"\"_TD_"\"_$H
	I X="STU",$D(^$ROUTINE("cANEM0")) D
	. N I,J,L
	. S (I,J)="",L=0
	. F  S I=$O(@LOG@(I),-1) Q:I=""!(L>2)  D
	.. F  S J=$O(@LOG@(I,J),-1) Q:J=""!(L>2)  D
	... S L=L+1 I L=2,$P(^(J),"\")=X D  D D1001^cANEM0($T(+0),"STUSSD")
	.... F K=0,"DAM" I '$D(^DMS(K,"ALERT")) S ^DMS(K,"ALERT")="0\ALERT",^DMS(K,"ALERT",0)="Alert-boodschappen\1\0\ALERT\1\\\\\\Alert-boodschappen\\\\\\\\\\\\\\\\\\\\Alert-boodschappen"
STUSSDZ	Q
	;
ADD(LOG,X)	;Add entry to logbook
	D date,time
	S ^cLOG($ZU(5),LOG,+$H,+$P($H,",",2))="0\"_DT_"\"_TD_"\"_$G(X),X=$ZR
	D CLEAN("^cLOG("""_$ZU(5)_""","""_LOG_""")",40)
ADDZ	Q X
	;
CLEAN(LOG,X)	;Clean-up entry in LOG
	N I,DAG,UUR S (DAG,UUR)="",X=$G(X,45)
	F I=2:1 S DAG=$O(@LOG@(DAG),-1) Q:(DAG="")!(DAG=0)  D
	. F I=I-1:1 S UUR=$O(@LOG@(DAG,UUR),-1) Q:UUR=""  I I>X K ^(UUR)
CLEANZ	Q
	;
LAST(LOG)	;Get last entry from LOG
	N I,J,K S K=""
	S I=$O(@LOG@(""),-1) I I'="" S J=$O(@LOG@(I,""),-1) I J'="" S K=@LOG@(I,J)
LASTZ	Q K
	;
ALLN(S)	;get all namespaces for same roepnaam into S
	K S N I,K,L,SYS
	D NSPC^cQ21(.SYS,1) S (K,L)=""
	F  S K=$O(SYS(K)) Q:K=""  D
	. I $ZSTRIP(K,">N")'=$ZSTRIP($ZU(5),">N") K SYS(K)
	. I $ZSTRIP(K,">N")=$ZSTRIP($ZU(5),">N") S L=L_$P(K,$ZSTRIP($ZU(5),">N"),2)_" "
	S:$E(L,$L(L))=" " $E(L,$L(L))=""
	F I=1:1:$L(L," ") S S($ZSTRIP($ZU(5),">N")_$P(L," ",I))=""
ALLNZ	Q L
	;
KBAT	;kill cmd that started cache
	N K,ER
	S K=$$KOSFI^cQ14_" cmd.exe",ER=$$JNW^cQFILE(K)
KBATZ	Q
	;
ERR	;U 0 W !,$ZE,!
ERRZ	ZQ
	;
YZ	Q
	;
ZZ	; 17.01.2012 - 15:58 * Cache-r6.4.9