cQLINT	;Analyze Integrit.log ;cQLINT;
	;Read ...\Mgr\INTEGRIT.LOG and put result into an alert
	;
START	K R
	I '(($P($P($ZV,")",2),"(",1)[" 5.")+($P($P($ZV,")",2),"(",1)[" 2008")+($P($P($ZV,")",2),"(",1)[" 2010")) Q
	S FILE=$P($ZU(86),"\",1,(($P($P($ZV,")",2),"(",1)[" 2008")!($P($P($ZV,")",2),"(",1)[" 2010"))+3)_"\Mgr\INTEGRIT.LOG",(DIF,L,NE)=0,M="Errors were found."
	S ER=$$OR^cQFILE(FILE)
	I ER S M=" not found!",R(1)="File "_FILE_M
	E  D
	. F I=1:1 S ER=$$RF^cQFILE(FILE,.K) Q:ER  D
	.. I I=1 S R($O(R(""),-1)+1)=K,DAY=$P($P(K," on ",2)," ") I DAY?2N1"/"2N1"/"4N S DIF=$H-$ZDATEH(DAY)
	.. I I=2 S R($O(R(""),-1)+1)=K
	.. I K="" K L S L=0
	.. S L=L+1,L(L)=K
	.. I K="No Errors were found." S R($O(R(""),-1)+1)=K,NE=1,M=K
	.. I K["Error " D
	... F  S ER=$$RF^cQFILE(FILE,.K) Q:ER  Q:K=""  S L=L+1,L(L)=K
	... F J=1:1:L S R($O(R(""),-1)+1)=L(J)
	... K L S L=0
	. I I=1,'$L(K),ER=99 S NE=1,M="is empty."
	. S ER=$$CF^cQFILE(FILE)
	. I DIF>7 S NE=1,M="is from "_DAY
	; Send Alert
	S M=$ZCVT($ZU(110),"U")_" Integrit.log: "_M
	S I="" F  S I=$O(R(I)) Q:I=""  S R(I)=$TR(R(I),"\","/")
	I NE D D9002^cANEM0($T(+0),M,.R)	;no errors -> to logging
	I 'NE D D9001^cANEM0($T(+0),M,.R)	;errors -> to support
	;
YZ	Q
	;
ZZ	; 17.01.2012 - 15:58 * Cache-r6.4.9