cQQSYS	;Check ^cQSYS ;cQQSYS;
	G 1
	;
date	;date
	N %H,%J,%R S %H=1+$H,%J=%H\1461,%R=%H#1461,DJ=%J*4+1841+(%R\365),DD=%R#365,DM=1 I %R=1460 S DD=365,DJ=DJ-1
	F %J=31,(%R>1154)+28,31,30,31,30,31,31,30,31,30 Q:%J'<DD  S DM=DM+1,DD=DD-%J
	S:'DD DJ=DJ-1,DM=12,DD=31 S:DD<10 DD=0_DD S:DM<10 DM=0_DM S DT=DD_"."_DM_"."_$E(DJ,3,4)
datez	Q
time	;time
	N %J,%R S QT=$G(QT),%R=$P($H,",",2)\60,%J=%R\60
	S TD=$J(%J,2)_$P(" u ; h ; h ",";",$S(QT="F":2,QT="E":3,1:1))_(%R#60\10)_(%R#10)
timez	Q
doubleq(X)	;Double quotes in string
	N Y S Y=0 F  S Y=$F(X,"""",Y) Q:'Y  S X=$E(X,0,Y-1)_""""_$E(X,Y,$L(X)),Y=Y+1
doubleqz	K Y Q X
	;
T0	;Controle ^cQSYS ;
T1	;Er werden geen fouten gevonden\"[] = ok";
T2	;Gelieve de fouten manueel te corrigeren\"[] = ok";
T3	;Ongeldig IP-adres;
T4	;Ongeldige NetBiosName;
T5	;Ongeldig MAC-adres;
	;
T0F	;Contrôle ^cQSYS ;
T1F	;On n'a pas trouvé des erreurs\"[] = ok";
T2F	;Veuillez corriger les erreurs manuellement\"[] = ok";
T3F	;Addresse IP incorrect;     
T4F	;NetBiosName incorrect;
T5F	;Addresse MAC incorrect;
	;
T0E	;Check ^cQSYS ;
T1E	;There are no errors\"[] = ok";
T2E	;Please correct the errors manually\"[] = ok";
T3E	;Invalid IP-address;
T4E	;Invalid NetBiosName;
T5E	;Invalid MAC-address;
	;
T0D	;Check ^cQSYS ;
T1D	;There are no errors\"[] = ok";
T2D	;Please correct the errors manually\"[] = ok";
T3D	;Invalid IP-address;
T4D	;Invalid NetBiosName;
T5D	;Invalid MAC-address;
	;
1	D INI^cQ6 S K=$P($T(@("T0"_QT)),U,2)_QN_" ",FP=203+$L(K) W @F61,@F11,@F1,@F,@F5 S FP=202 W @F,@F4,K,@F5
	S %SYS="^cQSYS(CFG,""DDB"",PRT)",CFG=$$CONFIG^cQ9
	S $ZT="ERR"
	;
	S FP=420 W @FS S FP=379 W @F S $Y=3,SW=0,INFO=$$INFO^cQ14
	K ^TEMP($ZCVT($ZU(110),"U"),$J),^($J+.01),^($J+.02),^($J+.03),^($J+.04)
	S PRT=0
	F  S PRT=$O(@%SYS) Q:PRT=""  I $$PV^cQZSTART(PRT) S A=@%SYS D
	. S IP=$P(A,",",2),P=0
	. F  S P=$O(^(P)) Q:P=""  I P'=PRT,$P(^(P),",",2)=IP S $P(^(P),",",2)=""
	S PRT=0 F  S PRT=$O(@%SYS) Q:PRT=""  S A=@%SYS D
	. I $$PV^cQZSTART(PRT) Q  ;Do not touch scanner ports
	. I '$L($TR(A,","))!($TR(A,",")="TELN") K @%SYS
	. S NBN=$P(A,",",3) I NBN?.E1C.E S NBN=$ZSTRIP(NBN,"*C"),$P(^(PRT),",",3)=NBN
	S PRT=0 F  S PRT=$O(@%SYS) Q:PRT=""  S A=@%SYS D
	. I $$PV^cQZSTART(PRT) Q  ;Do not touch scanner ports
	. F I=2:1:3 S C=$P(A,",",I) I $L(C) D
	.. S B="^TEMP("""_$ZCVT($ZU(110),"U")_""",I/100+$J,$P(A,"","",I))" I $D(@B) S @B=@B_D_PRT Q
	.. S @B=PRT
	;
2	S A=""
	F I=2:1:3 D
	. F  S A=$O(^TEMP($ZCVT($ZU(110),"U"),I/100+$J,A)) Q:A=""  S B=^(A) D
	.. I (I=2&(A'?3(1.3N1".")1.3N))!(I=3&(A'?.ANP))!(I=4&(A'?5(2AN1"-")2AN)) D
	... W !?2,B," = ",A," -> ",$P($T(@("T"_(I+1)_QT)),U,2) S SW=1
	.. I B[D S SW=1 D
	... W !?2,A," = ",B," -> " F J=1:1:$L(B,D)-1 W $J($P(A,D,J),4) I '$$AP^cAFA5($P(B,D,J)) K ^cQSYS(0,"DDB",$P(B,D,J))
	.. I $Y>19 S R="K\22\3\[] = ok\\1\\K=""""\" D R0 S $Y=4,FP=2079 W @F,@F1
	;
3	S FP=124 W @FS
	S R="K\22\3\"_$P($T(@("T"_(SW+1)_QT)),U,2)_"\1\\""-""[K\" D R0
	;
YZ	K ^TEMP($ZCVT($ZU(110),"U"),$J),^($J+.01),^($J+.02),^($J+.03),^($J+.04)
	Q
	;
ERR	D E^cA612 W *27,"[1;24r" w !!,$ZE,!! Q
	;
CLEAN	S I=""
	F  S I=$O(^cQSYS(0,"DDB",I)) Q:I=""  Q:I>8999  D
	. S A=^(I),J=I,IPA=$P(A,",",2),NBNA=$P(A,",",3),MACA=$P(A,",",4)
	. I '$L(IPA),'$L(NBNA),'$L(MACA) K ^(I) Q
	. F  S J=$O(^cQSYS(0,"DDB",J)) Q:J=""  Q:J>8999  D
	.. I $$PV^cQZSTART(J) Q  ;Do not touch scanner ports
	.. S B=^(J),IPB=$P(B,",",2),NBNB=$P(B,",",3),MACB=$P(A,",",4)
	.. I '$L(IPB),'$L(NBNB),'$L(MACB) K ^(B) Q
	.. I IPA=IPB,NBNA=NBNB,MACA=MACB W !,"All the same: ",I," = ",J," = ",A
	.. I IPA=IPB S $P(^cQSYS(0,"DDB",J),",",2)=""
	.. I NBNA=NBNB S $P(^cQSYS(0,"DDB",J),",",3)=""
	.. I MACA=MACB S $P(^cQSYS(0,"DDB",J),",",4)=""
	S I="" F  S I=$O(^cQSYS(0,"DDB",I)) Q:I=""  Q:I>8999  D
	. I ^(I)="TELN,"!(^(I)="TELN,,")!(^(I)="TELN,,,") W !,"Leeg: ",I," = ",^(I)
	S (I,J)=""
	F  S I=$O(^cLOG(I)) Q:I=""  D
	. F  S J=$O(^cLOG(I,"LOGIN",J)) Q:J=""  I $P(^(J),"\",2)="^TTSC",'$$PV^cQZSTART(J) K ^cLOG(I,"LOGIN",J)
CLEANZ	Q
	;
FNBN	N A,I,NBN K A S I=""
	F  S I=$O(^cQSYS(0,"DDB",I)) Q:I=""  Q:I>9999  D
	. S NBN=$P(^(I),",",3)
	. I NBN?.E1L.E S NBN=$ZCONVERT(NBN,"U"),$P(^(I),",",3)=NBN
	. I NBN?.E1C.E S NBN=$ZSTRIP(NBN,"*C"),$P(^(I),",",3)=NBN
	. I $L(NBN) S ^cQSYS(0,"FIXED","NBN",NBN)=I,A(NBN)=""
	S I="" F  S I=$O(^cQSYS(0,"FIXED","NBN",I)) Q:I=""  I '$D(A(I)) K ^(I)
FNBNZ	Q
	;
FIP	N A,B,I K A S I=""
	F  S I=$O(^cQSYS(0,"DDB",I)) Q:I=""  Q:I>9999  D
	. S IP=$P(^(I),",",2)
	. I IP'?3(1.3N1".")1.3N S IP="",$P(^(I),",",3)=IP
	. I $L(IP) S ^cQSYS(0,"FIXED","IP",IP)=I,A(IP)=""
	S I="" F  S I=$O(^cQSYS(0,"FIXED","IP",I)) Q:I=""  I '$D(A(I)) K ^(I)
FIPZ	Q
	;
R0	S R0=$P(R,D,5) I $L(R0),R0'["""" S $P(R,D,5)=R0_"^"_$T(+0)
R0A	S R0=$P(R,D,7) I $L(R0),R0'="DCTR" S $P(R,D,7)="",R1=$P(R,D,8),R0=$P($T(@R0),U,2,99) S:$L(R1) R0=R0_"&("_R1_")" S $P(R,D,8)=R0
R0Z	S $P(R,D,12)=$T(+0) K R0,R1 D ^cA100 Q  ; v11 30.05.94
	;
ZZ	; 17.01.2012 - 15:58 * Cache-r6.4.9