cQSTART	;STARTUP THE CACHE SYSTEM ;cQSTART;
	Q
	;
date	;date
	N %H,%J,%R S %H=1+$H,%J=%H\1461,%R=%H#1461,DJ=%J*4+1841+(%R\365),DD=%R#365,DM=1 I %R=1460 S DD=365,DJ=DJ-1
	F %J=31,(%R>1154)+28,31,30,31,30,31,31,30,31,30 Q:%J'<DD  S DM=DM+1,DD=DD-%J
	S:'DD DJ=DJ-1,DM=12,DD=31 S:DD<10 DD=0_DD S:DM<10 DM=0_DM S DT=DD_"."_DM_"."_$E(DJ,3,4)
datez	Q
time	;time
	N %J,%R S QT=$G(QT),%R=$P($H,",",2)\60,%J=%R\60
	S TD=$J(%J,2)_$P(" u ; h ; h ",";",$S(QT="F":2,QT="E":3,1:1))_(%R#60\10)_(%R#10)
timez	Q
doubleq(X)	;Double quotes in string
	N Y S Y=0 F  S Y=$F(X,"""",Y) Q:'Y  S X=$E(X,0,Y-1)_""""_$E(X,Y,$L(X)),Y=Y+1
doubleqz	K Y Q X
	;
START	;
1	;setup variables
	S SERVER=$ZCVT($ZU(110),"U"),NMSPC=$ZU(5) I SERVER="?" G YZ
	S K="" F  S K=$O(^cTABELd(K)) Q:K=""  I K'=SERVER K ^cTABELd(K)
	S CONFIG=$G(^cTABEL("base",SERVER,NMSPC,"Config")) I '$L(CONFIG) G YZ
	I +$G(^cTABELd(SERVER,NMSPC,CONFIG)) G YZ
	;
	;Don't allow logon
	D LOGINN^cQ6
	;
	;Wait 2 seconds to let things settle down
	H 2
	;
	;Stop jobs if already started:  shadowing, backgroundjob manager 
	D JOBS^cQSYS S A=""
	F  S A=$O(JOB(0,A)) Q:A=""  S J=JOB(0,A),K=$$JP^cQJOB(J,"routine") I "\cQCTK1\SHDWSREC\SHDWCREC\SHDWSBLK\SHDWCBLK\"[("\"_K_"\") S X=$ZU(4,J) Q
	;
2	;loop through ^cTABEL
	S QUIET=1 D Message("Data-M apply ^cTABEL(""change"","""_SERVER_""","""_NMSPC_""","""_CONFIG_""") started")
	S A=""
	F  S A=$O(^cTABEL("change",SERVER,NMSPC,CONFIG,"kill",A)) Q:A=""  K @A
	F  S A=$O(^cTABEL("change",SERVER,NMSPC,CONFIG,"merge",A)) Q:A=""  S B=^(A) M @A=@B
	F  S A=$O(^cTABEL("change",SERVER,NMSPC,CONFIG,"set",A)) Q:A=""  S B=^(A),@A=B
	F  S A=$O(^cTABEL("change",SERVER,NMSPC,CONFIG,"xecute",A)) Q:A=""  S B="N A "_^(A) X B
3	;Set switch
	S ^cTABELd(SERVER,NMSPC,CONFIG)=1_"\"_$H_"\"_$TR($ZD(+$H,4),"/",".")_"\"_$ZT(+$P($H,",",2),1)
	S QUIET=1 D Message("Data-M apply ^cTABEL(""change"","""_SERVER_""","""_NMSPC_""","""_CONFIG_""") ended")
	;
4	;restart system
	S QUIET=1 D Message("Data-M waiting 5 seconds before shutting down Caché")
	;Create global to flush data
	F I=1:1:1000 S ^HULP($ZCVT($ZU(110),"U"),$J,I)=I
	H 5 D INT^cQRESET
	;
YZ	Q
	;
REP	;Replace cache.cpf with ^cTABEL("cpf",CurrentSystem,"cache.cpf")
	N BG,CF,ER,K
	S CF=$P($ZU(86),"*")
	S K=$$FSEQ^cQFILE(CF),ER=$$CP^cQFILE(CF,K)  ;make backup of cache.cpf
	I '$D(^cTABEL("cpf",$ZCVT($ZU(110),"U"),"cache.cpf")) Q
	I $O(^cTABEL("cpf",$ZCVT($ZU(110),"U"),"cache.cpf",""))="" Q
	S BG=1,ER=$$EXP($ZCVT($ZU(110),"U"),CF)
REPZ	Q
	;
MSEC(X,Y)	;Modify cache.cpf Section
	;X = section, Y = Add, Remove, Replace
	S X=$G(X),Y=$G(Y) Q:'$L(X)  Q:'$L(Y) 
	S CF=$P($ZU(86),"*"),ER=$$OR^cQFILE(CF) I ER Q
	S CFN=$P(CF,".cpf")_".new",ER=$$CF^cQFILE(CFN),ER=$$OW^cQFILE(CFN) I ER Q
	F  S ER=$$RF^cQFILE(CF,.K) Q:ER  Q:$E(K,1,$L(X))=X  S ER=$$WF^cQFILE(CFN,K_$C(13,10)) Q:ER
	I 'ER D
	. I Y="Remove" F  S ER=$$RF^cQFILE(CF,.K) Q:ER  Q:K=""
	. I Y="Replace" S I="" F  S I=$O(^cTABEL("change",SERVER,NMSPC,CONFIG,"Cache.cpf",X,I)) Q:I=""  S K=^(I) S ER=$$WF^cQFILE(CFN,K_$C(13,10)) Q:ER
	. F  S ER=$$RF^cQFILE(CF,.K) Q:ER  D  Q:ER  S ER=$$WF^cQFILE(CFN,K_$C(13,10)) Q:ER
	I Y="Add" S I="" F  S I=$O(^cTABEL("change",SERVER,NMSPC,CONFIG,"Cache.cpf",X,I)) Q:I=""  S K=^(I) S ER=$$WF^cQFILE(CFN,K_$C(13,10)) Q:ER
	S ER=$$CF^cQFILE(CF),ER=$$CF^cQFILE(CFN)  ;close files
	S K=$$FSEQ^cQFILE(CF),ER=$$CP^cQFILE(CF,K)  ;make backup of cache.cpf
	S ER=$$CP^cQFILE(CFN,CF)  ;copy new file to cache.cpf
MSECZ	Q
	;
RSTR(X,Y)	;Replace line in cache.cpf
	;X = string, Y = new value
	S X=$G(X),Y=$G(Y) Q:'$L(X)  Q:'$L(Y)
	S CF=$P($ZU(86),"*"),ER=$$OR^cQFILE(CF) I ER Q
	S CFN=$P(CF,".cpf")_".new",ER=$$CF^cQFILE(CFN),ER=$$OW^cQFILE(CFN) I ER Q
	F  S ER=$$RF^cQFILE(CF,.K) Q:ER  Q:$E(K,1,$L(X))=X  S ER=$$WF^cQFILE(CFN,K_$C(13,10)) Q:ER
	S ER=$$WF^cQFILE(CFN,X_Y_$C(13,10)) Q:ER
	F  S ER=$$RF^cQFILE(CF,.K) Q:ER  D  Q:ER  S ER=$$WF^cQFILE(CFN,K_$C(13,10)) Q:ER
	S ER=$$CF^cQFILE(CF),ER=$$CF^cQFILE(CFN)  ;close files
	S K=$$FSEQ^cQFILE(CF),ER=$$CP^cQFILE(CF,K)  ;make backup of cache.cpf
	S ER=$$CP^cQFILE(CFN,CF)  ;copy new file to cache.cpf
RSTRZ	Q
	;
CHECK()	;check config
	S SERVER=$ZCVT($ZU(110),"U"),NMSPC=$ZU(5)
	S CONFIG=$G(^cTABEL("base",SERVER,NMSPC,"Config")) I '$L(CONFIG) Q 1
	S A="",E=0
	F  S A=$O(^cTABEL("change",SERVER,NMSPC,CONFIG,"set",A)) Q:A=""  S B=^(A) I @A'=B S E=2 W !,A,!?10,@A,!?20,B Q
CHECKZ	Q E
	;
Message(Msg)	;
	n (QUIET,Msg)
	s $ZT="MessageZ"
	i QUIET=0 w !,$ztime($p($h,",",2))_" "_Msg
	i $zu(9,"",Msg)
MessageZ	q
	;
BUILD(S)	;Build ^cTABEL("cpf",system,"cache.cpf")
	N CF,ER,I,K,SYS
	S S=$G(S,$ZCVT($ZU(110),"U")),CF=$P($ZU(86),"*")
	I $ZCONVERT(S,"L")'[".terbeke.loc" D
	. S CF="\\"_S_"\"_$TR(CF,":","$")
	I $ZCONVERT(S,"L")[".terbeke.loc" D
	. S I=$$INFO^cQ14
	. S K="psexec \\"_S_" -u ter_beke\msmadm -p wabcomdp cmd /c type "_CF_" > "_I
	. S ER=$$JW^cQFILE(K) S CF=I
	S SYS=$P(S,"."),ER=$$IMP(S,CF)
BUILDZ	Q ER
	;
SHDW	;Build settings for ^["%SYS"]SYS("shdwcli")
	N SERVER,NMSPC,CONFIG,T,X,Y
	S SERVER=$ZCVT($ZU(110),"U"),NMSPC=$ZU(5) I SERVER="?" Q
	S CONFIG=$G(^cTABEL("base",SERVER,NMSPC,"Config")) I '$L(CONFIG) Q
	S T="^cTABEL(""change"","""_SERVER_""","""_NMSPC_""","""_CONFIG_""",""set"","
	S (X,Y)="^[""%SYS""]SYS(""shdwcli"")"
	F  S X=$Q(@X) Q:X=""  Q:$E(X,1,$L(Y)-1)_")"'=Y  W !,";;~",T,"""",$$DOUBLEQ^cQ9(X),""")",!,";;",@X
SHDWZ	Q
	;
IMP(S,B)	;Import file B into ^cTABEL("cpf",S,"cache.cpf")
	N ER,I,K
	S S=$G(S,$ZCVT($ZU(110),"U")),B=$G(B,$E($ZU(86))_":\DataM\Temp\"_S_".cpf")
	I '$G(BG) U 0 W !,"Import ",B,!,"into ^cTABEL(""cpf"","""_S_""",""cache.cpf"")"
	K ^cTABEL("cpf",S,"cache.cpf")
	S ER=$$OR^cQFILE(B) I ER Q ER
	F I=1:1 S ER=$$RF^cQFILE(B,.K) Q:ER  S ^cTABEL("cpf",S,"cache.cpf",I)=K
	I ER["ENDOFFILE" S ER=0
	S ER=$$CF^cQFILE(B)
IMPZ	Q ER
	;
EXP(S,B)	;Export ^cTABEL("cpf",S,"cache.cpf") into File B
	N ER,I,K
	S S=$G(S,$ZCVT($ZU(110),"U")),B=$G(B,$E($ZU(86))_":\DataM\Temp\"_S_".cpf")
	S I=""
	I '$G(BG) U 0 W !,"Export ^cTABEL(""cpf"",""",S,""",""cache.cpf"")",!,"into "_B
	S ER=$$OW^cQFILE(B) I ER Q ER
	F  S I=$O(^cTABEL("cpf",S,"cache.cpf",I)) Q:I=""  S K=^(I),ER=$$WF^cQFILE(B,K_$C(13,10)) Q:ER  
	S ER=$$CF^cQFILE(B)
EXPZ	Q ER
	;
COPY	;Copy ^cTABEL naar ^cTABELsysteem voor een bepaald systeem
	N I,SYS,SYSS,TAB S SYS=$ZCVT($ZU(110),"U")
	S SYSS=$TR($TR(SYS,"abcdefghijklmnopqrstuvwxyz","ABCDEFGHIJKLMNOPQRSTUVWXYZ"),"-")
	S TAB="^cTABEL"_SYSS K @TAB
	S @TAB@(0,"name")=SYS
	F I="base","change","cpf" M @TAB@(I,SYS)=^cTABEL(I,SYS)
COPYZ	Q
	;
INSL	;Insert line in ^cTABEL("cpf",system,"cache.cpf")
	N A,DATA,I,K,MAX,N,system K A,system
INSLA	W !!,$P($T(INSL),";",2) D SYS Q:'$D(system)
INSLB	W !,"Insert after line number? (max=",MAX,"): " R K G INSLA:K="-"
	I K'?.N W !!,"Invalid input!",! G INSLB
	I K>MAX W !!,"Invalid input!",! G INSLB
	S N=K
INSLC	W !,"Insert after  ^cTABEL(""cpf"",""",system,""",""cache.cpf"",",N,")=",^cTABEL("cpf",system,"cache.cpf",N)
	W !,"1[] = yes  0[] = no : " R K I K="-"!(K=0) G INSLB
	I K'=1 G INSLC
INSLD	W !,"Insert which data? :",! R K S DATA=K
INSLE	W !,"Insert  ^cTABEL(""cpf"",""",system,""",""cache.cpf"",",N+1,")=",DATA
	W !,"1[] = yes  0[] = no : " R K I K="-"!(K=0) G INSLD
	I K'=1 G INSLD
	;Insert
	F I=MAX:-1:N+1 S ^(I+1)=^cTABEL("cpf",system,"cache.cpf",I)
	S ^cTABEL("cpf",system,"cache.cpf",N+1)=DATA
INSLZ	Q
	;
DELL	;Delete line in ^cTABEL("cpf",system,"cache.cpf")
	N A,I,K,MAX,N,system
DELLA	K A,system W !!,$P($T(DELL),";",2) D SYS Q:'$D(system)
DELLB	W !,"Delete line number? (max=",MAX,"): " R K G DELLA:K="-"
	I 'K W !!,"Invalid input!",! G DELLB
	I K>MAX W !!,"Invalid input!",! G DELLB
	S N=+K
DELLC	W !,"Delete  ^cTABEL(""cpf"",""",system,""",""cache.cpf"",",N,")=",^cTABEL("cpf",system,"cache.cpf",N)
	W !,"1[] = yes  0[] = no : " R K I K="-"!(K=0) G DELLB
	I K'=1 G DELLC
	;Delete
	F I=N:1:MAX-1 S ^(I)=^cTABEL("cpf",system,"cache.cpf",I+1)
	K ^cTABEL("cpf",system,"cache.cpf",MAX)
DELLZ	Q
	;
REPL	;Replace line in ^cTABEL("cpf",system,"cache.cpf")
	N A,DATA,I,K,MAX,N,system K A,system
REPLA	W !!,$P($T(REPL),";",2) D SYS Q:'$D(system)
REPLB	W !,"Replace line number? (max=",MAX,"): " R K G REPLA:K="-"
	I K'?.N W !!,"Invalid input!",! G REPLB
	I K>MAX W !!,"Invalid input!",! G REPLB
	S N=K
REPLC	W !,"Replace  ^cTABEL(""cpf"",""",system,""",""cache.cpf"",",N,")=",^cTABEL("cpf",system,"cache.cpf",N)
	W !,"1[] = yes  0[] = no : " R K I K="-"!(K=0) G REPLB
	I K'=1 G REPLC
REPLD	W !,"Replace with data? :",! R K S DATA=K
REPLE	W !,"Replace with  ^cTABEL(""cpf"",""",system,""",""cache.cpf"",",N,")=",DATA
	W !,"1[] = yes  0[] = no : " R K I K="-"!(K=0) G REPLD
	I K'=1 G REPLD
	;Replace
	S ^cTABEL("cpf",system,"cache.cpf",N)=DATA
REPLZ	Q
	;
SYS	S K="" F I=0:1 S K=$O(^cTABEL("cpf",K)) Q:K=""  S A(I+1)=K
	I I=0 Q  	;No systems found
SYSA	W !,"System? " F I=1:1:I W I,"[] = ",A(I),"  "
	W ": " R K Q:K="-"  I '$D(A(+K)) W !!,"Invalid input!" G SYSA
	S system=A(K) S MAX=$O(^cTABEL("cpf",system,"cache.cpf",""),-1)
SYSZ	Q
	;
GE(X,V)	;Export ^cTABEL versie V for customer X
	N %ABIE,SEL S X=$G(X),V=$G(V) Q:'$L(X)  Q:'$L(V)
	S %ABIE("FILE")=$$GF(X,V)
	S %ABIE("COM")="cTABEL "_X_" v"_V
	S %ABIE("SEL")="SEL",SEL("cTABEL")=""
	W !,"Exporting ^cTABEL with comment: ",%ABIE("COM"),!
	D GE^cABIE
GEZ	Q
	;
GI(X,V)	;Import ^cTABEL versie V for customer X
	N %ABIE S X=$G(X),V=$G(V) Q:'$L(X)  Q:'$L(V)
	S %ABIE("FILE")=$$GF(X,V)
	W !,"Importing ^cTABEL",! K ^cTABEL
	D GI^cABIE
GIZ	Q
	;
GF(X,V)	;set filename for ^cTABEL
	N K S X=$G(X),V=$G(V) Q:'$L(X)  Q:'$L(V)
	S K="cTABEL_"_$TR(X," ")_"_v"_$TR(V,".","-")_".gsa"
	I $E($ZCVT($ZU(110),"U"),1,3)="DAM" S K="\\data-m.be\dfs\mappen\Documenten\Klanten\"_X_"\Configuratie\"_K
	E  S K=$$UDIR^cQUS()_K
GFZ	Q K
	;
ZZ	; 17.01.2012 - 15:58 * Cache-r6.4.9