cQSGLO(S,X,E,N)	;Search all globals for string S ;cQSGLO;
	; Find string S in all globals, if X=1 convert to uppercase
	; E = exclude globals, format (\^G1\^G2\), if N=1 do not exclude anything
	G 1
	;
date	;date
	N %H,%J,%R S %H=1+$H,%J=%H\1461,%R=%H#1461,DJ=%J*4+1841+(%R\365),DD=%R#365,DM=1 I %R=1460 S DD=365,DJ=DJ-1
	F %J=31,(%R>1154)+28,31,30,31,30,31,31,30,31,30 Q:%J'<DD  S DM=DM+1,DD=DD-%J
	S:'DD DJ=DJ-1,DM=12,DD=31 S:DD<10 DD=0_DD S:DM<10 DM=0_DM S DT=DD_"."_DM_"."_$E(DJ,3,4)
datez	Q
time	;time
	N %J,%R S QT=$G(QT),%R=$P($H,",",2)\60,%J=%R\60
	S TD=$J(%J,2)_$P(" u ; h ; h ",";",$S(QT="F":2,QT="E":3,1:1))_(%R#60\10)_(%R#10)
timez	Q
doubleq(X)	;Double quotes in string
	N Y S Y=0 F  S Y=$F(X,"""",Y) Q:'Y  S X=$E(X,0,Y-1)_""""_$E(X,Y,$L(X)),Y=Y+1
doubleqz	K Y Q X
	;
1	S $ZT="ERR^"_$T(+0),D="\",S=$G(S) I '$L(S) G YZ
	S boot=$ZCVT($ZU(110),"U"),X=$G(X),E=$G(E),N=$G(N) B 1 I X S S=$ZCONVERT(S,"U")
	S EX="\^HULP\"
	I 'N D
	. S EX=EX_"^%utility\^BENCH\^ERRORS\^ROUTINE\^STRTBNCH\^TEMP\^TEMPC\^TEMPS\^TMP\^UTILITY\^ZZLOG\^mcq\^zzlog\"
	. S EX(1)="^CacheTemp",EX(2)="^mtemp",EX(3)="^r",EX(4)="^c",EX(5)="^%q",EX(6)="^odd"
	I $L(E) S:$E(E)="\" E=$E(E,2,$L(E)) S:$E(E,$L(E))'="\" E=E_"\" S EX=EX_E
	K ^HULP(boot,$J)
	D date,time D SD(DT_D_TD_D_S,0)
	K ^%utility($j) S X=$$Fetch^%GD("*",1,0),%G=""
	F  S %G=$O(^%utility($J,%G)) Q:%G=""  D
	. I $G(EX)[(D_%G_D) Q
	. S (SW,I)=0 F  S I=$O(EX(I)) Q:I=""  I $E(%G,1,$L(EX(I)))=EX(I) S SW=1 Q
	. Q:SW  S %GX=%G
	. F  S %GX=$Q(@%GX) Q:%GX=""  D  I $$VD()>1000 Q
	.. S data=@%GX I X S data=$ZCONVERT(data,"U")
	.. I data[S S V=$$VD() D SD(%GX,V),SD(@%GX,V+.01)
	D date,time D SD(DT_D_TD_D_S,.99)
YZ	Q
	;
VD()	Q $O(^HULP(boot,$J,""),-1)\1+1
	;
SD(K,N)	S N=$G(N) Q:'$L(N)  S K=$G(K) Q:'$L(K)  S ^HULP(boot,$J,N)=K
	Q
	;
ERR	S K=$ZE S V=$$VD() D SD(K,V) Q
	;
ZZ	; 17.01.2012 - 15:58 * Cache-r6.4.9