cQUP649	;Update cQ ;cQUP649;
	;
	;Release 6.4.9 - 01.12.2011
	;Updated routines
	;cQ4     ;07.12.2011 11:23 ;RES: module added
	;cQ14    ;20.12.2011 17:05 ;AL+7: get optional e-mail addresses, put in CC
	;        ;17.01.2012 11:50 ;M+24: get optional e-mail addresses, put in CC
	;        ;17.01.2012 13:00 ;AL: adres format adjusted
	;cQ17    ;06.12.2011 14:23 ;COPYBG+6: FJOB(...,"routine"
	;cQCD    ;12.01.2012 11:12 ;JRNL+28: message only when shadowing is active
	;cQCE    ;26.12.2011 14:20 ;CTK+6: add A("BU")
	;        ;26.12.2011 14:25 ;CTK+19: check BU added
	;        ;28.12.2011 09:55 ;CTK+15: S0-S1=1 -> S0-S1'=0
	;cQCPF   ;20.12.2011 13:43 ;CHECK: module added
	;        ;26.12.2011 16:32 ;CHECK+15: line added
	;cQCPFR  ;17.01.2012 16:55 ;GMX+2: added 'K GMX'
	;cQCPF10 ;16.01.2012 17:00 ;mapping for DKAS & INDKAS added
	;cQCTK1  ;26.12.2011 10:10 ;START+91: job time-out from 2 to 3 seconds
	;cQIC    ;01.12.2011 12:01 ;TBK: module added
	;cQJOB   ;06.12.2011 16:00 ;FJOB: parameter added
	;        ;06.12.2011 16:10 ;JK: parameters Y, nokill added
	;        ;05.01.2012 12:35 ;KCTK+3: FJOB("cQCC",.A) -> FJOB("cQCC","routine",.A)
	;        ;05.01.2012 12:36 ;KCTK+5: FJOB("cQCTK1",.A) -> FJOB("cQCTK1","routine",.A)
	;cQJRNL  ;12.01.2012 10:45 ;PUJ: PPURGE -> PURGE
	;        ;12.01.2012 11:10 ;make foolproof ($G(X), etc.)
	;cQUS    ;12.01.2012 12:00 ;RST+16: Export routines defined by EXTDEF
	;New Routines
	;cQSCGS  ;19.12.2011 17:57 ;Scan global size
	;cQUP649 ;01.12.2011 12:00 ;changes in version 6.4.9
	;Deleted Routines
	;
	;Update
	W !!,"Update voor  ",$ZV,"  release  ",$P($T(ZZ),"-r",2),!
	S NSPC=$G(^["%SYS"]cLOG(0,"NAMESPACE",0)) I $L(NSPC) ZN NSPC
	;
	S REL=$P($T(ZZ),"-r",2),RELDP=$TR(REL,".")
	F K="cQINT","cQUP" D
	. S (I,J)=K
	. F  S I=$O(^$R(I)) Q:$E(I,1,$L(J))'=J  S K=$P(I,J,2) I K?.N,K'=RELDP X "ZR  ZS @I"
	;
	S CN=$ZU(5),SN="%SYS",LN="%CACHELIB"
	;
	;Save routines in namespace %SYS
	I '($P($P($ZV,")",2),"(",1)[" 2008")&'($P($P($ZV,")",2),"(",1)[" 2010") D
	. D RS("cQCW\%CHARWIN",CN,SN),RS("cQX364\%X364",CN,SN)
	. D RS("cQCW\cCHARWIN",CN,SN),RS("cQX364\cX364",CN,SN)
	. D RS("cQCW\cCHARWIN",CN,CN),RS("cQX364\cX364",CN,CN)
	. D RS("cQQ\cQQ",CN,LN)
	E  D
	. D RS("cQCW2008\%ZCHARWIN",CN,SN),RS("cQX364\%ZX364",CN,SN)
	. D RS("cQCW2008\cCHARWIN",CN,SN),RS("cQX364\cX364",CN,SN)
	. D RS("cQCW2008\cCHARWIN",CN,CN),RS("cQX364\cX364",CN,CN)
	D RS("cQQ\cQQ",CN,SN)
	D RS("cQSYS\%ZQSYS",CN,SN)
	S MM="" ZN SN X:$D(^$R("%ZSTART")) "ZL %ZSTART S MM=$P($T(+2),"";"",2)" ZN CN
	I MM="DATA-M" D RS("cQZSTART\%ZSTART",CN,SN)
	S MM="" ZN SN X:$D(^$R("%ZSTOP")) "ZL %ZSTOP S MM=$P($T(+2),"";"",2)" ZN CN
	I MM="DATA-M" D RS("cQZSTOP\%ZSTOP",CN,SN)
	;Save routines in current namespace
	D RS("cQIINT\IINT",CN,CN)
	D RS("cQTTSC\TTSC",CN,CN)
	;
	;Delete routines in namescpace %SYS
	D RD("cQMSMQ",CN,SN)
	;Delete routines in current namespace 
	D RD("cQDSCON",CN,CN)
	D RD("cQJRNLTT",CN,CN)
	D RD("cQLOCK",CN,CN)
	D RD("cQSS",CN,CN)
	D RD("cQVGCOM",CN,CN)
	;
	;Delete logbook ^ZZLOG
	F K="%GSIZE","GCOMPACT","INTEGRIT" I $D(^ZZLOG(K)) K ^ZZLOG(K)
	;
	;Skip next updates if already on cQ 5.4.3 or beyond
	S K=$P($P($G(^cLOG(0,"VERS","cQ"),"1.1.0"),"\"),"r",2),L=""
	S L=($P(K,".",1)*10000)+($P(K,".",2)*100)+$P(K,".",3)
	I L>50402 G NEW
 	;
	;Set ^cLOG(0,"LOGOUT")
	D LOGOUT^cQ7
	;
	;Change references to routines cQMSM... to cQ...
	K N D NSPC^cQ21(.N,1) S N=""
	F  S N=$O(N(N)) Q:N=""  D
	. F G="^DAMBA","^cDAMBA","^EABA" S GS=G_"(""MENU"")",I1="" D
	.. F  S I1=$O(@GS@(I1)) Q:I1=""  S I2="" D
	... F  S I2=$O(@GS@(I1,I2)) Q:I2=""  S A=^(I2) I A["cQMSM" D  S ^(I2)=A
	.... F  S A=$P(A,"cQMSM",1)_"cQ"_$P(A,"cQMSM",2,$L(A,"cQMSM")) Q:A'["cQMSM"
	;
	;change ^cLOG(0,"SYSTEM") to ^cLOG( cs ,"SYSTEM")
	I $D(^cLOG(0,"SYSTEM")) D
	. S K=$TR($ZU(5),"1234567890","")
	. F I=1:1:99 I $ZU(90,10,K_I) M ^cLOG(K_I,"SYSTEM")=^cLOG(0,"SYSTEM")
	. K ^cLOG(0,"SYSTEM")
	;
	;Change settings in Cache.cpf
	I '($P($P($ZV,")",2),"(",1)[" 2008") D
	. D FR^cQCPF("gmheap=","[config]","gmheap=32768")
	. D FR^cQCPF("BIGINT=","[SqlSysDatatypes]","BIGINT=%Library.BigInt")
	. D FR^cQCPF("ExtrinsicFunctions=","[SQL]","ExtrinsicFunctions=1")
	I ($P($P($ZV,")",2),"(",1)[" 2008") D
	. D FR^cQCPF("Mnemonic_OTH=^%X364","[IO]","Mnemonic_OTH=^%ZX364")
	. D FR^cQCPF("Mnemonic_SEQ=^%X364","[IO]","Mnemonic_SEQ=^%ZX364")
	. D FR^cQCPF("Mnemonic_TTY=^%X364","[IO]","Mnemonic_TTY=^%ZX364")
	. D FR^cQCPF("DisconnectErr=0","[Miscellaneous]","DisconnectErr=1")
	I ($P($P($ZV,")",2),"(",1)[" 2010") D
	. D FR^cQCPF("File=^%X364","[IO]","File=^%ZX364")
	. D FR^cQCPF("Other=^%X364","[IO]","Other=^%ZX364")
	. D FR^cQCPF("Terminal=^%X364","[IO]","Terminal=^%ZX364")
	. D FR^cQCPF("DisconnectErr=0","[Miscellaneous]","DisconnectErr=1")
	;
	;Change backuptime to seconds
	S (I,J)=""
	F  S I=$O(^cLOG($ZU(5),"BACKUP","LOGBOEK",4,I)) Q:I=""  D
	. F  S J=$O(^cLOG($ZU(5),"BACKUP","LOGBOEK",4,I,J)) Q:J=""  D
	.. S K=$P(^(J),"\",6) I K<60 S $P(^(J),"\",6)=K*60
	;
NEW	;new for this version
	;
	;Set Update directory
	S K=$$CRED^cQFILE($E($ZU(86))_":\DataM\Updates")
	S K=$G(^cLOG($ZU(5),"cABIE","DIR"),$G(^cLOG($ZCVT($ZU(110),"U"),"cABIE","DIR"),$E($ZU(86))_":\DataM\Temp\"))
	S K=$ZCONVERT(K,"U") I $E(K,$L(K))'="\" S K=K_"\"
	I K=($ZCONVERT($E($ZU(86)),"U")_":\DATAM\TEMP\") S ^cLOG($ZCVT($ZU(110),"U"),"cABIE","DIR")=$E($ZU(86))_":\DataM\Updates\"
	;
	D PDF^cQ7
	D SYM^cQ7
	D VERS^cQ7
	;
	I '$D(^cLOG(0,"BACKUP","TYPE",4)) S ^cLOG(0,"BACKUP","TYPE",4)="M Xcopy"
	;
	;Update backgroundjobs
	F J="SYSTEM","CACHE","SUSP","SHDW","JRNL","SAL" S K=J_"^cQCD",I=0 F  S I=$O(^cLOG($ZU(5),"CTK0","AUTO",I)) Q:I=""  I $P(^(I),"\")=K S $P(^(I),"\")=K_"()"
	D UCTK0^cQ10
	;
	I $D(^cLOG($ZU(5),"BACKUPPC","DIR")) D
	. S ^cLOG($ZU(5),"BACKUP","PC","DIR")=^cLOG($ZU(5),"BACKUPPC","DIR")
	. K ^cLOG($ZU(5),"BACKUPPC","DIR")
	I $D(^cLOG($ZU(5),"BACKUPPC","LOG")) D
	. S ^cLOG($ZU(5),"BACKUP","PC","LOG")=^cLOG($ZU(5),"BACKUPPC","LOG")
	. K ^cLOG($ZU(5),"BACKUPPC","LOG")
	;
	I $D(^cLOG($ZCVT($ZU(110),"U"),"UPDATE",0)) K ^cLOG($ZCVT($ZU(110),"U"),"UPDATE",0)
	I $D(^cLOG($ZU(5),"UPDATE",0)) K ^cLOG($ZU(5),"UPDATE",0)
	;
	M ^cDATA(0,"DEV.VID","ZE")=^cDATA(0,"DEV.VID","ZC")
	M ^cDATA(0,"DEV.VID","ZP")=^cDATA(0,"DEV.VID","ZC")
	M ^cDATA(0,"DEV.VID","ZR")=^cDATA(0,"DEV.VID","ZC")
	S ^cDATA(0,"DEV.VID","ZC",0)="ZC\ISO-LATIN-1\\\\\\\\\\ISO-LATIN-1"
	S ^cDATA(0,"DEV.VID","ZE",0)="ZE\ISO-LATIN-9\\\\\\\\\\ISO-LATIN-9"
	S ^cDATA(0,"DEV.VID","ZP",0)="ZC\ISO-LATIN-2\\\\\\\\\\ISO-LATIN-2"
	S ^cDATA(0,"DEV.VID","ZR",0)="ZC\ISO Cyrillic\\\\\\\\\\ISO Cyrillic"
	;
YZ	Q
	;
RS(R,From,To)	      ; Save routine R in namespace To
	S R=$G(R),From=$G(From),To=$G(To)
	Q:'$L(R)  Q:'$L($P(R,"\"))  Q:'$D(^$R($P(R,"\")))  Q:'$L($P(R,"\",2))  Q:'$L(From)  Q:'$L(To)
	W !,"Saving ",$P(R,"\")," as ",$P(R,"\",2)," in namespace ",To
	X "ZL "_$P(R,"\")_" ZN To ZS "_$P(R,"\",2)_" ZN From"
	Q
	;
RD(R,From,To)	      ; Delete routine R in namespace To
	S R=$G(R),From=$G(From),To=$G(To)
	Q:'$L(R)  Q:'$L($P(R,"\"))  Q:'$L(From)  Q:'$L(To)
	W !,"Removing ",$P(R,"\")," in namespace ",To
	X "ZN To ZR  ZS "_$P(R,"\")_" ZN From"
	Q
	;
XL(R,From,To)	      ; Xecute R in namespace To
	S R=$G(R),From=$G(From),To=$G(To)
	Q:'$L(R)  Q:'$L($P(R,"\"))  Q:'$L(From)  Q:'$L(To)
	W !,"Xecuting ",$P(R,"\")," in namespace ",To
	X "ZN To "_$P(R,"\")_" ZN From"
	Q
	;
SYS	;Update %ZSTART and %ZSTOP without check
	S CN=$ZU(5),SN="%SYS"
	D RS("cQZSTART\%ZSTART",CN,SN)
	D RS("cQZSTOP\%ZSTOP",CN,SN)
SYSZ	Q
	;
ZZ	; 17.01.2012 - 15:58 * Cache-r6.4.9