cQCPF	;Manipulate cache.cpf ;cQCPF;
	Q
	;
date	;date
	N %H,%J,%R S %H=1+$H,%J=%H\1461,%R=%H#1461,DJ=%J*4+1841+(%R\365),DD=%R#365,DM=1 I %R=1460 S DD=365,DJ=DJ-1
	F %J=31,(%R>1154)+28,31,30,31,30,31,31,30,31,30 Q:%J'<DD  S DM=DM+1,DD=DD-%J
	S:'DD DJ=DJ-1,DM=12,DD=31 S:DD<10 DD=0_DD S:DM<10 DM=0_DM S DT=DD_"."_DM_"."_$E(DJ,3,4)
datez	Q
time	;time
	N %J,%R S QT=$G(QT),%R=$P($H,",",2)\60,%J=%R\60
	S TD=$J(%J,2)_$P(" u ; h ; h ",";",$S(QT="F":2,QT="E":3,1:1))_(%R#60\10)_(%R#10)
timez	Q
doubleq(X)	;Double quotes in string
	N Y S Y=0 F  S Y=$F(X,"""",Y) Q:'Y  S X=$E(X,0,Y-1)_""""_$E(X,Y,$L(X)),Y=Y+1
doubleqz	K Y Q X
	;
INIT	W !!,"Copy default Global Mapping into cache.cpf",!
	W !!,"Roepnaam: " R RPN I RPN="-" Q
	I '((RPN?.A)!(RPN?1"V".N)) W !!,"Roepnaam ongeldig" G INIT
	W !!,"Aantal firma's: " R ANTL I 'ANTL G INIT
	S LOC=$P($ZU(86),"\",1,2)_"\Database\"_RPN_"\"
	S LOC("R0")=LOC_"R\0\",LOC("G0")=LOC_"G\0\"
	F VNR=1:1:ANTL S LOC("G"_VNR)=LOC_"G\"_VNR_"\"
	D INITD
INITZ	Q
	;
INITD	;Do-it
	S RPN=$ZCONVERT(RPN,"U") F VNR=1:1:ANTL S K=RPN S:RPN'?1"V"3.N K=K_VNR S NMSP(VNR)=K,GLOM(VNR)=K
	I '$D(VER) S VER=$S(($P($P($ZV,")",2),"(",1)[" 3."):3,($P($P($ZV,")",2),"(",1)[" 4."):4,($P($P($ZV,")",2),"(",1)[" 5."):5,($P($P($ZV,")",2),"(",1)[" 2008"):8,($P($P($ZV,")",2),"(",1)[" 2010"):10,1:10)
	K ^TEMP($J) D TEMPI(CF),DATAF,DATAS,BUC(CF),TEMPO(CF)
INITDZ	Q
	;
ST	;Copy Standard cache.cpf file
	I '$D(SYSD) S SYSD=$E($ZU(86))
	S ROUT="cQCPF"_$S(VER=3:1,VER=4:2,VER=5:3,VER=8:4,VER=10:5,1:5) K ^TEMP($J,"new")
	F J=0:1 S K=$T(1+J^@ROUT) S K=$P(K,";",2,$L(K,";")) Q:K="END"  D
	. I RPN'="USER",K["DefLoginNSP" S K="DefLoginNSP="_$ZCONVERT(RPN,"U")_"1"
	. I K["wijdir" S K=$P(K,"=",2),K="wijdir="_SYSD_$E(K,2,$L(K))
	. D S(K)
	D BUC(CF),TEMPO(CF)
STZ	Q
	;
DATAF	;Find data in Cache.cpf
	;Find if DataSets for ROEPNAAM already exists
	S (L,Z)=0,Y=$S(($P($P($ZV,")",2),"(",1)[" 2010"):"[Databases]",1:"[Datasets]")
	F  S L=$O(^TEMP($J,"org",L)) Q:L=""  S K=^(L) S:'Z&(K=Y) Z=1 I Z Q:K=""  D
	. F I="R0",0:1:99 S J=$S(I="R0":I,1:"G"_I) I $D(LOC(J)),$ZCONVERT($P(K,$S(($P($P($ZV,")",2),"(",1)[" 2010"):"=",1:","),2),"U")=$ZCONVERT(LOC(J),"U") K LOC(J)
	;Find if NameSpace for ROEPNAAM already exists
	S (L,Z)=0,Y="[Namespaces]"
	F  S L=$O(^TEMP($J,"org",L)) Q:L=""  S K=^(L) S:'Z&(K=Y) Z=1 I Z Q:K=""  D
	. F I=1:1:99 I $D(NMSP(I)),$ZCONVERT($P($P(K,","),"=",'($P($P($ZV,")",2),"(",1)[" 2010")+1),"U")=$ZCONVERT(NMSP(I),"U") K NMSP(I)
	;Find out if Global Mapping for Namespace already exists
	S (L,Z)=0,Y=$S(($P($P($ZV,")",2),"(",1)[" 2010"):"[Map.",1:"[NspMap.")
	F  S L=$O(^TEMP($J,"org",L)) Q:L=""  S K=^(L) S:'Z&($E(K,1,$L(Y))=Y) Z=1 I Z D
	. F I=1:1:99 I $D(GLOM(I)) D
	.. I $ZCONVERT(K,"U")=$ZCONVERT("[NspMap."_GLOM(I)_"]","U") K GLOM(I)
	.. I $ZCONVERT(K,"U")=$ZCONVERT("[Map."_GLOM(I)_"]","U") K GLOM(I)
DATAFZ	Q
	;
DATAS	;Set up Data
	;Set up DataSets for ROEPNAAM
	S L=0,Y=$S(($P($P($ZV,")",2),"(",1)[" 2010"):"[Databases]",1:"[Datasets]")
	F  S L=$O(^TEMP($J,"org",L)) Q:L=""  S K=^(L) D S(K) I K=Y Q
	F  S L=$O(^TEMP($J,"org",L)) Q:L=""  S K=^(L) Q:K=""  D S(K) I $L(K) S X=K
	I $O(LOC(""))'="" D
	. S X=$P($P(X,"="),"_",2)+1
	. F V="R0",0:1:99 S I=$S(V="R0":V,1:"G"_V) I $D(LOC(I)) D
	.. I ($P($P($ZV,")",2),"(",1)[" 2010") S K=RPN_"-"_I_"="_LOC(I)
	.. E  S K="DataSet_"_X_"="_RPN_"-"_I_","_LOC(I)_",,0,"_$S(VER=3:"C",1:"P,0,0"),X=X+1
	.. D S(K)
	. D S("")
	;Set up NameSpace for ROEPNAAM
	S Y="[Namespaces]"
	F  S L=$O(^TEMP($J,"org",L)) Q:L=""  S K=^(L) D S(K) I K=Y Q
	F  S L=$O(^TEMP($J,"org",L)) Q:L=""  S K=^(L) Q:K=""  D S(K) I $L(X) S X=K
	S X=$P($P(X,"="),"_",2)+1
	I $O(NMSP(""))'="" D
	. F I=1:1:99 I $D(NMSP(I)) D
	.. I ($P($P($ZV,")",2),"(",1)[" 2010") S K=NMSP(I)_"="_RPN_"-G"_I_","_RPN_"-R0"
	.. E  S K="Nsp_"_X_"="_NMSP(I)_","_RPN_"-G"_I_",CACHESYS,"_RPN_"-R0,CACHESYS,CACHELIB,CACHETEMP",X=X+1
	.. D S(K)
	. D S("")
	;Add Global Mapping for ROEPNAAM and Firma above first [NspMap.xxx
	S Y=$S(($P($P($ZV,")",2),"(",1)[" 2010"):"[Map.",1:"[NspMap.")
	F  S L=$O(^TEMP($J,"org",L)) Q:L=""  S K=^(L) Q:$E(K,1,$L(Y))=Y  D S(K)
	S L=$O(^TEMP($J,"org",L),-1)
	I $O(GLOM(""))'="" D
	. F I=1:1:99 I $D(GLOM(I)) D S(Y_GLOM(I)_"]"),G(RPN,I)
	F  S L=$O(^TEMP($J,"org",L)) Q:L=""  S K=^(L) D S(K)
DATASZ	Q
	;
G(B,C)	;Set globalmapping for database B, number C
	S B=$G(B),C=$G(C) Q:'$L(B)!'$L(C)
	K GMX D GMX^cQCPFR(B,C)
	S J="" F  S J=$O(GMX(J)) Q:J=""  D S(GMX(J))
	D S("")
GZ	Q
	;
DS	;Sort DataSets and NameSpaces
	I ($P($P($ZV,")",2),"(",1)[" 2008")+($P($P($ZV,")",2),"(",1)[" 2010") Q
	K ^TEMP($J) S CF=$$CF^cQINST($E($ZU(86))_":") D TEMPI(CF)
	S L=0,Y="[Datasets]" K B
	F  S L=$O(^TEMP($J,"org",L)) Q:L=""  S K=^(L) D S(K) I K=Y Q
	F  S L=$O(^TEMP($J,"org",L)) Q:L=""  S K=^(L) Q:K=""  S B($P(K,"=",2))=""
	K B("CACHESYS,,,0,P,0,0") D S("DataSet_1=CACHESYS,,,0,P,0,0")
	S K="" F I=2:1 S K=$O(B(K)) Q:K=""  D S("DataSet_"_I_"="_K)
	D S("")
	S Y="[Namespaces]" K B
	F  S L=$O(^TEMP($J,"org",L)) Q:L=""  S K=^(L) D S(K) I K=Y Q
	F  S L=$O(^TEMP($J,"org",L)) Q:L=""  S K=^(L) Q:K=""  S B($P(K,"=",2))=""
	S K="" F I=1:1 S K=$O(B(K)) Q:K=""  D S("Nsp_"_I_"="_K)
	D S("")
	F  S L=$O(^TEMP($J,"org",L)) Q:L=""  S K=^(L) D S(K)
	D BUC(CF),TEMPO(CF)	
DSZ	Q
	;
S(R)	S ^TEMP($J,"new",$O(^TEMP($J,"new",""),-1)+1)=R
SZ	Q
	;
TEMPI(C)	; Get Cache.cpf into ^TEMP($J,"org")
	N ER,K,L K ^TEMP($J,"org") N K S C=$G(C) I '$L(C) S C=$$CPF()
	S ER=$$OR^cQFILE(C) I ER Q
	F L=1:1 S ER=$$RF^cQFILE(C,.K) Q:ER  S ^TEMP($J,"org",L)=K
	S ER=$$CF^cQFILE(C)
TEMPIZ	Q
	;
TEMPO(C)	;Put ^TEMP($J,"new") into Cache.cpf
	N ER,K,L S L=0 S C=$G(C) I '$L(C) S C=$$CPF()
	I $O(^TEMP($J,"new",L))="" Q
	S ER=$$FS^cQFILE(C,.FSB),FSB=$G(FSB,0)
	S ER=$$OW^cQFILE(C) I ER Q
	F  S L=$O(^TEMP($J,"new",L)) Q:L=""  S K=^(L),ER=$$WF^cQFILE(C,K_$C(13,10)) Q:ER
	I ER U 0 W !,"Error writing ",C,"!",!
	S ER=$$CF^cQFILE(C)
	S ER=$$FS^cQFILE(C,.FSE),FSE=$G(FSE,0)
	U 0 W !,"File size ",C," went from ",FSB," to ",FSE," = ",FSE-FSB," bytes.",!
TEMPOZ	Q
	;
CPF()	Q $P($ZU(86),"*")
	;
BU()	;Copy entire cache.cpf into ^cCPF
	D TEMPI() I $O(^TEMP($J,"org",""))="" Q
	M ^cCPF($ZCVT($ZU(110),"U"),"cache.cpf")=^TEMP($J,"org")
BUZ	Q 0
	;
	;Make backup of cache.cpf
BUC(C)	N K S C=$G(C) I '$L(C) S C=$$CPF()
	S K=$$FSEQ^cQFILE(C),ER=$$CP^cQFILE(C,K)
BUCZ	Q
	;
GMUP(X,Z)	;Update Global Mapping for Namespace X
	;If Z=1 => update all mappings
	N G,J,K,L,N,RPN,Y
	S Z=+$G(Z),X=$G(X) I 'Z,'$L(X) Q
	;Do not proceed on TBxxx systems
	S K=$E($ZCVT($ZU(110),"U"),1,2) I (K="TB") Q
	D TEMPI() S L=0,Y=$S(($P($P($ZV,")",2),"(",1)[" 2010"):"[Map.",1:"[NspMap.") K ^TEMP($J,"new")
	F  S L=$O(^TEMP($J,"org",L)) Q:L=""  S K=^(L) D S(K) D
	. I $E(K,1,$L(Y))=Y D
	.. S (RPN,N)=$P($P(K,".",2),"]"),G=1
	.. I N'?1"V".N D
	... S (RPN,G)=""
	... F I=1:1:$L(N) Q:$E(N,I)?1N  S RPN=RPN_$E(N,I)
	... F I=I:1:$L(N) Q:$E(N,I)'?1N  S G=G_$E(N,I)
	... I $E(N,I)?1A S RPN=RPN_"-" F I=I:1:$L(N) S RPN=RPN_$E(N,I) 
	.. I (N=X)!Z D
	... ;Is this our globalmapping?
	... S SW=0,M=$S(($P($P($ZV,")",2),"(",1)[" 2010"):"Global_BA=",1:"GloMap_1=BA,"),K=^($O(^TEMP($J,"org",L))) I $E(K,1,$L(M))=M S SW=1
	... ;Skip until line is empty, if 'SW keep these lines else skip them
	... F  S L=$O(^TEMP($J,"org",L)) Q:L=""  S K=^(L) D:'SW S(K) Q:K=""
	... ;If this is our globalmapping, update the globalmapping
	... I SW D G(RPN,G)
	D BUC(),TEMPO()
GMUPZ	Q
	;
GUM(X,Z)	;Global Mapping Update for Namespace X - Caché 2010
	;If Z=1 => update all mappings	
	N A,E,G,GM,GMC,GMD,GMX,I,J,K,M,N,NS,P,OK,OKN,RPN,Y
	S Z=+$G(Z),X=$G(X) I 'Z,'$L(X) Q
	I '($P($P($ZV,")",2),"(",1)[" 2010") Q
	;Do not proceed on TBxxx systems
	S K=$E($ZCVT($ZU(110),"U"),1,2) I (K="TB") Q
	D TEMPI(),NSPC^cQ21(.A,1) S N=""
	F  S N=$O(A(N)) Q:N=""  I ((N'?1.A1.N)&(N'?1.A1.N1"S")&(N'?1.A1.N1"M")) K A(N)
	F  S N=$O(A(N)) Q:N=""  I (N=X)!Z D
	. D GM^cQCPFR(N)
	. S M=N,E="" I (N?1.A1.N1"S")!(N?1.A1.N1"M") S E=$E(N,$L(N)),M=$E(N,1,$L(N)-1)
	. I N?1"V".N S M=N,Y=1
	. E  D
	.. F I=1:1:$L(M) Q:$E(M,I)?1N
	.. S Y=$E(M,I,$L(M)),M=$E(M,1,I-1)
	. D GMX^cQCPFR(M,Y,E) S I=0 K GMC,GMD
	. F  S I=$O(GM(I)) Q:I=""  S SW=1,J=0 D
	.. F  S J=$O(GMX(J)) Q:J=""  I GM(I)=GMX(J) S SW=0 Q
	.. I SW S GMD(I)=GM(I)
	. F  S I=$O(GMX(I)) Q:I=""  S SW=1,J=0 D
	.. F  S J=$O(GM(J)) Q:J=""  I GMX(I)=GM(J) S SW=0 Q
	.. I SW S GMC(I)=GMX(I)
	. S J=0,NS=$ZU(5) ZN "%SYS"
	. F  S J=$O(GMD(J)) Q:J=""  D
	.. S G=$P($P(GMD(J),"="),"_",2)
	.. S OK=##Class(Config.MapGlobals).Delete(N,G)
	. F  S J=$O(GMC(J)) Q:J=""  D
	.. S P("Database")=$P(GMC(J),"=",2),G=$P($P(GMC(J),"="),"_",2)
	.. S OK=##Class(Config.MapGlobals).Create(N,G,.P)
	.. I 'OK S OKN=##Class(Config.MapGlobals).Modify(N,G,.P)
	. ZN NS
GUMZ	Q
	;
CHECK	;Check CPF settings
	I ($P($P($ZV,")",2),"(",1)[" 2010") D
	. W !,"Checking cache.cpf",!
	. D TEMPI() S ROUT="cQCPF5" 
	. F J=0:1 S K=$T(2+J^@ROUT) S K=$P(K,";",2,$L(K,";")) Q:K="END"  D
	.. S A=$P(K,";",2),Y=$P(K,";",1),B=$P(K,";",3),C=$P(B,"=",1)_"=",(L,SW,SW2,SW3)=0
	.. ;Find section Y
	.. I $L(Y) F  S L=$O(^TEMP($J,"org",L)) Q:L=""  S K=^(L) I K=Y Q
	.. ;Find string A
	.. F  S L=$O(^TEMP($J,"org",L)) Q:L=""  S K=^(L) Q:$L(Y)&(K="")  D  Q:SW!SW2
	... I $L(C),$E($ZCONVERT(K,"U"),1,$L(C))=$ZCONVERT(C,"U") S SW3=1,Z=K
	... I $L(B),$E($ZCONVERT(K,"U"),1,$L(B))=$ZCONVERT(B,"U") S SW2=1 Q
	... I $L(A),$E($ZCONVERT(K,"U"),1,$L(A))=$ZCONVERT(A,"U") S SW=1 Q
	.. I SW3 D
	... I SW!'SW2 W !,Y D
 	.... W !,Z,?50,"Current Value."
	.... I SW,'SW2 W !,A,?50,"Original Value."
	.... I 'SW,SW2 W !,Z,?50,"Non-Standard Value."
	.... W !,B,?50,"Expected Value.",!
CHECKZ	Q
	;	
FR(A,Y,B,R)	;Find string A in module Y (if defined)
	;Remove if R=del
	;Replace with B is B defined and R is not defined
	;Add if A not found but module Y and replacement B are defined
	N L,SW,SW2,K
	S A=$G(A),Y=$G(Y),B=$G(B),R=$ZCONVERT($G(R),"U")
	D TEMPI() K ^TEMP($J,"new") S (L,SW,SW2)=0
	;Find section Y
	I $L(Y) F  S L=$O(^TEMP($J,"org",L)) Q:L=""  S K=^(L) D S(K) I K=Y Q
	;Find string A
	F  S L=$O(^TEMP($J,"org",L)) Q:L=""  S K=^(L) Q:$L(Y)&(K="")  D  Q:SW!SW2
	. I $L(A),$E($ZCONVERT(K,"U"),1,$L(A))=$ZCONVERT(A,"U") S SW=1 Q:R="DEL"  I $L(B),'$L(R) D S(B) Q
	. D S(K)
	. I $L(B),$E($ZCONVERT(K,"U"),1,$L(B))=$ZCONVERT(B,"U") S SW2=1 Q
	I 'SW,'SW2,$L(Y) D:$L(B) S(B) D S("")
	I L F  S L=$O(^TEMP($J,"org",L)) Q:L=""  S K=^(L) D S(K)
	I SW D BUC(),TEMPO()
FRZ	Q
	;
GSKR(N,G,S)
	;Save global G from the databases that make up the namespace N
	;kill the global and import the global
	;If S=1, do it for all Gx databases
	S N=$G(N),G=$G(G),S=+$G(S) Q:'$L(N)  Q:'$L(G)  I $E(G)="^" S G=$E(G,2,$L(G)-1)
	D GS(N,G,S) 
	D GK(N,G,S)
	D GR(N,G,S)
GSKRZ	Q
	;
GS(N,G,S)	;Save global G from the databases that make up the namespace N
	;If S=1, do it for all Gx databases
	N %ABIE,A,B,CS,DIR,F,H,I,X,boot,bootrvg,client,cs,master,quiet,slave,workst
	S N=$G(N),G=$G(G),S=+$G(S) Q:'$L(N)  Q:'$L(G)  I $E(G)="^" S G=$E(G,2,$L(G))
	K B D NS^cQ21(.B) Q:'$D(B(N))
	S H(1)=B(N,"globals"),H(0)=$P(H(1),"G",1,$L(H(1),"G")-1)_"G0"
	K A,B,F D DB^cQ21(.A) S F(0)=$G(A(H(0))),F(1)=$G(A(H(1))) Q:'$D(F)
	I S D
	. F I=1:1:99 S H(I)=$P(H(0),"G",1,$L(H(0),"G")-1)_"G"_I D
	.. I $D(A(H(I))) S F(I)=A(H(I)) Q
	.. K H(I)
	K A S DIR=$$INFO^cQ14,DIR=$P(DIR,"\",1,$L(DIR,"\")-1)_"\",CS=$ZU(5),I=""
	F  S I=$O(F(I)) Q:I=""  D
	. ZN "^^"_F(I) S X=$ZU(20,N)
	. Q:'$D(@("^"_G))  L +@("^"_G):1 E  Q
	. S %ABIE=1,%ABIE("PORT")="E",%ABIE("TO")="E",%ABIE("GLRO")="G",%ABIE("FILE")=DIR_H(I)_"-"_G
	. S %ABIE("COM")="Export "_G_" from "_F(I),A("^"_G)="",%ABIE("SEL")="A"
	. S B=$$DEL^cQFILE(%ABIE("FILE")_".GSA") D ^cABIE L -@("^"_G)
	. ZN N S X=$ZU(20,N)
	ZN CS S X=$ZU(20,CS)
GSZ	Q
	;
GK(N,G,S)	;Kill the global from the database that make up the namespace N
	;If S=1, do it for all Gx databases
	N CS,F,H,I,X
	S N=$G(N),G=$G(G),S=+$G(S) Q:'$L(N)  Q:'$L(G)  I $E(G)="^" S G=$E(G,2,$L(G))
	K B D NS^cQ21(.B) Q:'$D(B(N))
	S H(1)=B(N,"globals"),H(0)=$P(H(1),"G",1,$L(H(1),"G")-1)_"G0"
	K A,B,F D DB^cQ21(.A) S F(0)=$G(A(H(0))),F(1)=$G(A(H(1))) Q:'$D(F)
	I S D
	. F I=1:1:99 S H(I)=$P(H(0),"G",1,$L(H(0),"G")-1)_"G"_I D
	.. I $D(A(H(I))) S F(I)=A(H(I)) Q
	.. K H(I)
	K A S CS=$ZU(5),I=""
	F  S I=$O(F(I)) Q:I=""  D
	. ZN "^^"_F(I) S X=$ZU(20,N)
	. Q:'$D(@("^"_G))  L +@("^"_G):1 E  Q
	. K @("^"_G) L -@("^"_G)
	. ZN N S X=$ZU(20,N)
	ZN CS S X=$ZU(20,CS)
GKZ	Q
	;
GR(N,G,S)	;Restore global G from the databases that make up the namespace N
	;If S=1, do it for all namespaces Nx
	N %ABIE,A,B,CS,DIR,H,I,L,X,boot,bootrvg,client,cs,master,quiet,slave,workst
	S N=$G(N),G=$G(G),S=+$G(S) Q:'$L(N)  Q:'$L(G)  I $E(G)="^" S G=$E(G,2,$L(G))
	K B D NS^cQ21(.B) Q:'$D(B(N))
	S H(1)=B(N,"globals"),H(0)=$P(H(1),"G",1,$L(H(1),"G")-1)_"G0"
	K A,L D DB^cQ21(.A) S L(N)=""
	I S K L D
	. F I=1:1:99 S H(I)=$P(H(0),"G",1,$L(H(0),"G")-1)_"G"_I D
	.. I $D(A(H(I))) S L($ZSTRIP(N,">N")_I)="" Q
	.. K H(I)
	S DIR=$$INFO^cQ14,DIR=$P(DIR,"\",1,$L(DIR,"\")-1)_"\",CS=$ZU(5),I=""
	F  S I=$O(L(I)) Q:I=""  D
	. ZN L(I) S X=$ZU(20,N)
	. F X=H(0),B(I,"globals") D
	.. S %ABIE=1,%ABIE("PORT")="I",%ABIE("TO")="E",%ABIE("GLRO")="G",%ABIE("FILE")=DIR_X_"-"_G
	.. S %ABIE("SEL")="A"
	.. I '$$TST^cQFILE(%ABIE("FILE")_".GSA") D ^cABIE
	. ZN N S X=$ZU(20,N)
	ZN CS S X=$ZU(20,CS)
GRZ	Q
	;
YZ	Q
	;
ZZ	; 17.01.2012 - 15:58 * Cache-r6.4.9