cQRESET	;Reset computer ;cQRESET;
	Q
	;
date	;date
	N %H,%J,%R S %H=1+$H,%J=%H\1461,%R=%H#1461,DJ=%J*4+1841+(%R\365),DD=%R#365,DM=1 I %R=1460 S DD=365,DJ=DJ-1
	F %J=31,(%R>1154)+28,31,30,31,30,31,31,30,31,30 Q:%J'<DD  S DM=DM+1,DD=DD-%J
	S:'DD DJ=DJ-1,DM=12,DD=31 S:DD<10 DD=0_DD S:DM<10 DM=0_DM S DT=DD_"."_DM_"."_$E(DJ,3,4)
datez	Q
time	;time
	N %J,%R S QT=$G(QT),%R=$P($H,",",2)\60,%J=%R\60
	S TD=$J(%J,2)_$P(" u ; h ; h ",";",$S(QT="F":2,QT="E":3,1:1))_(%R#60\10)_(%R#10)
timez	Q
doubleq(X)	;Double quotes in string
	N Y S Y=0 F  S Y=$F(X,"""",Y) Q:'Y  S X=$E(X,0,Y-1)_""""_$E(X,Y,$L(X)),Y=Y+1
doubleqz	K Y Q X
	;
1	R !!,"Ok to restart the system <N>? ",R I R="" S R="NO" W R 
	I R'=$E("YES",1,$L(R))&(R'=$E("yes",1,$L(R))) G YZ
INT	;Restart Caché but NOT OS
	S LOG="^cLOG("""_$ZU(5)_""",""RESET"")" D date,time,CLEAN^cQ13(LOG,45)
	S @LOG@($P($H,","),$P($H,",",2))=$$IO^cQ5_"\"_DD_"."_DM_"."_DJ_"\"_TD_"\"_$H_"\"_$G(QU)
	D STUSSD^cQ13("RES"),LOGIN^cQ6("Y")
	D BCSD S X=$$JNW^cQFILE($E($ZU(86))_":\DataM\Menu\CacheStartD.bat")
	D INT^cQSSD
INTZ	Q
	;
BINT	;Stop Caché en restart OS
	S LOG="^cLOG("""_$ZU(5)_""",""RESET"")" D date,time,CLEAN^cQ13(LOG,45)
	S @LOG@($P($H,","),$P($H,",",2))=$$IO^cQ5_"\"_DD_"."_DM_"."_DJ_"\"_TD_"\"_$H_"\"_$G(QU)
	D STUSSD^cQ13("ROS"),LOGIN^cQ6("Y")
	S X=$$JNW^cQFILE($E($ZU(86))_":\DataM\menu\Shutdown /L /R /C")
	D INT^cQSSD
BINTZ	Q
	;
YZ	Q
	;
BCSD	S FILE=$E($ZU(86))_":\DataM\Menu\CacheStartD.bat",CRLF=$C(13,10)
	S KILL=$$KOSFI^cQ14
	S ER=$$DEL^cQFILE(FILE) I ER Q
	S ER=$$OW^cQFILE(FILE) I ER Q
	S ER=$$WF^cQFILE(FILE,"@echo off"_CRLF)
	S ER=$$WF^cQFILE(FILE,"rem Wait 30 seconds to allow Caché to shutdown properly"_CRLF)
	S ER=$$WF^cQFILE(FILE,$E($ZU(86))_":\DataM\Menu\wait.exe 30"_CRLF)
	S ER=$$WF^cQFILE(FILE,"rem Kill all remaining Caché processes"_CRLF)
	S ER=$$WF^cQFILE(FILE,KILL_"ctelnetd.exe"_CRLF)
	S ER=$$WF^cQFILE(FILE,KILL_"cache.exe"_CRLF)
	S ER=$$WF^cQFILE(FILE,KILL_"ccontrol.exe"_CRLF)
	S ER=$$WF^cQFILE(FILE,KILL_"css.exe"_CRLF)
	S ER=$$WF^cQFILE(FILE,KILL_"cservice.exe"_CRLF)
	S ER=$$WF^cQFILE(FILE,$P($ZU(86),"\",1,(($P($P($ZV,")",2),"(",1)[" 2008")!($P($P($ZV,")",2),"(",1)[" 2010"))+3)_"\bin\css.exe start CACHE"_CRLF)
	S ER=$$WF^cQFILE(FILE,"exit"_CRLF)
	S ER=$$CF^cQFILE(FILE)
BCSDZ	Q
	;
ZZ	; 17.01.2012 - 15:58 * Cache-r6.4.9